gestion des erreurs et annuler

[zebulon_]

Bonjour,

 

L'autre jour je me suis fait rappeler à l'ordre parce que je n'avais pas mis de undo group et de undo end dans un lisp que je vous soumettais. La leçon a été bien retenue, promis je n'oublierai plus.

Cela m'a donné l'idée de rajouter également des _undo dans la fonction error. Votre avis ?

 

(defun C:MAFONC (/)
 (command "_.undo" "_group")


 (defun *error* (msg)
   (command "_.undo" "_end")
   (command "_.undo" "1") ;; annuler tout ce qui a été fait par MAFONC
   (alert (strcat "\nErreur : " msg))
   (princ)
 )

 ;; créer des entités
 (command "_LINE" '(0 0) '(1 1) "")
 (setq ET1 (entlast))
 (command "_LINE" '(1 1) '(2 0) "")
 (setq ET2 (entlast))
 (setvar "filletrad" 2)       ;; passe par la fonction error
;;  (setvar "filletrad" 0.50)  ;; ne provoque pas d'erreur
 (command "_fillet" ET1 ET2)  ;; ligne qui provoque une erreur si filletrad trop grand

 (command "_.undo" "_end")
 (princ)  
 
) 

 

Amicalement

 

Zebulon_

[(gile)]

Salut,

 

Je pense que si on utilise une fonction *error* redéfinie dans un LISP qui ouvre un groupe "_undo" elle doit contenir une commande de fermeture du groupe, elle peut, en outre, annuler les actions depuis le début du groupe, comme tu le propose.

 

Mais de la façon dont tu as écrit ton code tu as redéfini la fonction *error* non seulement pour le LISP mais pour toute la session du dessin en cours.

 

Je pense qu'il est préférable d'utiliser la méthode consistant en sauvegarder la fonction originelle dans une variable et de la restaurer à la fin du LISP et de la fonction redéfinie :

 

(defun MAFONC_ERR (msg)
(command "_.undo" "_end")
(command "_.undo" "1") ;; annuler tout ce qui a été fait par MAFONC
(alert (strcat "\nErreur : " msg))
(setq *error* m:err ;; restaurer *error*
m:err nil
)
(princ)
)

(defun C:MAFONC (/)

(setq m:err *error* ;;sauvegarder *error*
*error* MAFONC_ERR ;;redéfinir *error*
)

(command "_.undo" "_group")

;; créer des entités
(command "_LINE" '(0 0) '(1 1) "")
(setq ET1 (entlast))
(command "_LINE" '(1 1) '(2 0) "")
(setq ET2 (entlast))
(setvar "filletrad" 2) ;; passe par la fonction error
;; (setvar "filletrad" 0.50) ;; ne provoque pas d'erreur
(command "_fillet" ET1 ET2) ;; ligne qui provoque une erreur si filletrad trop grand

(command "_.undo" "_end")

(setq *error* m:err ;; restaurer *error* originel
m:err nil
)

(princ)

) 

[zebulon_]

Salut,

 

(setq m:err *error* ;;sauvegarder *error*

*error* MAFONC_ERR ;;redéfinir *error*

)

 

Quand on n'a pas l'habitude, c'est surprenant de voir qu'on peut traiter des subroutines comme des variables, avec setq. C'est très fort le lisp.

 

Merci

 

Amicalement

 

Zebulon_