Select Lisp (help)

[Pako]

Slt les mecs,

 

Pouvez-vous m'aider ca marche pas ? Mon but est de selectionner un bloc nommé "BINC" est de dessiner un cercle d'après son point d'insertion.......Facile pour des pro comme vous ! Merci !

;*******************************************************************

(defun c:ccb ()

 

;(setq selec (ssget "X" '((2 . "BINC"))))

(setq selec (ssget "x"))

(if

(= selec nil)

(alert "AUCUNE BORNE D'INCENDIE SÉLECTIONNÉ")

(progn

(setq PT (cdr (assoc 10 selec)))

(command "_.circle" PT "d" "2.0")

(princ)

 

);progn close

);if close

);defun close

 

;*********************************************************************

[bonuscad]

Voilà trés rapidement

(defun c:ccb ( / selec nbel ent pt)
(setq selec (ssget "X" '((2 . "BINC"))))
(if selec
	(progn
		(setq nbel (sslength selec) i 0)
		(repeat nbel
			(setq ent (entget (ssname selec i)))
			(setq pt (cdr (assoc 10 ent)))
			(command "_.circle" pt "_diameter" "2.0")
			(setq i (1+ i))
		)
	)
	(alert "AUCUNE BORNE D'INCENDIE SÉLECTIONNÉ")
)
(princ)
)

 

Y A PU KA ;)

[Pako]

 

 

Une petite modif, je veux selectionné le bloc pour appliquer le cercle, et

non tous les blocs de mon dessin .......

 

 

Merci bonuscad ! une petite facile !

 

[zebulon_]

il suffit d'enlever le "X" dans la commande ssget. ;)

 

Sinon, pour la grammaire, borne est féminin donc sélectionnée aussi. :D

[bru]

Voilà trés rapidement

(defun c:ccb ( / selec nbel ent pt)
(setq selec (ssget "X" '((2 . "BINC"))))
(if selec
	(progn
		(setq nbel (sslength selec) i 0)
		(repeat nbel
			(setq ent (entget (ssname selec i)))
			(setq pt (cdr (assoc 10 ent)))
			(command "_.circle" pt "_diameter" "2.0")
			(setq i (1+ i))
		)
	)
	(alert "AUCUNE BORNE D'INCENDIE SÉLECTIONNÉ")
)
(princ)
)

 

 

et d'ailleurs, une petite function géniale:

 

(defun sslist (ss / n lst)
 (if (= 'PICKSET (type ss))
   (repeat (setq n (sslength ss))
     (setq lst (cons (ssname ss (setq n (1- n))) lst))
     )
   )
 )

 

avec cela:

 

(mapcar

'(lambda (x) (command "_.circle" (cdr (assoc 10 (entget x))) "_diameter" "2.0"))

(sslist (ssget '((2 . "bind"))))

)

 

checkez les parrenthèses ;)

 

 

 

[Pako]

Merci beaucoup à tous ! vous êtes tous sympa !