Decaler plusieurs polylignes fermées simultanément

[Maxime10]

Bonjour à toutes et tous,

 

Suite à quelques recherches depuis AutoCAD ainsi que sur internet, je ne parviens pas à trouver une commande, un lisp ou une macro qui permettrait d'effectuer l'opération ci-dessous:

Le but recherché serait de pouvoir décaler une multitude de polylignes fermées étant dans le même calque, vers l'intérieur de ces dernières, en indiquant le décalage souhaité (ex: 0.2).

Aujourd'hui j'effectue la commande décaler en sélectionnant une par une chaque polyligne.

Suis-je passé à côter de quelque chose de natif sur le logiciel ou d'une autre commande permettant d'effectuer cette opération ?

 

Maxime

 

[lecrabe]

Hello

SVP tu testes cette jolie routine "OffIn / OffOut" de Kent Cooper ... Et tu nous signales si c OK !?

Belle annee 2024, La Sante, Bye, lecrabe

 

;; 
;; https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/offset-multiple-objects-at-once/td-p/7835213
;; 

;|
OffsetInOrOut.lsp [command names:  OffIn & OffOut]
To Offset selected objects all by same User-specified distance, all either Inward
  or Outward, regardless of drawn direction.
OffIn = Offset Inward; OffOut = Offset Outward.
Works on Arcs/Circles/Ellipses/planar Splines/LW or "heavy" 2D Polylines.
  [cannot Offset 3D Polylines or non-planar Splines].  Polylines/Splines/
  Ellipses can be open/partial or closed/full.
Offsets in direction that results in entity of [in OffIn] smaller or [in OffOut]
  larger area than original.
In OffIn, detects objects too small to be Offset Inward by specified distance,
  and reports how many there were.
Can have unintended result with Polyline/Spline if self-intersecting or of other
  shape that results in more than one new entity when Offset.
Works in any UCS.
Remembers User's distance independent of regular Offset's, and offers as
  default on subsequent use; on first use, offers regular Offset's if not Through.
Kent Cooper, 1 August 2018
|;


(defun OIO ; = Offset object(s) Inward or Outward [called by OffIn & OffOut]
  (subpr / *error* doc ss nogo n ent obj oarea)
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
      (princ (strcat "\nError: " errmsg))
    ); if
    (vla-endundomark doc)
    (princ)
  ); defun - *error*
  (vla-startundomark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
  (initget (if (and (not *OIOdist) (= (getvar 'offsetdist) -1.0)) 7 6))
    ; no Enter if no prior value and regular Offset is Through; no zero; no negative
  (setq *OIOdist ; global, to offer as default on subsequent use
    (cond
      ( (getdist ; User input
          (strcat
            "\nDistance to Offset " subpr "ward"
            (cond
              (*OIOdist (strcat " <" (rtos *OIOdist) ">")); prior OIO value
              ((/= (getvar 'offsetdist) -1.0) (strcat " <" (rtos (getvar 'offsetdist)) ">"))
                ; regular Offset's distance if not Through
              (""); no default if neither above condition
            ); cond
            ": "
          ); strcat
        ); getdist
      ); User-input condition
      (*OIOdist); User Enter with prior OIO value
      ((/= (getvar 'offsetdist) -1.0) (getvar 'offsetdist))
        ; User Enter with no OIO value but regular Offset not Through
    ); cond
    nogo 0
  ); setq
  (prompt (strcat "\nTo Offset object(s) " subpr "ward by same distance,"))
  (if (setq ss (ssget ":L" '((0 . "*POLYLINE,ARC,CIRCLE,ELLIPSE,SPLINE")))); level1
    (progn ; then
      (setq nogo 0)
      (repeat (setq n (sslength ss)); level1 then
        (if ; level2
          (and
            (not
              (member
                '(100 . "AcDb3dPolyline"); can't Offset 3DPolyline
                (entget (setq ent (ssname ss (setq n (1- n)))))
              ); member
            ); not
            (vlax-curve-isPlanar ent); nor non-planar [Spline only]
          ); and
          (progn ; level2 then -- proceed
            (setq
              obj (vlax-ename->vla-object ent)
              oarea (vla-get-Area obj)
            ); setq
            (if ; level3
              (not ; Offset succeeded [returns T if so, because:]
                (vl-catch-all-error-p ; returns T for error if inward but too small
                  (vl-catch-all-apply 'vla-offset (list obj *OIOdist))
                ); -error-p
              ); not
              (if ; level4 is level3 then -- check comparative areas:
                ((if (= subpr "In") > <) (vla-get-Area (vlax-ename->vla-object (entlast))) oarea)
                (progn ; level4 then -- went wrong way
                  (entdel (entlast))
                  (if ; level5 -- go the other way [if possible]
                    (vl-catch-all-error-p ; returns T for error if inward but too small
                      (vl-catch-all-apply 'vla-offset (list obj (- *OIOdist)))
                    ); -error-p
                    (setq nogo (1+ nogo)); then -- add to count of too-small [no else]
                  ); if level5
                ); progn
              ); if level4 [went wrong way -- no else; do nothing if it went right way]
              (if (= subpr "Out") (vla-offset obj (- *OIOdist)) (setq nogo (1+ nogo)))
                ; level3 else -- too small for inward; go other way only if OffOut
                ; if OffIn, add to count of too-small
            ); if level3 [Offset succeeded]
          ); progn [then]
        ); if level2 [valid object -- no else; can't Offset otherwise]
      ); repeat
      (if (> nogo 0)
        (prompt (strcat "\n" (itoa nogo) " objects too small to be Offset Inward. ")); then
      ); if
    ); progn -- then
  ); if level1 [unlocked object(s) selected]
  (vla-endundomark doc)
  (princ)
); defun -- C:OIO


(defun C:OffIn (/ *error*)
  (OIO "In")
); defun -- C:OffIn


(defun C:OffOut (/ *error*)
  (OIO "Out")
); defun -- C:OffIn


(vl-load-com)
(prompt "\nType OffIn to Offset object(s) Inward, OffOut to Offset object(s) Outward. ")

 

[Maxime10]

Bonjour lecrabe,

Et bien ... ça fonctionne au poil et répond entièrement à mon besoin !

Merci à toi pour la rapidité du retour et le temps pris, et merci à Kent Cooper

 

[lecrabe]

Hello

Je suis venal : cela te coutera un excellent Whisky single malt !

Bye, lecrabe

 

[Maxime10]

J'ignorais que les décapodes s'abreuvaient de Whisky sur leur temps libre 😮 mon ignorance m’impressionnera toujours !

En utilisant la fonction je me suis retrouvé à augmenter la largeur globale de la polyligne créée de 2x fois le montant du décalage

(ex: décalage 0.2 -> largeur globale 0.4) et à supprimer les polylignes ayant été sélectionnées lors de la commande OffIn.

Etant novice dans la compréhension des Lisps, je me demandais si je pouvais incorporer, au Lisp que tu m'as gentiment fourni,

des morceaux d'autres Lisps afin d'effectuer ces deux actions complémentaires ?

Maxime

 

[Maxime10]

J'ai changé mon approche vis à vis du résultat à obtenir afin d'optimiser les étapes et gagner en temps, par conséquent le besoin cité ci-dessus n'est plus valable dans mon cas.

Néanmoins la fonction OffIn et OffOut me sera nécessaire pour d'autres applications.

Maxime