Liste calques gelés ou activés

[jalna]

Bonjour

Comment faire une icone qui me listerait uniquement les calques gelés et désactives dans une Form (uniquement pour info avant impression, car il m'arrive souvent de laisser des calques gelés ou désactivés lors d'une impression.........)

 

J'ai mis la question dans ce forum mais elle peut s'adapter dans les autres...

Merci

[bryce]

Bonjour,

 

Un petit Lisp vite fait:

 

(defun c:VISVERIF ( / layers liste )

 (vl-load-com)
 
 (setq layers (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
       liste '()
 )
 (vlax-for lay layers
   (if (or
         (= (vla-get-LayerOn lay) :vlax-false)
         (= (vla-get-Freeze lay) :vlax-true)
       )
     (setq liste (cons (vla-get-Name lay) liste))
   )
 )
 (if liste
   (progn
     (princ "\nListe des calques désactivés ou gelés:")
     (princ "\n--------------------------------------")
     (mapcar '(lambda (x) (princ (strcat "\n" x))) (reverse liste))
     (princ "\n--------------------------------------")
     (textpage)
   )
   (princ "\nAucun calque gelé ou désactivé.")
 )
 (princ)
)

 

Le résultat s'affichera dans la bonne vieille fenêtre de texte. ;)

Tu peux utiliser APPLOAD ou le fichier AutoCAD.lsp pour charger automatiquement la routine dans chaque dessin, et créer une icône avec la macro suivante:

^C^CVISVERIF

[jalna]

Salut

Merci ça fonctionne nickel!!

Peut on séparer les calques des xrefs?

Je suis gourmand!!

En tous cas c'est bien efficace

[bryce]

Bonjour,

 

(defun c:VISVERIF ( / layers nom liste xliste )

 (vl-load-com)
 
 (setq layers (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
       liste '()
       xliste '()
 )
 (vlax-for lay layers
   (if (or
         (= (vla-get-LayerOn lay) :vlax-false)
         (= (vla-get-Freeze lay) :vlax-true)
       )
     (if (wcmatch (setq nom (vla-get-Name lay)) "*|*")
       (setq xliste (cons nom xliste))
       (setq liste (cons nom liste))
     )
   )
 )
 
 (if liste (setq liste(cons "\nCalques du dessin:\n" (reverse liste))))
 (if xliste (setq xliste(cons "\nCalques des XRefs:\n" (reverse xliste))))
 
 (if (or liste xliste)
   (progn
     (princ "\nListe des calques désactivés ou gelés:")
     (princ "\n--------------------------------------")
     (mapcar '(lambda (x) (princ (strcat "\n" x))) (append liste xliste ))
     (princ "\n--------------------------------------")
     (textpage)
   )
   (princ "\nAucun calque gelé ou désactivé.")
 )
 (princ)
)

 

;)

[jalna]

Ben voila!

 

Excellent merci beaucoup!!

[lili2006]

Bonjour à toutes et tous,

 

Pour aller encore plus loin, est-il possible de différencier les calques gelés de ceux qui sont désactivés ?

 

Merci d'avance,

[GEGEMATIC]

Bonjour à toutes et tous,

 

Pour aller encore plus loin, est-il possible de différencier les calques gelés de ceux qui sont désactivés ?

 

Merci d'avance,

Salut,

je pense que la manière la plus rationnelle de traiter ce problème n'est pas la programmation, mais la création de filtre de propriété de calque.

 

On peut donc faire un filtre général "calque invisibles" regroupant, gelés, inactivés et non imprimable, et des sous filtre pour chaque catégorie.

 

Je crois que Gile et patrick35 on créés des outils pour générer des filtre de calques, là c'est intéressant.

Gégé

[lili2006]

Bonjour à toutes et tous,

 

Merci de te réponse GEGEMATIC .

 

Bien entendu mais cette info en ligne de commande me plaisait bien aussi pour un dernier contrôle avant tracé par exemple,...

[tyrese69_]

Bonjour,

les dos lib de mac neel

Permettent d'avoir une listbox très simplement

 

(defun c:LstCG ( / layers liste )

(vl-load-com)

(setq layers (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))

liste '()

xliste '()

)

(vlax-for lay layers

(if (or

(= (vla-get-LayerOn lay) :vlax-false)

(= (vla-get-Freeze lay) :vlax-true)

)

(if (wcmatch (setq nom (vla-get-Name lay)) "*|*")

(setq xliste (cons nom xliste))

(setq liste (cons nom liste))

)

)

)

(dos_listbox "Technip TPS" "Couches GELEES ou INACTIVES" liste)

(dos_listbox "Technip TPS" "Couches Xrefs GELEES ou INACTIVES" xliste)

 

(if liste (setq liste(cons "\nCalques du dessin:\n" (reverse liste))))

(if xliste (setq xliste(cons "\nCalques des XRefs:\n" (reverse xliste))))

 

(if (or liste xliste)

(progn

(princ "\nListe des calques désactivés ou gelés:")

(princ "\n--------------------------------------")

(mapcar '(lambda (x) (princ (strcat "\n" x))) (append liste xliste ))

(princ "\n--------------------------------------")

(textpage)

)

(princ "\nAucun calque gelé ou désactivé.")

)

(princ)

 

)

[tyrese69_]

Re bonjour,

Dans le même esprit il aussi bon d'avoir la liste des couches gelées ou inactives dans les fenêtres !

 

Vaste sujet:

 

Daniel OLIVES