Rotation de plusieurs textes avec leurs points d'origine

[THBDM]

Bonjour,

J'ai plusieurs textes dans mon dessin Autocad. Ceux-ci sont d'un angle différent et j'aimerais tous les sélectionner et les faire tourner de 180°, par exemple.

Je ne souhaite pas les faire tous tourner autour d'un point défini mais que chacun tourne autour de son point d'origine, tout en gardant la même position.

Sur la même idée mais seulement pour les blocs, j'ai trouvé ce sujet :

https://cadxp.com/topic/35654-rotation-bloc-avec-point-dorigine/

 

En espérant avoir été assez clair pour mon explication, je vous remercie d'avance.

[Dominique974]

Bonjour,

De mon coté j'utilise la commande Torient du menu express. Elle fonctionne un peu comme la commande aligne mais pour les textes, on peut traiter plusieurs texte et mTxt avec.

Peace.

 

[THBDM]

@Dominique974 Merci pour ton idée.

C'est presque ce que je demande oui.

Au lieu de tout mettre à 180, ou autre, je souhaite tourner mon texte de 180.

Le texte à 54 serait à 234 et celui à 34 serait à 214

[Steven]

Salut @THBDM,

Juste par curiosité, pourquoi souhaites-tu faire faire une rotation de tes textes à 180° ?

[THBDM]

@Steven

Je reprends des textes et d'autres éléments qui sont tournés dans un sens différent du mien.
Je travaille avec le nord en haut de mon écran mais l'autre fichier non

 

[DOMI]

Bonjour,

La solution proposée par Bred dans votre lien sur le sujet concernant les blocs, à l'époque, ne convient pas ? Cela semble correspondre à votre demande.

Sélection des textes à pivoter, puis dans Propriétés, Rotation, Indication de la valeur de rotation.

Modifié le 20 juillet 2023 par DOMI

[Luna]

Coucou @THBDM,

Pas testé mais cela convient-il à la demande ?

(defun c:ROT180TXT (/ jsel i name n a)
  (if (setq jsel (ssget '((0 . "MTEXT,TEXT"))))
    (progn
      (repeat (setq i (sslength jsel) n i)
        (setq
          name (ssname jsel (setq i (1- i)))
          a (cdr (assoc 50 (entget name)))
        )
        (or
          (entmod
            (subst
              (cons 50 (+ a pi))
              (assoc 50 (entget name))
              (entget name)
            )
          )
          (ssdel name jsel)
        )
      )
      (sssetfirst)
      (sssetfirst nil jsel)
      (prompt (strcat "\nSuccessfully rotated " (itoa (sslength jsel)) "/" (itoa n) " text(s)"))
    )
  )
  (princ)
)

Une variante ci-dessous pour permettre à l'utilisateur de choisir la valeur de l'angle de rotation :

(defun c:ROTANGTXT (/ val jsel i name n a)
  (if (setq jsel (ssget '((0 . "MTEXT,TEXT"))))
    (progn
      (or
        (setq val (getreal "\nEnter the rotation angle (°) or <180> : "))
        (setq val 180)
      )
      (setq val (/ (* val pi) 180.))
      (repeat (setq i (sslength jsel) n i)
        (setq
          name (ssname jsel (setq i (1- i)))
          a (cdr (assoc 50 (entget name)))
        )
        (or
          (entmod
            (subst
              (cons 50 (+ a val))
              (assoc 50 (entget name))
              (entget name)
            )
          )
          (ssdel name jsel)
        )
      )
      (sssetfirst)
      (sssetfirst nil jsel)
      (prompt (strcat "\nSuccessfully rotated " (itoa (sslength jsel)) "/" (itoa n) " text(s) with an angle of " (rtos (/ (* val 180) pi) 2 2) "°"))
    )
  )
  (princ)
)

Pas testé non plus...

Bisous,
Luna