initget

[zebulon_]

bonjour,

 

nous avons parlé il y a peu de temps au sujet du couple initget et getkword

 

http://www.cadxp.com/sujetXForum-7032.htm

 

Maintenant, ce que je voudrais obtenir, c'est de pouvoir saisir soit un point, soit un mot clé. Un peu comme quand on utilise la commande _PLINE qui permet de cliquer des points ou de modifier des paramètres (Arc, Longueur, LArgeur ...).

 

Exemple : je voudrais saisir les deux point d'extrémité d'une semelle de fondation et faire tracer le béton de propreté dessous et je voudrais en même temps pouvoir paramétrer l'épaisseur du béton de propreté.

J'ai associé un (initget 128) avec getpoint. Comme ça getpoint peut aussi saisir autre chose que des points.

 

 

; entrée données

(defun lire_BP (/ TEMP)
 (if (not EP)
   (setq EP 100.00)
 )
 (setq DEP nil
       FIN nil
 )
 (prompt (strcat "\nEpaisseur : " (rtos EP 2 3)))
 (while (/= (type DEP) 'LIST)
   (initget 128)
   (setq DEP (getpoint "\nPoint gauche semelle ou [Epaisseur] "))
   (if (= (type DEP) 'STR)
     (if (= (strcase (substr DEP 1 1)) "E")
       (setq EP (getdist "\nEpaisseur : "))
     )
   )
 )
 (setq FIN (getpoint DEP "\nPoint droit semelle  : "))
 (if (> (car DEP) (car FIN))
   (progn
     (setq TEMP DEP)
     (setq DEP FIN)
     (setq FIN TEMP)
   )
 )
)

; dessiner polyligne béton de propreté

(defun dess_BP ()
 (setq X1 (- (car DEP) EP))
 (setq Y1 (cadr DEP))
 (setq X2 (+ (car FIN) EP))
 (setq Y2 (- (cadr FIN) EP))
 (setq OldOS (getvar "OSMODE"))
 (setvar "OSMODE" 0)

 (command "_PLINE"
          DEP
          (list X1 Y1)
          (list X1 Y2)
          (list X2 Y2)
          (list X2 Y1)
          FIN
          ""
 )
(setvar "OSMODE" OldOS)

)

(defun C:BP ()
 (lire_BP)
 (dess_BP)
)

[(gile)]

Salut,

 

Tu peux faire un peu plus court en cumulant les arguments avec (initget) :

 

(while (/= (type DEP) 'LIST)
   [surligneur](initget 1 "Epaisseur")[/surligneur]
   (setq DEP (getpoint "\nPoint gauche semelle ou [Epaisseur] "))
   (if	(= DEP "Epaisseur")
     (setq EP (getdist "\nEpaisseur : "))
   )
 ) 

 

À la place de :

 

(while (/= (type DEP) 'LIST)

(initget 128)

(setq DEP (getpoint "\nPoint gauche semelle ou [Epaisseur] "))

(if (= (type DEP) 'STR)

(if (= (strcase (substr DEP 1 1)) "E")

(setq EP (getdist "\nEpaisseur : "))

)

)

)

[surligneur] [/surligneur]

[zebulon_]

encore mieux

 

merci

[Fab62]

Salut,

 

Je voudrais savoir si cette application a évolué un petit peu???

 

Je suis intéressé par tout ce qui touche au dessin d'une Semelle/Fondation, s'il y a quelqu'un qui a un filon???

 

Merci d'avance

 

++

 

[Edité le 9/1/2007 par Fab62]

[zebulon_]

Bonjour,

 

tu nous décris avec le plus de précision possible ce que tu veux ou ce que tu cherches dans un nouveau sujet de ce forum et on regarde ce qu'on a en magasin

 

amicalement

 

zebulon_

[Fab62]

Bonjour,

 

tu nous décris avec le plus de précision possible ce que tu veux ou ce que tu cherches dans un nouveau sujet de ce forum et on regarde ce qu'on a en magasin

 

amicalement

 

zebulon_

 

Et bien voilà, j'ai recadré le sujet

 

 

http://www.cadxp.com/sujetXForum-13300.htm

 

 

Merci pour votre aide!!!

 

++

 

Fab