transformer un arc en lignes

[ahmednassim]

je veux savoir comment peut on transformer un arc en segement de lignes sous autocad

 

Merci

[(gile)]

Salut et bienvenue,

 

Un petit LISP qui, j'espère, répond à ta demande.

 

(defun c:arc2lines (/ ent nb obj n dist lst)
 (vl-load-com)
 (if (and (setq ent (car (entsel "\nSélectionnez un arc: ")))
   (= (cdr (assoc 0 (entget ent))) "ARC")
     )
   (progn
     (initget 7)
     (setq nb	 (getint "\nEntrez le nombre de segments: ")
    obj	 (vlax-ename->vla-object ent)
    dist (/ (vlax-curve-getDistAtParam
	      obj
	      (vlax-curve-getEndParam obj)
	    )
	    nb
	 )
    lst (list (vlax-curve-getStartPoint obj))
    n	 0
     )
     (repeat nb
(setq
  lst
   (cons
     (vlax-curve-getPointAtDist obj (* dist (setq n (1+ n))))
     lst
   )
)
     )
     (while (cdr lst)
(entmake (list '(0 . "LINE")
	       (cons 10 (car lst))
	       (cons 11 (cadr lst))
	 )
)
(setq lst (cdr lst))
     )
     (entdel ent)
   )
   (prompt "\nEntité non valide.")
 )
 (princ)
) 

 

[Edité le 12/9/2008 par (gile)]

[ahmednassim]

merci mais pouvez me l'exporter en tant que fichier lisp parceque je sais pas comment utilisé le code

[(gile)]

Re,

 

Il suffit de copier le code,

le coller dans le bloc-note (Windows),

l'enregistrer avec l'extension .lsp,

le charger dans AutoCAD,

taper arc2lines à la ligne de commande.

[ahmednassim]

j'ai fait ce vous m'avez dit et je ouvre autocad2004 je clique sur outil\autolisp\charger une boite de dialogue s'ouvre je selectionne le fichier puis je clique sur le bouton charger et il se charge pas

[ahmednassim]

il me donne le message: erreur: type d'argument incorrect:

désolé pour le derangement

[ahmednassim]

il me donne le message: erreur: type d'argument incorrect:

désolé pour le derangement

[(gile)]

Le nom du fichier est il du type : arc2lines.lsp ?

[ahmednassim]

voila c'est ce qu'il me donne comme messages:

 

Commande: _appload arc2lines.lsp correctement chargé(s)

 

 

Commande: ; erreur: type d'argument incorrect: numberp: nil

 

Commande:

Commande: arc2lines

Commande inconnue "ARC2LINES". Appuyez sur F1 pour obtenir de l'aide.

 

[(gile)]

Une fois que le LISP est chargé, après avoir tapé arc2lines à la ligne de commande, il faut répondre aux invites de la ligne de commande :

 

Commande: ARC2LINES

 

Sélectionnez un arc:

Entrez le nombre de segments: 5

 

 

[ahmednassim]

le lispe il se charge pas correctement puisque il me donne le message: "Commande: ; erreur: type d'argument incorrect: numberp: nil

Commande:"

 

[ahmednassim]

Merci baucoup gile ca marché

[didier]

Bonjour,

 

je viens répondre car je constate que AhmedNassim poste également dans le forum Covadis,

 

c'est une fonction intégrée de Covadis, donc, c'est bien pour la culture générale de savoir qu'on peut lisper mais il faut déjà se servir de ce qui existe....

 

amicalement

 

 

[DomLearn]

Je travaille sur les version Autocad 2008 et 2009 , et j'obtiens le message d'erreur ci-après.

Une mise à jour du lisp serait-elle nécessaire ... (Gile) ... au secours

 

 

Commande: ARC2LINES

 

Sélectionnez un arc:

Entrez le nombre de segments: 5

; erreur: no function definition: VLAX-ENAME->VLA-OBJECT

 

:(

[(gile)]

Salut,

 

Un oubli classique : (vl-load-com) en début de routine pour charger les fonctions Visual LISP.

 

J'ai modifié le code ci-dessus.

[DomLearn]

Super ... ça marche

 

Merci Gile

:D