Imprimer toute une directorie

[serge77]

Bonjour,

 

Je suis sure que l'on peu le faire simplement mais je ne trouve pas comment.

Je voudrais imprimer toute les fichiers contenu dans une meme directorie en une seule fois, sachant que quel que soit le format du plan, je veux tout imprimer en A3 étndu avec mise à l'echelle du papier.

J'en pense que vous allez pouvoir m'aider et je vous en remercie d'avance

Serge

[Pieroka]

le plus simple pour imprimer des présentations qui se trouvent dans plusieurs dwg qui sont dans le même répertoire, c'est de créer un "jeu de feuille" (sheet set) à partir des "présentations" (onglets) existants dans les dwg du répertoire.

 

pour cela il faut créer un nouveau jeu de feuille (sheet set) et là autocad te demandera dans quel répertoire sont tes dwg.

Une fois le jeu de feuille crée ,il n'y a plus qu'à le publier.

 

http://xs304.xs.to/xs304/06305/sheetset.jpg

[Patrick_35]

Salut

 

créer un "jeu de feuille"

Oui, mais pour cela, on est obligé de reconfigurer toutes les présentations

Sinon, avec ce lisp qui créé un script

 

(defun c:scr(/ fic fscr lst n)
 (if (setq fic (getfiled "Impression de plusieurs Fichiers - Sélectionnez un fichier cible" (getvar "dwgprefix") "dwg" 16))
   (progn
     (setq lst (acad_strlsort (vl-directory-files (vl-filename-directory fic) "*.dwg" 1))
           fscr (open (strcat (vl-filename-directory fic) "\\SCRIPT.SCR") "w") n 0)
     (while (nth n lst)
       (write-line (strcat "_.open " (chr 34) (vl-filename-directory fic) "\\" (nth n lst) (chr 34)) fscr)
       (write-line "(acad-push-dbmod)" fscr)

;=======================================================================================
; Début de Partie personnalisable
;=======================================================================================
       
       (write-line "(command \"_.plot\" \"o\" \"Choix Presentation\" \"Adresse du traceur\" \"A3\" \"m\" \"p\" \"n\" \"e\" \"p\" \"c\" \"o\" \"Style de tracé\" \"o\" \"\" \"n\" \"n\" \"o\")" fscr)

;=======================================================================================
; Fin de Partie personnalisable
;=======================================================================================

       (write-line "(acad-pop-dbmod)" fscr)
       (write-line "(if (zerop (getvar \"sdi\"))" fscr)
       (write-line "  (command \"_.close\")" fscr)
       (write-line ")" fscr)
       (setq n (1+ n))
     )
     (close fscr)
     (princ (strcat "\n\tFichier " (vl-filename-directory fic) "\\SCRIPT.SCR créé"))
   )
 )
 (princ)
)

 

@+

[serge77]

Bonjour Patrick,

 

Ta solution me parait plus simple, les plans n'étant pas tous sauvegardés avec les bonnes impressions.

Mais peux-tu developper un peu plus la ligne avec toutes les otpions du traceur car je suis un peu perdu.

Merci d'avance

[Pieroka]

dans ce cas tu publie ton jeu de feuilles en un seul dwf quue tu imprimes d'un coup en A3 étendu avec dwf viewer

[Patrick_35]

(write-line "(command \"_.plot\" \"o\" \"Choix Presentation\" \"Adresse du traceur\" \"A3\" \"m\" \"p\" \"n\" \"e\" \"p\" \"c\" \"o\" \"Style de tracé\" \"o\" \"\" \"n\" \"n\" \"o\")" fscr)

Quand tu fais sur la ligne de commande -traceur, tu suis ce que t'indique autocad et tu vas retrouver lce que je t'ai cité

ex : commande:-traceur

>Configuration de tracé détaillée? [Oui/Non] : o

>Entrez un nom de présentation ou [?] :Présentation1

>Entrez un nom de périphérique de sortie ou [?] :Un traceur

>Entrez une taille de papier ou [?] :A4

>etc...

 

Ce qui donne (write-line "(command "_.plot" "o" "Présentation" "Un traceur" "A4" etc... )" fscr)

et comme autocad interprète mal dans ce cas les guillemetsdans le command, il faut ajouter un \ devant

Ce qui donne (write-line "(command \"_.plot\" \"o\" \"Présentation\" \"Un traceur\" \"A4\" etc... )" fscr)

 

@+

[serge77]

pour mon traceur, j'ai un \ et il ne le prend pas en compte, j'ai essayé avec un / mais il ne trouve pas mon traceur.

Je suis bloqué par la syntaxe.

 

[Patrick_35]

Il faut en ajouter plusieurs. Un \ doit donner \\ et un \\ donne un \\\\

En lisp, un \ veux dire que ce qui suit doit être pris comme un caractère

[serge77]

Merci beaucoup,

 

j'ai tout compris, ca marche nickel

Encore merci

A+

Serge