Rotation à une fenêtre de présentation...

[yalta]

Bonjour à toutes et à tous,

 

:P Pour faire simple: je suis dans l'espace papier et je désire exécuter une rotation (90° par exemple) à l'ensemble de ma présentation.

Mon souci, comme vous pouvez l'imaginer, est au niveau de ma fenêtre de présentation qui, elle, reste à son état d'origine.

J'y arrive bien sûr avec les SCU en activant ma fenêtre mais y-a-t-il un moyen plus rapide et tout aussi efficace..?? :casstet: :casstet:

 

Merci à vous,

 

Sylvain

[rimbo]

3 méthodes :

 

1) si tu fais un scu spécifique dans l'espace objet je t'encourage a suivre celle là :

tu nommes ton nouveau scu, puis affichage/point vue 3D/vue en plan scu/scu courant

ensuite tu présente (toujours dans l'espace Objt) au mieux ta vue et tu récupères soit la barre outil soit juste le bouton vue existante, soit par le menu et dans la boite de dialogue tu fais nouveau tu nommes la vue pour t'en souvenir ( nom de rue ou de profil...) puis OK.

Dans l'espace papier, tu double clic pour ouvrir dans ta fenetre l'EO, et la tu retourne dans la boite de dialogue vue existante tu la sélectionne oK et c'est tout bon, plus qu'a gérer l'échelle.

 

2) facile : vue dyn

 

3) mvsetup puis a puis r et tu donne un angle, chaque fois que tu renouvelle la commande la valeur revient à 0

 

 

a+

[bonuscad]

Une bidouille en lisp pour tourner une fenetre de présentation de 90° en + ou -.

NB: ne fonctionne pas si la vue est verrouillé, j'ai pas paufiné. ;)

 

(defun c:r_viewport ( / e_vport dxf_vport base_pt lg_view ht_view h_vue pt_ctr-view pt_dl pt_ur)
(cond
	((zerop (getvar "TILEMODE"))
		(setvar "CMDECHO" 0)
		(command "_.undo" "_begin")
		(if (/= (getvar "CVPORT") 1)
			(command "_.pspace")
		)
		(setq e_vport nil dxf_vport nil)
		(while (null e_vport)
			(setq e_vport (ssget "_+.:E:S" '((0 . "VIEWPORT"))))
			(if e_vport (setq e_vport (ssname e_vport 0)))
		)
		(setq
			dxf_vport (entget e_vport)
			base_pt (cdr (assoc 10 dxf_vport))
			lg_view (cdr (assoc 40 dxf_vport))
			ht_view (cdr (assoc 41 dxf_vport))
			h_vue (cdr (assoc 45 dxf_vport))
		)
		(command "_.mspace")
		(setvar "CVPORT" (cdr (assoc 69 dxf_vport)))
		(setq pt_ctr-view (getvar "VIEWCTR"))
		(initget "+ -")
		(if (eq (getkword "\nRotation de +90° ou -90°? [+/-] <+>: ") "-")
			(command "_.dview" "" "_twist" (angtos (rem (- (getvar "VIEWTWIST") (/ pi 2)) pi) 0 5) "")
			(command "_.dview" "" "_twist" (angtos (rem (+ (getvar "VIEWTWIST") (/ pi 2)) pi) 0 5) "")
		)
		(command "_.-view" "_save" "$bascul_vue")
		(command "_.-layer" "_state" "_save" "$bascul_vue" "" "" "")
;			(command "_.-layer" "_state" "_save" "$bascul_vue" "_on" "_froze" "_lock" "_plot" "_newvp" "_color" "_linetype" "_weight" "_plotstyle" "" "" "")
		(command "_.pspace")
		(setq pt_dl
			(list
				(- (car base_pt) (/ ht_view 2.0))
				(- (cadr base_pt) (/ lg_view 2.0))
				(caddr base_pt)
			)
		)
		(setq pt_ur
			(list
				(+ (car base_pt) (/ ht_view 2.0))
				(+ (cadr base_pt) (/ lg_view 2.0))
				(caddr base_pt)
			)
		)
		(entdel e_vport)
		(command "_.mview" pt_dl pt_ur)
		(command "_.mspace")
		(command "_.-view" "_restore" "$bascul_vue")
		(command "_.-view" "_delete" "$bascul_vue")
		(command "_.-layer" "_state" "_restore" "$bascul_vue" "_delete" "$bascul_vue" "" "")
		(if (zerop (logand 1 (getvar "viewmode")))
			(command "_.zoom" "_ce" pt_ctr-view (strcat (rtos (/ ht_view h_vue)) "XP"))
		)
		(command "_.pspace")
		(command "_.undo" "_end")
		(setvar "CMDECHO" 1)
	)
	(T (prompt "\n*** Commande non autorisée dans l'espace objet ***"))
)
(prin1)
)

[Tramber]

Je ne sais pas si MVPORT de notre ami Serge pourrait t'aider.

 

L'essai dure 90 jours, de uoi se faire une idée !

[BIM G CO]

MVPORT? pour avoir fait le test cette fonction est trop nébuleuse pour certains utilisateur! d'ailleurs j'ai abandonné d'expliquer cette fonction!

 

Ce qu'ils comprennent : _UCS 3pts puis _PLAN et deux fois entrée! J'ai mis environs 6 mois pour faire entrer dans les moeurs qu'on puisse faire tourner les présentations et l'espace objet

[yalta]

...Merci de vos réponses,

 

Sylvain ;) ;)

[Laurent_CAMPEDEL]

Maximilien,tu confonds entre le dévellopement "mvport " de Serge Camiré et la commande mvsetup d'AutoCAD.

 

Sinon, j'utilise la même méthode que toi.

Simple et efficace.

Son défaut : il faut re-régler le facteur d"échelle et le cadrage de la zone vue. Mais comme en général on en est à la mise en place de la présentation, çe n'est pas très génant.

[Tramber]

I faut reconsidérer MVSETUP et pourquoi pas "configurer la vue" en créant un solide fantôme.

 

Dans l'une et l'autre il y des moyens puissants de faire tourner la vue.

 

Mais je concède que ca n'est pas très rapide.

[DenisHen]

Bonsoir à tous, ou bonjour,

 

Pour ma part, j'utilise un scu local en espace objet, je le sauvegarde avec "Vue" puis, dans la fenêtre de l'espace papier, je la rappelle et Hop ! !

 

J'ai bon ?

 

Denis...