Compte des polylignes

mikl63 · le 3 mars 2017

Bonjour à tous,

Je suis à la recherche d'un lisp permettant de compter les longueurs des polylignes en cumulés.

Je m'explique, j'ai l'intention de créer plusieurs calques correspondants à des déperditions linéiques et de les représenter, chacune dans son calque approprié, par une polyligne.

Le but étant de connaitre exactement les longueurs des pl attribuées à chaque calque.

J'ai trouvé un lisp crée par l'excellent Gile mais il ne fonctionne pas. Enfin si il fonctionne mais il donne des valeurs erronées.

Le seul souci dans l'histoire, c'est que mon collègue est sous un Autocad LT donc s'il existe un truc, je suis preneur.

Merci d'avance

DenisHen · le 3 mars 2017

Salut.

Je pense que la réponse est ici ou encore mieux, ici...

mikl63 · le 3 mars 2017

Je viens de le tester mais c'est pas tout à fait ça. Ce lisp côte les pl et c'est pas vraiment le but que je recherche.

Je veux uniquement qu'il me donne les longueurs totales.

Avec ce lisp, je suis obligé de cliquer sur chacune des PL et sur tous les cotés puis d’additionner chacune des côtes.

Dans ce cas, autant cliquer sur propriétés et additionner également.

On se rapproche ceci dit

DenisHen · le 3 mars 2017

Alors le deuxième lien sera le bon, section "Somme de polylignes par calques"

C'est un petit LISP, sur la base d'un code de (gile), qui calcul la somme des polylignes par calques sélectionnés...

mikl63 · le 3 mars 2017

J'ai trouvé un truc parfait : tableau périmètre.

Il crée même le tableau qui va avec.

Je vais regarder celui dont tu me parle.

Merci beaucoup

lecrabe · le 3 mars 2017

Hello

SVP tu peux partager ce Lisp ?

Bye, lecrabe

Aleck_Ultimate · le 3 mars 2017

Sinon pour ton collègue qui est sur LT, il peut passer par EXTRACTDONNEE, en faisant un tri par calque, puis en rajoutant une ligne "somme" pour additionner les longueurs de touts les segmentes de chaque calques, ça fait le café.

Je l'ais utilisé pour calculer la longueur d'un plancher-chauffant tout en SPLINE : au poile !

DaWeeD_Gab · le 3 mars 2017

bonjour,

j'utilise le lisp ci-dessous, il nécessite de sélectionner les polylignes au préalable.

ça peut-être pratique lorsqu'on ne veut pas toutes les longueurs de polylignes d'un même calque:

(defun c:lg-pol (/ LG SEL X)

(setq lg 0)

(while (not sel)

(setq sel (ssget '((0 . "LWPOLYLINE"))))

)

(repeat (setq x (sslength sel))

(setq lg (+ lg

(vla-get-Length

(vlax-ename->vla-object (ssname sel (setq x (1- x)))))))

)

(alert (strcat "Longueur :" (rtos lg) " ."))

(princ)

)

Red · le 3 mars 2017

Hello

SVP tu peux partager ce Lisp ?

Bye, lecrabe

Totalement intéressé aussi :D

Eric · le 3 mars 2017

Pour AutoCAD LT, j'avais développé un petit truc basique qui additionne les longueurs et les surfaces.

Je ne le met pas en ligne directement parce que je ne l'ai pas mis sur un site, il y a une petite procédure d'installation à faire et il est encore en cours de développent.

Mais si ça en intéresse quelques-uns de tester, contactez moi par MP ou courriel.

En gros cela donne ça :

http://img4.hostingpics.net/thumbs/mini_844487longueurs.jpg

DenisHen · le 3 mars 2017

Salut Eric...

Excellente idée... Ça fonctionne par calques ?

Eric · le 3 mars 2017

Salut Eric...

Excellente idée... Ça fonctionne par calques ?

Salut DenisHen

Non, ça fonctionne par sélection d'objets, mais après rien ne t'empêche d'isoler un calque avant de lancer cette commande.

DenisHen · le 3 mars 2017

Ok...

Ça va en sauver plus d'un ton truc...

Bon courage pour la suite...

Denis...

rebcao · le 3 mars 2017

Bonjour,

Sinon pour ton collègue qui est sur LT, il peut passer par EXTRACTDONNEE,

NON cette commande n'existe pas dans les versions LT ! On peut aussi utiliser le SCANDXF de Brice...

Hello, Riri tu peux me l'envoyer ? Comme ça je vais pouvoir t'embêter ! Merci...

Christian

Aleck_Ultimate · le 3 mars 2017

cette commande n'existe pas dans les versions LT

Oups, désolé

mikl63 · le 5 mars 2017

;;; c:tableau_Perimetres

;;; Dessine un tableau illustrant la liste des calques et les périmètres d'objets filtrés (en ModelSpace)

;;;

;;; Compatibilité: AutoCAD 2005 et plus

;;;

;;; Instructions:

;;; 1) Charger ce fichier

;;; 2) Tapez TABLEAU_PERIMETRES sur la ligne de commande

;;; 3) Indiquez le point d'insertion

;;; 4) La partie Personnalisation peut être modifiés.

;;;

;;; Par Serge Camiré, CadNovation, 2008/08/12

;;; http://www.cadnovation.com/fr

;;;

(vl-load-com)


(defun c:tableau_Perimetres (

/ acadObject column ColWidth endPt filteredLayers filteredObjets i LayerCount LayerName layerNames lcLayerName 

  LineWeightMedium LineWeightNone LineWeightThick ModelSpace n NumColumns NumRows objectName perimeter Point3D_UCS 

  Point3D_WCS Resultat Resultats row RowHeight tableau textsize ThisDrawing Total vlaLayers vlaPoint3D vlaTableau

  ) 

 

  ;; ======================================================================================================================

  ;; Personnalisation

  ;; ======================================================================================================================

 

  ;; Liste des calques et objets désirés, séparés par des virgules, sans espace, wildcard acceptés, en minuscules ou majuscules

  ;; Exemple pour calques: "*" pour tous les calques, "E*,Z*" pour tous ceux qui commencent par E et par Z

  ;; Exemple pour objets "*" pour tous les objets "*line,circle" pour tous les objets dont le nom se termine par "line", ainsi que les cercles

  (setq filteredLayers "*")  

  (setq filteredObjets "*line")  


  ;; Taille du tableau

  (setq textsize (getvar "textsize"))          ; Voir cette variable qui contrôle la hauteur du texte

  (setq RowHeight (* 2.0 textsize))

  (setq ColWidth (* 10.0 RowHeight))           ; Largeur totale du tableau = 2 * ColWidth puisqu'on a 2 colonnes

  (setq LineWeightThick acLnWt090)             ; Épaisseur de la ligne de séparation (voir LWDISPLAY)

  (setq LineWeightMedium acLnWt040)            ; Épaisseur de la ligne de séparation (voir LWDISPLAY)

  (setq LineWeightNone acLnWt000)              ; Épaisseur de la ligne de séparation (voir LWDISPLAY)


 

  ;; ======================================================================================================================

  ;; Ne pas modifier la suite du programme

  ;; ======================================================================================================================


  (setq filteredLayers (strcase filteredLayers t))  ; Minuscules

  (setq filteredObjets (strcase filteredObjets t))  ; Minuscules



  (setq acadObject (vlax-get-acad-object))

  (setq ThisDrawing (vla-get-ActiveDocument acadObject))

  (setq ModelSpace (vla-get-ModelSpace ThisDrawing))

  (setq vlaLayers (vla-get-Layers ThisDrawing))

  (setq LayerCount (vla-get-count vlaLayers))


  (setq Point3D_UCS (getpoint "\nPoint d'insertion: "))

  (setq Point3D_WCS (trans Point3D_UCS 1 0))  ; Si pas en WCS

  (setq vlaPoint3D (PointToVariant Point3D_WCS))


  ;; En AutoLISP, il n'y a pas de tableau. On va se créer un faux tableau avec des clés (hash table)

  ;; dont les paires sont (LayerName Count)

  (setq Resultats nil)

  (setq layerNames nil)

  (vlax-for vlaLayer vlaLayers

     (setq layerName (vla-get-name vlaLayer))

     (setq lcLayerName (strcase layerName t))  ; Minuscules

     (if (wcmatch lcLayerName filteredLayers) (setq layerNames (cons lcLayerName layerNames)))

  )

  (setq layerNames (vl-sort layerNames '<))  ; Trier en ordre croissant

  (setq Resultats (mapcar '(lambda (x) (cons x 0.0)) layerNames))


  (vlax-for vlaObject ModelSpace

     

     (if (and (wcmatch (setq objectName (strcase (vla-get-ObjectName vlaObject) t)) filteredObjets)

              (wcmatch (setq layerName (strcase (vla-get-Layer vlaObject) t)) filteredLayers)

         )

     (progn

        (setq endPt (vlax-curve-getEndParam vlaObject))

        (setq perimeter (vlax-curve-getDistAtParam vlaObject endPt))

        (setq Total (+ perimeter (cdr (assoc layerName Resultats))))

        (setq Resultats (subst (cons layerName Total) (assoc layerName Resultats) Resultats)) 

     ))

  )


  (setq NumRows (+ 3 LayerCount)) ; 2 lignes de titre + total

  (setq NumColumns 2)

  (setq vlaTableau (vla-AddTable ModelSpace vlaPoint3D NumRows NumColumns RowHeight ColWidth))


  ;; Ligne 0

  (setq row 0)

  (setq column 0)

  (SetCellProperties vlaTableau row column "Résultats" textsize acMiddleCenter nil)


  ;; Ligne 1, colonne 0

  (setq row 1)

  (setq column 0)

  (SetCellProperties vlaTableau row column "Calques" textsize acMiddleCenter (cons acHorzBottom LineWeightMedium))


  ;; Ligne 1, colonne 1

  (setq row 1)

  (setq column 1)

  (SetCellProperties vlaTableau row column "Périmètres" textsize acMiddleCenter (cons acHorzBottom LineWeightMedium))


  ;; Lignes de résultat

  (setq i 0)

  (setq n LayerCount)

  (setq Total 0.0)

  (while (< i n)

     (setq Resultat (nth i Resultats))

     (setq row (+ i 2))


     ;; Calque

     (setq column 0)

     (setq layerName (strcase (car Resultat)))

     (SetCellProperties vlaTableau row column layerName textsize acMiddleLeft nil)


     ;; Périmètre

     (setq column 1)

     (setq perimeter (cdr Resultat))

     (setq Total (+ Total perimeter))

     (SetCellProperties vlaTableau row column (rtos perimeter) textsize acMiddleRight nil)

     (setq i (1+ i))

  ) 


  ;; Total

  (setq row (+ LayerCount 2))

  (setq column 0)

  (setq layerName "Total")

  (SetCellProperties vlaTableau row column layerName textsize acMiddleLeft (cons acHorzTop LineWeightMedium))


  ;; Périmètre total

  (setq column 1)

  (setq perimeter Total)

  (setq Total (+ Total perimeter))

  (SetCellProperties vlaTableau row column (rtos perimeter) textsize acMiddleRight nil)

)


;;; c:tableau_Blocs

;;; Dessine un tableau illustrant la liste des calques et les blocs filtrés (en ModelSpace)

;;;

;;; Compatibilité: AutoCAD 2005 et plus

;;;

;;; Instructions:

;;; 1) Charger ce fichier

;;; 2) Tapez TABLEAU_BLOCS sur la ligne de commande

;;; 3) Indiquez le point d'insertion

;;; 4) La partie Personnalisation peut être modifiés.

;;;

;;;    IMPORTANT  IMPORTANT  IMPORTANT  IMPORTANT  IMPORTANT  IMPORTANT  IMPORTANT

;;;    Parmi les items à personnaliser, il faut prêter attention à ces variables

;;;    ;; Noms d'objets acceptés

;;;    (setq filteredLayers "*")  

;;;    (setq filteredBlockNames "*")  

;;;

;;;    ;; Noms d'objets à exclure

;;;    ;; Exemple pour calques: "" pour aucun, "*$*,*|*" pour tous ceux contenant un $ ou | (i.e. issu de xref)

;;;    (setq excludedLayers "defpoint,*$*,*|*")     ; Exclure defpoint et ceux issus de Xrefs

;;;    (setq excludedBlockNames "`**,*$*,*|*")      ; Exclure blocs anonymes et ceux issus de Xrefs

;;;

;;;    ;; Exclusion de lignes ou rangées vides

;;;    (setq excludeEmptyColumns t)                 ; Exclure du tableau si tous les items de la colonne sont 0

;;;    (setq excludeEmptyRows t)                    ; Exclure du tableau si tous les items de la rangée sont 0

;;;

;;;

;;; Par Serge Camiré, CadNovation, 2008/08/14

;;; http://www.cadnovation.com/fr

;;;


(defun c:tableau_Blocs (

/ acadObject blockName blockNames column ColWidth Count CurrentlayerWasLocked excludedBlockNames 

  excludedLayers excludeEmptyColumns excludeEmptyRows filteredBlockNames filteredLayers i j 

  layerName layerNames lcBlockName lcLayerName LineWeightMedium LineWeightNone LineWeightThick 

  m ModelSpace n NumColumns NumRows Point3D_UCS Point3D_WCS Resultats ResultatsBlock ResultatsBlocks 

  ResultatsLayersBlocks row RowHeight textsize ThisDrawing total vlaBlocks vlaLayers vlaPoint3D 

  vlaTableau 

  )

  ;; Liste des calques et noms de bloc désirés, séparés par des virgules, sans espace, wildcard acceptés, en minuscules ou majuscules

  ;; Le résultats est un tableau dont les titre de colonne sont les noms de bloc et les titres de rangée sont les calques.


  ;; Noms d'objets acceptés

  ;; Exemple pour calques: "*" pour tous les calques, "E*,Z*" pour tous ceux qui commencent par E et par Z

  (setq filteredLayers "*")     ; Tout

  (setq filteredBlockNames "*") ; Tout


  ;; Noms d'objets à exclure

  ;; Exemple pour calques: "" pour aucun, "*$*,*|*" pour tous ceux contenant un $ ou | (i.e. issu de xref)

  (setq excludedLayers "defpoint,*$*,*|*")     ; Exclure defpoint et ceux issus de Xrefs

  (setq excludedBlockNames "`**,*$*,*|*")      ; Exclure blocs anonymes et ceux issus de Xrefs


  ;; Exclusion de lignes ou rangées vides

  (setq excludeEmptyColumns t)                 ; Exclure du tableau si tous les items de la colonne sont 0

  (setq excludeEmptyRows t)                    ; Exclure du tableau si tous les items de la rangée sont 0


  ;; Taille du tableau

  (setq textsize (getvar "textsize"))          ; Voir cette variable qui contrôle la hauteur du texte

  (setq RowHeight (* 2.0 textsize))

  (setq ColWidth (* 10.0 RowHeight))           ; Largeur totale du tableau = 2 * ColWidth puisqu'on a 2 colonnes

  (setq LineWeightThick acLnWt090)             ; Épaisseur de la ligne de séparation (voir LWDISPLAY)

  (setq LineWeightMedium acLnWt040)            ; Épaisseur de la ligne de séparation (voir LWDISPLAY)

  (setq LineWeightNone acLnWt000)              ; Épaisseur de la ligne de séparation (voir LWDISPLAY)


 

  ;; ======================================================================================================================

  ;; Ne pas modifier la suite du programme

  ;; ======================================================================================================================


  (setq filteredLayers (strcase filteredLayers t))  ; Minuscules

  (setq filteredBlockNames (strcase filteredBlockNames t))  ; Minuscules



  (setq acadObject (vlax-get-acad-object))

  (setq ThisDrawing (vla-get-ActiveDocument acadObject))

  (setq ModelSpace (vla-get-ModelSpace ThisDrawing))

  (setq vlaBlocks (vla-get-blocks ThisDrawing))

  (setq vlaLayers (vla-get-Layers ThisDrawing))


  ;; En AutoLISP, il n'y a pas de tableau. On va se créer un faux tableau avec des clés (hash table)

  ;; dont les paires sont (LayerName Count)


  (setq ResultatsBlocks nil)

  (setq BlockNames nil)

  (vlax-for vlaBlock vlaBlocks

     (setq blockName (GetBlockName vlaBlock))          ; Nom du bloc (accepte les blocs dynamiques.

     (setq lcBlockName (strcase blockName t))          ; Minuscules, blocs nommés

     (if (and 

            (wcmatch lcBlockName filteredBlockNames) 

            (not (wcmatch lcBlockName excludedBlockNames))

          ) 

        (setq BlockNames (cons lcBlockName BlockNames))

     )

  )

  (setq BlockNames (vl-sort BlockNames '<))  ; Trier en ordre croissant

  (setq ResultatsBlocks (mapcar '(lambda (x) (cons x 0)) BlockNames))


  (setq ResultatsLayersBlocks nil)

  (setq layerNames nil)

  (vlax-for vlaLayer vlaLayers

     (setq layerName (vla-get-name vlaLayer))

     (setq lcLayerName (strcase layerName t))          ; Minuscules

     (if (and 

            (wcmatch lcLayerName filteredLayers)

            (not (wcmatch lcLayerName excludedLayers))

         )

        (setq layerNames (cons lcLayerName layerNames))

     )

  )

  (setq layerNames (vl-sort layerNames '<))  ; Trier en ordre croissant

  (setq ResultatsLayersBlocks (mapcar '(lambda (x) (cons x ResultatsBlocks)) layerNames))


  (vlax-for vlaObject ModelSpace

     

     (if (and (= "AcDbBlockReference" (vla-get-ObjectName vlaObject))

              (wcmatch (setq layerName (strcase (vla-get-Layer vlaObject) t)) filteredLayers)

              (wcmatch (setq blockName (strcase (GetBlockName vlaObject) t)) filteredBlockNames)

              (setq ResultatsBlocks (cdr (assoc layerName ResultatsLayersBlocks)))

              (setq ResultatsBlock (assoc blockName ResultatsBlocks))

         )

     (progn

        (setq Total (1+ (cdr ResultatsBlock)))

        (setq ResultatsBlocks (subst (cons blockName Total) (assoc blockName ResultatsBlocks) ResultatsBlocks)) 

        (setq ResultatsLayersBlocks (subst (cons layerName ResultatsBlocks) (assoc layerName ResultatsLayersBlocks) ResultatsLayersBlocks)) 

     ))

  )


  (if (and ResultatsLayersBlocks excludeEmptyRows)

  (progn

     ;; Nettoyage des lignes vides

     (setq ResultatsLayersBlocks (vl-remove-if '(lambda (x) (= 0 (apply '+ (mapcar 'cdr (cdr x))))) ResultatsLayersBlocks))

  ))


  (if (and ResultatsLayersBlocks excludeEmptyColumns)

  (progn

     ;; Nettoyage des colonnes vides

     (setq j (length BlockNames))

     (while (> j 0)

        (setq j (1- j))

        (setq BlockName (nth j BlockNames))

        (if (= 0 (apply '+ (mapcar '(lambda (x) (cdr (nth j (cdr x)))) ResultatsLayersBlocks)))

        (progn

           (setq ResultatsLayersBlocks (mapcar '(lambda (x) (cons (car x) (vl-remove-if '(lambda (y) (= BlockName (car y))) (cdr x)))) ResultatsLayersBlocks))

           (setq BlockNames (vl-remove-if '(lambda (x) (= x BlockName)) BlockNames))

        ))

     )

  ))


  ;; Dessiner le tableau, s'il reste des calques et des blocs après épuration

  (if (> (* (length BlockNames) (length ResultatsLayersBlocks)) 0)

  (progn

    (setq NumRows (+ 2 (length ResultatsLayersBlocks)))     ; 2 lignes de titre

    (setq NumColumns (+ 1 (length BlockNames)))             ; 1 colonne de plus pour les noms de calque

    (setq Point3D_UCS (getpoint "\nPoint d'insertion: "))

    (setq Point3D_WCS (trans Point3D_UCS 1 0))  ; Si pas en WCS

    (setq vlaPoint3D (PointToVariant Point3D_WCS))

    (setq CurrentlayerWasLocked (= :vlax-true (vla-get-lock (vla-get-ActiveLayer ThisDrawing))))

    (if CurrentlayerWasLocked (vla-put-lock (vla-get-ActiveLayer ThisDrawing) :vlax-false))

    (setq vlaTableau (vla-AddTable ModelSpace vlaPoint3D NumRows NumColumns RowHeight ColWidth))


    ;; Ligne 0

    (setq row 0)

    (setq column 0)

    (SetCellProperties vlaTableau row column "Résultats" textsize acMiddleCenter nil)


    ;; Ligne 1

    (setq row 1)

    (setq column 0)

    (while (< column (length BlockNames))

       (SetCellProperties vlaTableau row (1+ column) (nth column BlockNames) textsize acMiddleCenter (cons acHorzBottom LineWeightMedium))

       (setq column (1+ column))

    )


    ;; Lignes de résultat

    (setq i 0)

    (setq n (length ResultatsLayersBlocks))

    (while (< i n)

       (setq ResultatsBlocks (nth i ResultatsLayersBlocks))

       (setq row (+ i 2))  ; On saute les 2 lignes de titre


       ;; LayerName

       (setq column 0)

       (setq LayerName (car ResultatsBlocks))

       (SetCellProperties vlaTableau row column LayerName textsize acMiddleLeft nil)


       ;; Quantité

       (setq j 0)

       (setq m (length BlockNames))

       (setq ResultatsBlocks (cdr ResultatsBlocks))

       (while (< j m)

          (setq column (1+ j))  ; On saute la colonne des noms de calque

          (setq Count (cdr (nth j ResultatsBlocks)))

          (SetCellProperties vlaTableau row column (itoa Count) textsize acMiddleCenter nil)

          (setq j (1+ j))

       )


       (setq i (1+ i))

    )

    (if CurrentlayerWasLocked (vla-put-lock (vla-get-ActiveLayer ThisDrawing) :vlax-true))

  ))

  (princ)

)


(defun SetCellProperties (

  vlaTableau Row Column Texte TextHeight Alignment LineWeightPair

  )

  ;; Gère les propriétés populaires des cellules d'un tableau

  ;;    vlaTableau Row Column : Obligatoire, les autres sont facultatifs

  ;;    Row, Column : INT, base 0

  ;;    Alignment: INT, 

  ;;    LineWeightPair: nil, sinon (cons "AcGridLineType enum" "acad_lweight enum"), soit (cons Position Épaisseur)

  ;; Support pour Acad2006 et Acad2009

  (if LineWeightPair (vla-SetCellGridLineWeight vlaTableau Row Column (car LineWeightPair) (cdr LineWeightPair)))

  (if Alignment (vla-SetCellAlignment vlaTableau Row Column Alignment))

  (if TextHeight (vla-SetCellTextHeight vlaTableau Row Column TextHeight))

  (if Texte

     (if vla-SetCellValue 

        (vla-SetCellValue vlaTableau Row Column Texte) ; AutoCAD 2009

        (vla-SetText vlaTableau Row Column Texte)      ; AutoCAD 2006

     )

  )

)


;;; PointToVariant

;;; Conversion de Point2D ou Point3D en variant

(defun PointToVariant (

  point

/ arraySpace sArray

  )

  (setq arraySpace (vlax-make-safearray vlax-vbDouble (cons 0 (1- (length point)))))

  (setq sArray (vlax-safearray-fill arraySpace point))

  (vlax-make-variant sArray)

)


;;; Obtenir le nom du bloc (accepte les blocs dynamiques)

(defun GetBlockName (vlaBlock)

  (if (vlax-property-available-p vlaBlock 'EffectiveName) (vla-get-EffectiveName vlaBlock) (vla-get-Name vlaBlock))

)

mikl63 · le 5 mars 2017

Merci à Serge du coup. Le lien vers le sujet : http://cadxp.com/topic/20057-lisp-pour-recopier-longueur-totale-des-polylignes-dun-calque-dans-un-textmult/

Connexion

Compte des polylignes

Messages recommandés

mikl63

DenisHen

mikl63

DenisHen

mikl63

lecrabe

Aleck_Ultimate

DaWeeD_Gab

Red

Eric

DenisHen

Eric

DenisHen

rebcao

Aleck_Ultimate

mikl63

mikl63

Forums

Naviguer

Activité

Information importante