CadXP: un carroyage - CadXP

Aller au contenu

Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

un carroyage ça sert à quoi, c'est référencé comment?

#1 L'utilisateur est hors-ligne   philsogood 

  • ceinture noire 5em dan
  • Groupe : Membres
  • Messages : 2 601
  • Inscrit(e) : 03-mars 10

Posté 09 septembre 2020 - 07:50

hello
je viens de faire une découverte, je ne suis pas géomètre mais je sais que certain relevé topo sont équipé de carroyage
en fait c'est quoi ce carroyage?
je pensais que ça indiquait les coordonnées suivant le repère du fichier mais en fait non!!
exemple, j'ai un fichier en Lambert 93 et sur un point j'ai mes ref Lambert qui indique (à la louche) 433328,6325101 (attention mon fichier est en mm) alors que le corroyage indique 1433350,3202500
ya un rapport entre le deux?? ça marche comment un carroyage?
Phil
PS : je suis certain que mon fichier est en Lambert 93
Image IPB
Projeteur Revit - traitement des eaux
0

#2 L'utilisateur est hors-ligne   CTZen 

  • ceinture marron
  • Groupe : Membres
  • Messages : 291
  • Inscrit(e) : 08-août 13
  • LocationChampigny Sur Marne

Posté 09 septembre 2020 - 07:55

Salut,

Normalement le carroyage est dans le système de coordonnée qui était utilisé lorsqu'il a été créé. Donc il doit représenter les coordonnées selon une autre projection que celle de ton fichier.
Il arrive souvent que les éléments d'un fichier soient déplacés en masse par quelqu'un, et que le carroyage d'origine ne soit pas effacé ... Ce qui peut d'ailleurs faire douter du vrai système utilisé dans le fichier DWG.

Les carroyages sont surtout utilisés pour déterminer des coordonnées sur un plan papier.
Personnellement je n'en met plus sur mes plans depuis plusieurs années.
AutoCAD Map 3D 2021 (24.0.30.14)
Covadis 17.1b + AutoPiste
Mensura Genius 9.1
Windows 10 v.1909 - 64 bits


Toujours à l'affût des bonnes astuces !
0

#3 L'utilisateur est hors-ligne   didier 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 8 574
  • Inscrit(e) : 18-décembre 02
  • LocationPlanète : Terre

Posté 09 septembre 2020 - 08:00

Coucou

Tel que tu expliques : c'est impossible
Ou le fichier est en Lambert et le carroyage annonce ce les coordonnées correctes
Ou le fichier a été fait dans un autre système et il a subi ube transformation pour devenir Lambert 93
Et l'âne bâté qui a fait la transformation a laissé les croix de carroyages en place et elles deviennent fausses...

Le carroyage a perdu de son utilité car il servait (dans le temps) à trouver graphiquement les coordonnées
Il servait aussi à vérifier la distorsion des supports papier et calque suites aux tirages multiples car en séchant le papier avait tendance à se gondoler
Il existait aussi le triangle de stabilité mais la population du forum est trop jeune pour savoir de quoi je parle...

Amicalement
0

#4 L'utilisateur est hors-ligne   lecrabe 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 9 105
  • Inscrit(e) : 10-décembre 03
  • LocationLoire (42)

Posté 09 septembre 2020 - 08:57

Hello

Avec ces Coords 433328,6325101 , tu es en Lambert93 France Entiere (pas loin de Mont de Marsan - EPSG = 2154 ) !

Et avec 1433350,3202500 , tu es au MEME endroit en Lambert Zone CC44 ( EPSG = 3944 ) !

Tests avec cet excellent site : https://cad.kerlom.f...oordonnees.php#

LA SANTE (Stay Safe), Regards, lecrabe "triste"
Automne 2020, la retraite
Autodesk Expert Elite Team
0

#5 L'utilisateur est hors-ligne   thierry.garré 

  • ceinture rouge et blanche 6em dan
  • Groupe : Moderateurs
  • Messages : 3 110
  • Inscrit(e) : 30-juin 04
  • LocationAubenas 07 le pays des Chataignes

Posté 09 septembre 2020 - 09:42

Bonjour un fichier en mm (je ne parle pas des unités autocad , mais plutôt que si on mesure une distance de 1 mètre on obtient 1000,
ne peut pas par définition pas être géo référencé.

cordialement
Thierry Garré

Autocad-Autocad Map-Covadis-Autopiste-Infraworks 360- Navisworks -Recap
0

#6 L'utilisateur est hors-ligne   didier 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 8 574
  • Inscrit(e) : 18-décembre 02
  • LocationPlanète : Terre

Posté 09 septembre 2020 - 09:48

Coucou

Je plussoie Thierry
Et c'est pour ça que je disais que tel qu'expliqué c'est impossible

Amicalement

0

#7 L'utilisateur est hors-ligne   philsogood 

  • ceinture noire 5em dan
  • Groupe : Membres
  • Messages : 2 601
  • Inscrit(e) : 03-mars 10

Posté 09 septembre 2020 - 10:11

thierry
il faut mettre un facteur de 0.001 devant ls coordonnées qu'on extrait (j'ai lancé un topic ce matin à ce sujet)
bon, ça me rassure... il y a des quiches (des ânes batés comme dit didier) aussi parmi les géomètres!! :P
le crabe, connais aps ton site, j'utilise celui là eprso... ça me permet de savoir si le fichier est géoréférence et sur quel système
https://app.dogeo.fr...point-to-coords
Phil
Projeteur Revit - traitement des eaux
0

#8 L'utilisateur est hors-ligne   ssalle 

  • ceinture verte
  • Groupe : Membres
  • Messages : 82
  • Inscrit(e) : 20-novembre 15

Posté 09 septembre 2020 - 10:23

Voir le messagelecrabe, le 09 septembre 2020 - 08:57 , dit :


Tests avec cet excellent site : https://cad.kerlom.f...oordonnees.php#



Vraiment bien ce site, j'utilisais DOGEO depuis longtemps, tu m'as convaincu en 2 sec de changer!!
Merci

Seb
Autocad MAP2019 - Covadis V17.0f
0

#9 L'utilisateur est hors-ligne   bonuscad 

  • ceinture rouge et blanche 8em dan
  • Groupe : Membres
  • Messages : 4 764
  • Inscrit(e) : 20-juin 03

Posté 09 septembre 2020 - 10:29

Pour faire un carroyage, j'avais proposé ceci.
Cela fait un carroyage de ton Système Général dans lequel ton dessin est constitué ET référencé. Tu ne peux pas obtenir un carroyage en RGF93 si ton dessin est dans un autre système, il faut être cohérent.
Néanmoins ce code te permet de faire un carroyage très rapidement de ton système utilisé.
Mais comme Didier un carroyage à l'époque du numérique n'est guère utile, qui va reporter des points en coordonnées avec un kutsch sur du papier? L'utilité originale du carroyage était surtout cela...! cependant cela peut quand même informer du système utilisé dans le dessin pour celui qui consulte seulement le rendu papier.

(vl-load-com)
(defun des_vec (lst col / lst_sg)
	(setq lst_sg (list (cadr lst) (car lst)))
	(setq lst (cdr lst))
	(while lst
		(if (cadr lst)
			(setq lst_sg (cons (cadr lst) (cons (car lst) lst_sg)))
			(setq lst_sg (cons (last lst_sg) (cons (car lst) lst_sg)))
		)
		(setq lst (cdr lst))
	)
	(setq lst_sg (cons col lst_sg))
	(grvecs lst_sg)
)
(defun l-coor2l-pt (lst flag / )
	(if lst
		(cons (list (car lst) (cadr lst) (if flag (caddr lst) 0.0))
			(l-coor2l-pt (if flag (cdddr lst) (cddr lst)) flag)
		)
	)
)
(defun c:DIM-GRID ( / unit_draw AcDoc Space UCS save_ucs WCS dx_u hview old_snapang pt_ins dx dy pt_tmp ang l_scale format_scale coeff
 key pt_key s_ang nw_style f_pat nw_pl ech htx nw_pl_out nw_pl_in hatch_out hatch lst_pt str ori_txt nw_txt)
	(if (or (eq (getvar "USERS5") "") (not (eq (substr (getvar "USERS5") 1 2) "qz")))
		(setvar "USERS5" (strcat "qz" (itoa (setq unit_draw 1000))))
		(setq unit_draw (atoi (substr (getvar "USERS5") 3)))
	)
	(setq AcDoc (vla-get-ActiveDocument (vlax-get-acad-object)))
	(vla-StartUndoMark AcDoc)
	(setq
		Space
		(if (eq (getvar "CVPORT") 1)
			(vla-get-PaperSpace AcDoc)
			(vla-get-ModelSpace AcDoc)
		)
		UCS (vla-get-UserCoordinateSystems AcDoc)
		save_ucs
		(vla-add UCS
			(vlax-3d-point '(0.0 0.0 0.0))
			(vlax-3d-point (getvar "UCSXDIR"))
			(vlax-3d-point (getvar "UCSYDIR"))
			"CURRENT_UCS"
		)
	)
	(vla-put-Origin save_ucs (vlax-3d-point (getvar "UCSORG")))
	(setq WCS (vla-add UCS (vlax-3d-Point '(0.0 0.0 0.0)) (vlax-3d-Point '(1.0 0.0 0.0)) (vlax-3d-Point '(0.0 1.0 0.0)) "TEMP_WCS"))
	(vla-put-activeUCS AcDoc WCS)
	(if (not dx_u) (setq dx_u 210.0))
	(setq
		hview (getvar "VIEWSIZE")
		old_snapang (getvar "SNAPANG")
		pt_ins (list (- (car (getvar "VIEWCTR")) (* hview 0.5)) (- (cadr (getvar "VIEWCTR")) (* hview 0.5)))
		dx dx_u dy (* dx_u (sqrt 2)) pt_tmp pt_ins ang (getvar "SNAPANG")
		l_scale '(1.0 1.25 2.0 2.5 5.0 7.5)
		format_scale (car l_scale)
		coeff 1.0
	)
	(if (> (fix (/ hview dy)) 3)
		(while (> (fix (/ hview dy)) 3)
			(foreach value l_scale
				(if (> (fix (/ hview dy)) 3)
					(setq format_scale value dx (* dx_u format_scale) dy (* dx_u (sqrt 2) format_scale))
				)
			)
			(if (> (fix (/ hview dy)) 3)
				(setq
					coeff (* coeff 10.0)
					l_scale (mapcar '(lambda (x) (* x coeff)) l_scale)
					format_scale (car l_scale)
				)
			)
		)
	)
	(if (< (fix (/ hview dy)) 1)
		(while (< (fix (/ hview dy)) 1)
			(foreach value (reverse l_scale)
				(if (< (fix (/ hview dy)) 1)
					(setq format_scale value dx (* dx_u format_scale) dy (* dx_u (sqrt 2) format_scale))
				)
			)
			(if (< (fix (/ hview dy)) 1)
				(setq
					coeff (* coeff 0.1)
					l_scale (mapcar '(lambda (x) (* x coeff)) l_scale)
					format_scale (last l_scale)
				)
			)
		)
	)
	(princ (strcat "\nSpecify up rigth corner or: [P] for new Position of down left corner,[R] for make Rotate, [+/-] change scale <" (rtos (* unit_draw format_scale) 2 3) ">: "))
	(while (and (setq key (grread T 4 0)) (/= (car key) 3))
		(cond
			((eq (car key) 5)
				(setq pt_key (cadr key))
				(redraw)
				(setq
					dx (+ (* (- (car pt_key) (car pt_ins)) (cos ang)) (* (- (cadr pt_key) (cadr pt_ins)) (sin ang)))
					dy (- (* (- (cadr pt_key) (cadr pt_ins)) (cos ang)) (* (- (car pt_key) (car pt_ins)) (sin ang)))
				)
				(des_vec
					(list
						(list (car pt_ins) (cadr pt_ins))
						(list (+ (car pt_ins) (* dx (cos ang))) (+ (cadr pt_ins) (* dx (sin ang))))
						(setvar "LASTPOINT"
							(list
								(+ (car pt_ins) (- (* dx (cos ang)) (* dy (sin ang))))
								(+ (cadr pt_ins) (+ (* dy (cos ang)) (* dx (sin ang))))
							)
						)
						(list (- (car pt_ins) (* dy (sin ang))) (+ (cadr pt_ins) (* dy (cos ang))))
					)
					3
				)
			)
			((or (eq (cadr key) 114) (eq (cadr key) 82))
				(initget 0)
				(setq s_ang
					(getorient pt_ins
						(strcat
							"\nNew angle<"
							(angtos (getvar "SNAPANG"))
							">: "
						)
					)
				)
				(if (not s_ang) (setq s_ang ang))
				(if (and (> s_ang (/ pi 2)) (<= s_ang (/ (* 3 pi) 2)))
					(setq ang (+ s_ang pi))
					(setq ang s_ang)
				)
				(setvar "SNAPANG" ang)
				(princ (strcat "\nSpecify up rigth corner or: [P] for new Position of down left corner,[R] for make Rotate, [+/-] change scale <" (rtos (* unit_draw format_scale) 2 3) ">: "))
			)
			((or (eq (cadr key) 112) (eq (cadr key) 80))
				(initget 9)
				(setq pt_ins (getpoint "\nSpecify down left corner: "))
				(setq pt_ins (list (car pt_ins) (cadr pt_ins)))
				(princ (strcat "\nSpecify up rigth corner or: [P] for new Position of down left corner,[R] for make Rotate, [+/-] change scale <" (rtos (* unit_draw format_scale) 2 3) ">: "))
			)
			((eq (cadr key) 43)
				(setq format_scale (cadr (member format_scale l_scale)))
				(if (not format_scale) (setq format_scale (car (setq l_scale (mapcar '(lambda (x) (* x 10.0)) l_scale)))))
				(setq dx (* dx_u format_scale) dy (* dx_u (sqrt 2) format_scale))
				(princ (strcat "\nSpecify up rigth corner or: [P] for new Position of down left corner,[R] for make Rotate, [+/-] change scale <" (rtos (* unit_draw format_scale) 2 3) ">: "))
			)
			((eq (cadr key) 45)
				(setq format_scale (cadr (member format_scale (reverse l_scale))))
				(if (not format_scale) (setq format_scale (last (setq l_scale (mapcar '(lambda (x) (* x 0.1)) l_scale)))))
				(setq dx (* dx_u format_scale) dy (* dx_u (sqrt 2) format_scale))
				(princ (strcat "\nSpecify up rigth corner or: [P] for new Position of down left corner,[R] for make Rotate, [+/-] change scale <" (rtos (* unit_draw format_scale) 2 3) ">: "))
			)
		)
	)
	(princ "\n")
	(redraw)
	(if (not (tblsearch "STYLE" "$DIM-GRID"))
		(progn
			(setq nw_style (vla-add (vla-get-textstyles AcDoc) "$DIM-GRID"))
			(mapcar
				'(lambda (pr val)
					(vlax-put nw_style pr val)
				)
				(list 'FontFile 'Height 'ObliqueAngle 'Width 'TextGenerationFlag)
				(list "SIMPLEX.SHX" 0.0 0.0 1.0 0.0)
			)
		)
  )
	(if (not (tblsearch "LAYER" "DIM-GRID"))
		(vlax-put (vla-add (vla-get-layers AcDoc) "DIM-GRID") 'color 7)
	)
	(if (not (findfile "QUADISO.pat"))
		(progn
			(setq f_pat (open (strcat (getvar "ROAMABLEROOTPREFIX") "support\\QUADISO.pat") "w"))
			(write-line "*QUADISO,Quadrillage lambert" f_pat)
			(write-line "0, -.015,0, 0,1, .03,-.97" f_pat)
			(write-line "90, 0,-.015, 0,1, .03,-.97" f_pat)
			(close f_pat)
		)
	)
	(if (not (findfile "REPQUADISO.pat"))
		(progn
			(setq f_pat (open (strcat (getvar "ROAMABLEROOTPREFIX") "support\\REPQUADISO.pat") "w"))
			(write-line "*REPQUADISO,Repere du quadrillage lambert" f_pat)
			(write-line "0, 0,0, 0,1" f_pat)
			(write-line "90, 0,0, 0,1" f_pat)
			(close f_pat)
		)
	)
	(setq
		nw_pl
		(vlax-invoke Space 'AddLightWeightPolyline
			(append
				pt_ins
				(polar pt_ins (+ (getvar "SNAPANG") (* pi 0.5)) (* (distance pt_ins (getvar "LASTPOINT")) (sin (- (angle pt_ins (getvar "LASTPOINT")) (getvar "SNAPANG")))))
				
				(list (car (getvar "LASTPOINT")) (cadr (getvar "LASTPOINT")))
				(polar pt_ins (getvar "SNAPANG") (* (distance pt_ins (getvar "LASTPOINT")) (cos (- (angle pt_ins (getvar "LASTPOINT")) (getvar "SNAPANG")))))
			)
		)
		ech (* unit_draw format_scale)
		htx (/ ech 500.0)
	)
	(vla-put-Closed nw_pl 1)
	(vla-put-layer nw_pl "DIM-GRID")
	(vla-Offset nw_pl (* htx 2.5))
	(setq nw_pl_out (vlax-ename->vla-object (entlast)))
	(vla-Offset nw_pl (+ (* htx 2.5) (* htx 10.0)))
	(setq nw_pl_in (vlax-ename->vla-object (entlast)))
	(setvar "HPORIGINMODE" 0)
	(setvar "HPORIGIN" '(0.0 0.0))
	(setq hatch_out (vla-AddHatch Space acHatchPatternTypeCustomDefined "REPQUADISO" :vlax-True))
	(vlax-invoke hatch_out 'AppendOuterLoop (list nw_pl))
	(vlax-invoke hatch_out 'AppendInnerLoop (list nw_pl_out))
	(vla-put-patternscale hatch_out (/ ech 10.0))
	(vla-put-patternangle hatch_out 0.0)
	(vla-put-layer hatch_out "DIM-GRID")
	(vla-evaluate hatch_out)
	(setq hatch (vla-AddHatch Space acHatchPatternTypeCustomDefined "QUADISO" :vlax-True))
	(vlax-invoke hatch 'AppendOuterLoop (list nw_pl_in))
	(vla-put-patternscale hatch (/ ech 10.0))
	(vla-put-patternangle hatch 0.0)
	(vla-put-layer hatch "DIM-GRID")
	(vla-evaluate hatch)
	(setq lst_pt
		(l-coor2l-pt
			(vlax-invoke
				hatch_out
				'IntersectWith
				nw_pl_out
				acExtendThisEntity
			)
			T
		)
	)
	(foreach el lst_pt
		(cond
			((or (equal (rem (car el) (/ ech 10.0)) (/ ech 10.0) 1E-8) (equal (rem (car el) (/ ech 10.0)) 0.0 1E-8))
				(setq str (strcat " " (rtos (car el) 2 0) " ") ori_txt (* pi 0.5))
			)
			((or (equal (rem (cadr el) (/ ech 10.0)) (/ ech 10.0) 1E-8) (equal (rem (cadr el) (/ ech 10.0)) 0.0 1E-8))
				(setq str (strcat " " (rtos (cadr el) 2 0) " ") ori_txt 0.0)
			)
			(T (setq str nil ori_txt nil))
		)
		(cond
			((and el str ori_txt)
				(setq nw_txt (vla-AddText Space str (vlax-3d-point el) htx))
				(vla-put-layer nw_txt "DIM-GRID")
				(vla-put-StyleName nw_txt "$DIM-GRID")
				(vla-put-Alignment nw_txt acAlignmentMiddleLeft)
				(vla-put-Rotation nw_txt ori_txt)
				(vla-put-TextAlignmentPoint nw_txt (vlax-3d-point el))
				(if (vlax-invoke nw_pl 'IntersectWith nw_txt acExtendThisEntity)
					(vla-put-Alignment nw_txt acAlignmentMiddleRight)
				)
			)
		)
	)
	(setq pt_ins (polar pt_ins (+ (* pi 0.25) (getvar "SNAPANG")) (* htx 10)))
	(setq nw_txt (vla-AddText Space (strcat " Scale 1/" (rtos ech 2 0)) (vlax-3d-point pt_ins) (* 2 htx)))
	(vla-put-layer nw_txt "DIM-GRID")
	(vla-put-StyleName nw_txt "$DIM-GRID")
	(vla-put-Alignment nw_txt acAlignmentMiddleLeft)
	(vla-put-Rotation nw_txt (getvar "SNAPANG"))
	(vla-put-TextAlignmentPoint nw_txt (vlax-3d-point pt_ins))
	(and save_ucs (vla-put-activeUCS AcDoc save_ucs))
	(and WCS (vla-delete WCS) (setq WCS nil))
	(vla-EndUndoMark AcDoc)
	(setvar "SNAPANG" old_snapang)
	(prin1)
)


Choisissez un travail que vous aimez et vous n'aurez pas à travailler un seul jour de votre vie. - Confucius
0

#10 L'utilisateur est hors-ligne   thierry.garré 

  • ceinture rouge et blanche 6em dan
  • Groupe : Moderateurs
  • Messages : 3 110
  • Inscrit(e) : 30-juin 04
  • LocationAubenas 07 le pays des Chataignes

Posté 09 septembre 2020 - 10:33

Citation

thierry<br style="color: rgb(28, 40, 55); font-size: 13px; background-color: rgb(250, 251, 252);">il faut mettre un facteur de 0.001 devant ls coordonnées qu'on extrait (j'ai lancé un topic ce matin à ce sujet)<br style="color: rgb(28, 40, 55); font-size: 13px; background-color: rgb(250, 251, 252);">bon, ça me rassure... il y a des quiches (des ânes batés comme dit didier) aussi parmi les géomètres!!


j'aprécie ta remarque a sa juste valeur.........


ne connaissant pas le point de base qui a servi au changement d’échelle de ton dessin , je confirme ce que je de dit
Thierry Garré

Autocad-Autocad Map-Covadis-Autopiste-Infraworks 360- Navisworks -Recap
0

#11 L'utilisateur est hors-ligne   La Lozère 

  • ceinture noire 5em dan
  • Groupe : Membres
  • Messages : 2 729
  • Inscrit(e) : 28-juin 06
  • LocationVienne (38) - Etude APA - A480

Posté 09 septembre 2020 - 10:37

Perso, je préfère ce site qui permet de faire ce qu'on veux et dans tout les sens :
https://app.dogeo.fr...point-to-coords

Mais c'est un avis très personnel....
www.cad-is.fr
Autocad Map 2018 - Covadis/Autopiste V17.0d - Mensura Genius V8
Nous n’héritons pas de la Terre de nos ancêtres, nous l’empruntons à nos enfants
0

#12 L'utilisateur est hors-ligne   lecrabe 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 9 105
  • Inscrit(e) : 10-décembre 03
  • LocationLoire (42)

Posté 09 septembre 2020 - 12:06

Hello Bruno

J aime bien ton DIM-GRID que j avais deja !

SVP comment ajouter les Echelles a TA Liste : 150 , 400 , 1500 , 4000 , 15000

Ou SVP pourrais tu mettre TOUTES les echelles possibles dans UNE Liste !?
Ainsi on pourrait personnaliser facilement la routine Lisp ...

Merci de tes lumieres !

LA SANTE (Stay Safe), Regards, lecrabe "triste"
Automne 2020, la retraite

PS: https://app.dogeo.fr...point-to-coords
Ce site est different et "plus complet" !
Mais le site https://cad.kerlom.fr/ est oriente AutoCAD + Covadis ...
Autodesk Expert Elite Team
0

#13 L'utilisateur est hors-ligne   bonuscad 

  • ceinture rouge et blanche 8em dan
  • Groupe : Membres
  • Messages : 4 764
  • Inscrit(e) : 20-juin 03

Posté 09 septembre 2020 - 13:45

Voir le messagelecrabe, le 09 septembre 2020 - 12:06 , dit :

Hello Bruno

J aime bien ton DIM-GRID que j avais deja !

SVP comment ajouter les Echelles a TA Liste : 150 , 400 , 1500 , 4000 , 15000

Ou SVP pourrais tu mettre TOUTES les echelles possibles dans UNE Liste !?
Ainsi on pourrait personnaliser facilement la routine Lisp ...



à la ligne 54 où tu as:
		l_scale '(1.0 1.25 2.0 2.5 5.0 7.5)
tu la passe à:
		l_scale '(1.0 1.25 1.5 2.0 2.5 4.0 5.0 7.5)
C'est la liste unitaire des échelles, donc quand tu parle de 15000, c'est la même que 150 (ou 15 ou 1.5)
En appuyant sur "+", dès que tu arrive à la fin de la liste (un multiple de 7.5) , tu retourne au début de la liste en incrémentant avec un facteur de 10 et avec "-" avec un facteur de 0.1
Le code propose une échelle qui est calculée en conséquence d'un A4 suivant ton hauteur de vue actuelle (variable "VIEWSIZE"), donc : CONSEIL, ne pas trop s'écarter de l'échelle proposée au départ sous peine d'avoir un quadrillage très serré ou à l'inverse non visible car trop écarté. Passer par exemple de 7500000 à 7500 va donner un quadrillage très serré.
Le mieux est de lancer la routine lorsque la partie que tu désire quadriller est visible entièrement à l'écran et de rester dans l'ordre de grandeur proposée 10, 100, 1000, 10000 etc ......
Ma liste initiale était basée sur celle qu'on trouve sur un kutsch standard, mais rien n'empêche d'utiliser des échelles non usuelles, du 300, 700 et pourquoi pas du 3.333 Image IPB

Choisissez un travail que vous aimez et vous n'aurez pas à travailler un seul jour de votre vie. - Confucius
0

#14 L'utilisateur est hors-ligne   lecrabe 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 9 105
  • Inscrit(e) : 10-décembre 03
  • LocationLoire (42)

Posté 09 septembre 2020 - 14:17

Hello Bruno

Je t adore ! MERCI ...

Je te previens quand je passe en Ardeche, et je viens avec quoi : biere, blanc, rose, rouge, etc ???

LA SANTE (Stay Safe), Regards, lecrabe "triste"
Automne 2020, la retraite (21 jours restants)
Autodesk Expert Elite Team
0

#15 L'utilisateur est hors-ligne   nosset 

  • ceinture noire 1er dan
  • Groupe : Membres
  • Messages : 563
  • Inscrit(e) : 06-septembre 12

Posté 09 septembre 2020 - 15:20

Voir le messagebonuscad, le 09 septembre 2020 - 10:29 , dit :

Mais comme Didier un carroyage à l'époque du numérique n'est guère utile, qui va reporter des points en coordonnées avec un kutsch sur du papier? L'utilité originale du carroyage était surtout cela...! cependant cela peut quand même informer du système utilisé dans le dessin pour celui qui consulte seulement le rendu papier.


Détrompez vous les amis, ce bon vieux carroyage m'a bien aidé encore cette semaine.
Il y a de gros soucis avec REVIT pour mettre un plan de géomètre .DWG en fond. Trés régulièrement il apparaît complètement défoncé.
Après avoir essayer toute les manipulations qui marchent normalement, le résultat était toujours le même. pourri !
Du coup j'ai été obligé de passer à l'étape ultime, tout décomposé et mettre le point 0,0 au centre du dessin.


J'ai tout de même pu géo-référencer mon fichier REVIT grâce au carroyage. Alors soyez gentil, laissez le vieux carroyage pour ceux qui utilisent des logiciels modernes :(rires forts):
Autodesk Expert Elite Member
0

#16 L'utilisateur est hors-ligne   bonuscad 

  • ceinture rouge et blanche 8em dan
  • Groupe : Membres
  • Messages : 4 764
  • Inscrit(e) : 20-juin 03

Posté 10 septembre 2020 - 10:41

Voir le messagelecrabe, le 09 septembre 2020 - 14:17 , dit :

Hello Bruno

Je t adore ! MERCI ...

Je te previens quand je passe en Ardeche, et je viens avec quoi : biere, blanc, rose, rouge, etc ???

LA SANTE (Stay Safe), Regards, lecrabe "triste"
Automne 2020, la retraite (21 jours restants)


Hello Patrice,

En ce moment c'est plutôt Picon-bière, comme ça je fais ma prévention contre le COVID19 vu que la chloroquine est interdite, je remplace par la quinine.
Je dis bien en prévention, je me soignerais pas avec; vue la dose homéopathique qu'il y a dans le picon!
Et si j’exagère avec le picon bière, ce sera pour me soigner de la connerie humaine.
Et pis retraite début été 2021Image IPB

Choisissez un travail que vous aimez et vous n'aurez pas à travailler un seul jour de votre vie. - Confucius
0

#17 L'utilisateur est hors-ligne   lecrabe 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 9 105
  • Inscrit(e) : 10-décembre 03
  • LocationLoire (42)

Posté 10 septembre 2020 - 10:57

Hello Bruno

OK donc je t apporterai une caisse de Schweppes !
Car il y a aussi de la Quinine dans le Schweppes ...

LA SANTE (Stay Safe), Regards, lecrabe "triste"
Automne 2020, la retraite (20 jours restants)
Autodesk Expert Elite Team
0

Partager ce sujet :


Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

1 utilisateur(s) en train de lire ce sujet
0 membre(s), 1 invité(s), 0 utilisateur(s) anonyme(s)