Export des textes vers un fichier Excel

[salvanorigatore]

Bonjour,

est-ce que quelqu'un connait un outils existant ou un lisp ou bien quelqu'un saurait-il fabriquer un petit lisp qui fasse ceci : ?

- Extraction de tous les textes d'un calque donné (ou de tous les textes d'un dessin) et export vers un fichier Excel avec un texte par case en colonne ou en ligne

Merci beaucoup d'avance.

Bonne journée à tous.

[bryce]

Bonjour,

 

Ça peut se faire tout simplement avec la fonction d'extraction de données. ;)

[salvanorigatore]

Bonjour bryce,

désolé pour mon ignorance :red: mais peut-tu me dire où se trouve cette fonction dans AutoCAD ou me donner le nom de la commande qui fait cela ?

Merci beaucoup d'avance.

[bryce]

Dans le menu Outils > Extraction de données (ou commande EXTRACTDONNEES). :)

[salvanorigatore]

bryce il y a un souci quelque part :P

Est-ce que tu parle bien d'AutoCAD 2007 ?

Parce dans mon menu texte il n'y a pas la ligne [surligneur]"Extraction de données"[/surligneur] dans le menu Outils :casstet:

En plus quand je tape la commande EXTRACTDONNEES la seule réponse que j'ai c'est [surligneur]"Commande inconnue "EXTRACTDONNEES". Appuyez sur F1 pour obtenir de l'aide.[/surligneur]

Je ne sais pas quelle version d'AutoCAD tu a mais ce qui est sûr c'est que ce n'est pas la même que moi :hallucine:

Merci quand même d'avoir essayé.

Cela veut dire que mon sujet est toujours ouvert.

Merci aux bonnes volontés.

[bryce]

Il me semble de mémoire que la fonction en question existe depuis AutoCAD 2006...

Est-ce que tu n'utiliserais pas en réalité AutoCAD LT 2007 ?

Dans ce cas en effet, cette fonction n'existe pas (et tu ne pourras pas utiliser de LISP non plus...). :casstet:

[bryce]

Oups désolé...

Je viens de vérifier et l'extraction de données n'existe que depuis la 2008... :red:

J'espère que ce n'est pas déjà Alzheimer... :mad2:

[bonuscad]

Un bout de code que j'avais écris à je ne sais quelle occasion.

 

Il crée un fichier au format CSV qui est facilement lu par Excel.

 

(defun c:text_value2csv ( / js dxf_cod mod_sel n lremov file_name cle f_open ename l_pt l_pr nbs)
 (princ "\nChoix d'un objet modèle pour le filtrage: ")
 (while
   (null
     (setq js
       (ssget "_+.:E:S"
         (list
           '(0 . "*TEXT")
           (cons 67 (if (eq (getvar "CVPORT") 1) 1 0))
           (cons 410 (if (eq (getvar "CVPORT") 1) (getvar "CTAB") "Model"))
         )
       )
     )
   )
   (princ "\nCe n'est pas un objet valable pour cette fonction!")
 )
 (vl-load-com)
 (setq dxf_cod (entget (ssname js 0)))
 (foreach m (foreach n dxf_cod (if (not (member (car n) '(0 67 410 8 6 62 48 420 70))) (setq lremov (cons (car n) lremov))))
   (setq dxf_cod (vl-remove (assoc m dxf_cod) dxf_cod))
 )
 (initget "Unique Tout Manuel _Single All Manual")
 (if (eq (setq mod_sel (getkword "\nMode de sélection filtrée, choix [unique/Tout/Manuel]: ")) "Single")
   (setq n -1)
   (if (eq mod_sel "All")
       (setq js (ssget "_X" dxf_cod) n -1)
       (setq js (ssget dxf_cod) n -1)
   )
 )
 (setq file_name (getfiled "Nom du fichier a créer ?: " (strcat (substr (getvar "dwgname") 1 (- (strlen (getvar "dwgname")) 3)) "csv") "csv" 37))
 (if (null file_name) (exit))
 (if (findfile file_name)
   (progn
     (prompt "\nFichier éxiste déjà!")
     (initget "Ajoute Remplace annUler _Add Replace Undo")
     (setq cle
       (getkword "\nDonnées dans fichier? [Ajouter/Remplacer/annUler] : ")
     )
     (cond
       ((eq cle "Add")
         (setq cle "a")
       )
       ((or (eq cle "Replace") (eq cle ()))
         (setq cle "w")
       )
       (T (exit))
     )
     (setq f_open (open file_name cle))
   )
   (setq f_open (open file_name "w"))
 )
 (repeat (sslength js)
   (setq ename (vlax-ename->vla-object (ssname js (setq n (1+ n)))) l_pt nil)
   (setq l_pr (list 'TextString) nbs 0)
   (foreach n l_pr
     (if (vlax-property-available-p ename n)
       (setq l_pt
         (cons (vlax-get ename n) l_pt)
       )
     )
   )
   (foreach n l_pt
     (write-line n f_open)
   )
   (write-line "" f_open)
 )
 (close f_open)
 (prin1)
)

[Patrick_35]

Salut

 

Ou encore LXL

 

@+

[salvanorigatore]

merci bonus c'est juste ce qu'il me fallait :D

 

Une petite remarque si tu connais la réponse :

pourquoi quand il y a des accents dans ton lisp AutoCAD m'écrit des choses style " Mode de sélection filtrée, choix" ? :P

 

 

Patrick_35 je ne savais pas que LXL faisait aussi ça je croyais que c'était "juste" pour "Lier des Attributs, Textes, Mtexts ou des Rtexts avec Excel." ? :question:

 

merci en tout cas

[bonuscad]

pourquoi quand il y a des accents dans ton lisp AutoCAD m'écrit des choses style " Mode de sélection filtrée, choix" ?

 

???

 

Tu es le 1er a me rapporter ceci...

Je n'ai pas la réponse, je pense que c'est simplement une histoire de police avec une page de code non approprié utilisé avec le navigateur.

Avec firefox je suis en encodage de caractères: occidental (iso 8859-1)

 

 

[Patrick_35]

Salut

 

Patrick_35 je ne savais pas que LXL faisait aussi ça je croyais que c'était "juste" pour "Lier des Attributs, Textes, Mtexts ou des Rtexts avec Excel." ? :question:

 

Une fois lié, l'import/export n'est plus qu'un jeu d'enfant

 

@+