[Résolu] Ajouter un delta unique

[grand_sapin]

Bonjour,

 

je suis sûr d'avoir déjà vu un sujet pareil sur le forum mais je n'arrive pas à remettre les yeux dessus

 

Y a-t-il un moyen de rajouter un delta sur toute mes étiquettes de nivellement de mon projet ?

Le levé topo qu'on m'avait filé était en local, j'ai donc fait mon nivellement en conséquence, mais là on vient de le mettre à jour en LAMBERT, et du coup j'ai 48.57 m de différence entre le local et le référencé.

J'aimerai donc ajouter cette valeur en plus de chaque altitude qui sont inscrites dans mes blocs niveau.

 

D'avance Merci

Sapin

[x_all]

tu dois chercher ça...

http://cadxp.com/index.php?/topic/25182-ngf-ajouter-une-valeur-a-un-attribut/

[grand_sapin]

Ça à l'air d'être ça, mais cela ne fonctionne pas, j'imagine que c'est parce que c'est un bloc dynamique ...

[-Olivier-]

Bonjour grand_sapin,

Après avoir jeté un coup d'œil rapide au code, je confirme qu'il ne peux fonctionner en l'état sur un bloc dynamique. Je n'ai malheureusement pas le temps de le modifier aujourd'hui.

En faisant une petite demande de mise à jours sur le poste d'origine, un lispeur pourrais passer part là !

Olivier

[bryce]

Bonjour,

 

Essaie avec ceci (petite modif vite faite du code de (gile), les blocs ne seront plus filtrés d'après leur nom):

 

(defun c:att_add (/ att lst tag add ss n)
 (if (and
       (setq att (car (nentsel "\nSélectionnez un attribut à modifier: ")))
       (setq lst (entget att))
       (= (cdr (assoc 0 lst)) "ATTRIB")
       (numberp (read (cdr (assoc 1 lst))))
       (setq tag (cdr (assoc 2 lst)))
     )
   (if (and
         (setq add (getreal "\nEntrez la valeur à ajouter ou soustraire: "))
         (princ "\nSélectionnez les blocs à modifier.")
         (setq ss (ssget '((0 . "INSERT"))))
         (setq n 0)
       )
     (while (setq blc (ssname ss n))
       (setq att (entnext blc)
             lst (entget att)
       )
       (while (= (cdr (assoc 0 lst)) "ATTRIB")
         (if (and (= (cdr (assoc 2 lst)) tag)
               (numberp (setq val (read (cdr (assoc 1 lst)))))
             )
           (progn
             (entmod (subst (cons 1 (rtos (+ val add)))
               (assoc 1 lst)
               lst
               )
             )
             (entupd blc)
           )
         )
         (setq att (entnext att)
               lst (entget att)
         )
       )
       (setq n (1+ n))
     )
   )
 (princ "\nL'objet sélectionné n'est pas un attribut.")
 )
 (princ)
)

[grand_sapin]

Génial,

 

Merci Bryce

[lili2006]

Bonjour à toutes et tous,

 

Avec Covadis => Cov 2D => Points Topo => Modification des Z =

 

(C'est comme ça que font les topos avec les blocs point "TCPOINT" de manière à ce que l'attribut "Z" et l'élévation du bloc point soit ok !)

[grand_sapin]

J'ai essayé, mais il ne considère pas mon bloc comme point topo !

[lili2006]

Re,

 

dans mes blocs niveau.

Je croyais que c'était des TCPOINTS "covadis", désolé,...