Suppresion du dynamisme d'un block

[benoitlacroix]

Bonjour à tous

Je voulais savoir s'il existe une commande pour supprimer l'option "dynamique" d'un bloc tout en conservant ce bloc une fois inséré et dimensionner selon les besoins. 

Si la commande n'existe pas pourrait-on le faire en LISP?

En vous remerciant d'avance pour vos réponses.

@+

[(gile)]

Salut,

(vl-load-com)
(or *acad* (setq *acad* (vlax-get-acad-object)))
(or *acdoc* (setq *acdoc* (vla-get-ActiveDocument *acad*)))
(or *blocks* (setq *blocks* (vla-get-Blocks *acdoc*)))

;; GetItem (gile)
;; Retourne le vla-object de l'item s'il est présent dans la collection (ou nil)
;;
;; Arguments
;; col : la collection (vla-object)
;; name : le nom de l'objet (string) ou son indice (entier)

(defun gc:GetItem (col name / obj)
  (vl-catch-all-apply
    (function (lambda () (setq obj (vla-Item col name))))
  )
  obj
)

;; DYN2STAT
;; Converti les blocs dynamiques sélectionnés en blocs statiques
(defun c:DYN2STAT (/ s)
  (if (ssget '((0 . "INSERT")))
    (progn
      (vla-StartUndoMark *acdoc*)
      (setq s (vla-get-ActiveSelectionSet *acdoc*))
      (vl-catch-all-apply
	(function
	  (lambda (/ i n)
	    (vlax-for b	s
	      (if (= (vla-get-IsDynamicBlock b) :vlax-true)
		(progn
		  (setq i 1)
		  (while
		    (gc:GetItem *blocks* (setq n (strcat (vla-get-EffectiveName b) "_" (itoa i))))
		     (setq i (1+ i))
		  )
		  (Vla-ConvertToStaticBlock b n)
		)
	      )
	    )
	  )
	)
      )
      (vla-Delete s)
      (vla-EndUndoMark *acdoc*)
    )
  )
  (princ)
)

 

[lecrabe]

Hello

Veux tu une routine Lisp/VLisp qui supprime le Dynamisme d'un Bloc dynamique selectionne

et donc le transforme en Bloc classic / standard ?! Sans toucher au Bloc dynamique original !?

La Sante, Bye, lecrabe (triste & fatigue)

PS: battu par notre grand maitre Gilles ! ... Et j'allais sans doute fournir la meme routine de Gilles !

 

 

[Dioka]

A défaut d'un programme lisp, en mettant l'une des valeurs d'échelles différentes des autres, le dynamisme est temporairement perdu.

@+