Ajouter valeur constante à un ensemble de texte ?

[MNT]

Bonjour,

 

après moult recherches sur le site je n'ai pas réussis à trouver mon bonheur.

 

je que je cherche à faire:

 

lors de projet en déblais/remblais,en phase exécution après le décapage du terrain naturel on fait un relevé du TN décapé pour rééquilibrer les volumes.

 

Jusque là pas de problème,le hic c'est que le plan d'exécution à déjà été réalisé,que le projet altimétrique à été modifié et que pour le moment je reprends les textes un par un.

 

je connais déjà la solution d'utiliser les pts topo de Covadis et de faire la manip avec Covadis.

 

je voudrais savoir si la chose est possible avec de simples textes ?

 

Bonne fêtes.

 

 

[(gile)]

Salut,

 

Il me semblait bien avoir vu quelque chose là dessus, mais c'est peut-être ailleurs.

 

Donc, un petit LISP vite fait

 

(defun c:str+const (/ ndec add2str const sset ind txt str)

 (defun ndec (str / pos)
   (if	(setq pos (vl-string-position 46 str 1 t))
     (- (strlen str) pos 1)
     0
   )
 )

 (defun add2str (str add / dec)
   (if	(zerop (setq dec (max (ndec str) (ndec add))))
     (itoa (+ (atoi str) (atoi add)))
     (rtos (+ (atof str) (atof add)) 2 dec)
   )
 )

 (while
   (not
     (and
(setq const (getstring "\nEntrez la valeur à ajouter: "))
(numberp (read const))
     )
   )
    (princ "\nNécessite un nombre.")
 )
 (if
   (and
     (setq sset (ssget '((0 . "TEXT"))))
     (setq n 0)
   )
    (while (setq txt (ssname sset n))
      (setq elst (entget txt)
     str  (cdr (assoc 1 elst))
     n	  (1+ n)
      )
      (if (numberp (read str))
 (entmod
   (subst (cons 1 (add2str str const)) (cons 1 str) elst)
 )
      )
    )
 )
 (princ)
)

[MNT]

Salut (gile)

 

merci pour le lisp , j'essayerais Lundi

 

Bon WK et bonne fête à toi et aux tiens

 

@micalement