NGF ajouter une valeur a un attribut

[zin29]

Boujour voila un de mes problemes.

j' ai deux releves de geometre pour la meme zone et ils n ont pas le meme ngf de reference. Peut-on faire une addition rapidement de la valeur de l' attribut ALT du bloc point TOPO avec la difference de l autre pour realiser une correspondance de niveau.

 

merci d' avance

[lecrabe]

 

Hello

 

Que penses tu de cette excellente routine de Gilles ! :)

 

Encore Merci a Gilles, Le Decapode

 

 

;; Commande:  ATT_ADD 
;; par Gilles (Anciennement ADDATT)
;; Pour ajouter/soustraire une valeur numerique a un attribut

(defun c:att_add (/ att lst tag nam add ss n)
(if (and
(setq att (car (nentsel "\nSélectionnez un attribut à modifier: ")))
(setq lst (entget att))
(= (cdr (assoc 0 lst)) "ATTRIB")
(numberp (read (cdr (assoc 1 lst))))
(setq tag (cdr (assoc 2 lst)))
(setq nam (cdr (assoc 2 (entget (cdr (assoc 330 lst))))))
)
(if (and
(setq add (getreal "\nEntrez la valeur à ajouter ou soustraire: "))
(princ "\nSélectionnez les blocs à modifier.")
(setq ss (ssget (list '(0 . "INSERT") (cons 2 nam))))
(setq n 0)
)
(while (setq blc (ssname ss n))
(setq att (entnext blc)
lst (entget att)
)
(while (= (cdr (assoc 0 lst)) "ATTRIB")
(if (and (= (cdr (assoc 2 lst)) tag)
(numberp (setq val (read (cdr (assoc 1 lst)))))
)
(progn
(entmod (subst (cons 1 (rtos (+ val add)))
(assoc 1 lst)
lst
)
)
(entupd blc)
)
)
(setq att (entnext att)
lst (entget att)
)
)
(setq n (1+ n))
)
)
(princ "\nL'objet sélectionné n'est pas un attribut.")
)
(princ)
)  

 

 

[zin29]

Merci le crabe je l' avais oublié cette super routine de giles.

 

encore merci