Bloc avec objet Nettoyer

AdrienMEURET · le 31 janvier 2020

Bonjour,

Je reviens vers vous avec une autre question liée aux blocs.

J'ai fait un bloc poutre avec un objet nettoyer, qui me permet de placer une poutre en masquant ce qu'il y a en dessous.

Dans mon bloc j'ai bien ma polyligne au dessus de mon cadre nettoyer. Mais lorsque je l'insère dans un dessin le cadre nettoyer passe au dessus. Cela me crée un effet désagréable dans l'espace objet et même à l'impression : les lignes n'ont pas la bonne épaisseur ou sont partiellement visible.

Je dois alors entrer dans le bloc et passer le cadre nettoyé en dessous.

Avez-vous une solution qui me permettrait de ne pas avoir à faire cette manipulation ?

Ici vous pouvez voir mon bloc :

Bloc Poutre

Bonne journée,

Adrien MEURET

Aleck_Ultimate · le 31 janvier 2020

Salut.

Je n'aie pas réussit à reproduire ce dont tu parle avec ce bloc donc je ne vais pouvoir te donner qu'une réponse générique.

AutoCAD ne gère pas toujours très bien les changements d'ordre de tracé, il faut parfois lui rappeler que l'ordre de tracé est différant de l'ordre de création des objets. Quant visuellement l'objet NETOYER est au dessus de la polyligne voie si RGT corrige le truc.

Sinon le mieux c'est de créer directement les objets dans le bonne ordre. Pour corriger ça tu peut par exemple copier tout les autres objet de ton bloc, supprimer les originaux puis replacer les objets copiés à leur place. Etant alors plus récents que le NETOYER ils resterons devant.

Pour corriger des bugs d'affichage utiliser [Ctrl + S] pour sauvegarder le dessin ou déplacer la vue ailleurs que sur les objets concernés puis revenir peuvent parfois marcher, mais ce ne semble pas correspondre à ce dont tu parle.

Cordialy.

zza427 · le 31 janvier 2020

Sinon, tu réduis ton nettoyer à 95% de sa taille et ta polyligne sera toujours visible...

C'est de la bidouille mais ça marche.

Aleck_Ultimate · le 31 janvier 2020

Oui et non. Le problème c'est que les objets sous le bloc ne vont êtres tronqués qu'à l'intérieur de la polyligne, et ça va sauter aux yeux.

AdrienMEURET · le 31 janvier 2020

Merci impeccable, je note la réponse synthétique :

AutoCAD ne gère pas toujours très bien les changements d'ordre de tracé, il faut parfois lui rappeler que l'ordre de tracé est différant de l'ordre de création des objets. Quant visuellement l'objet NETOYER est au dessus de la polyligne voie si RGT corrige le truc.

Sinon le mieux c'est de créer directement les objets dans le bonne ordre. Pour corriger ça tu peut par exemple copier tout les autres objet de ton bloc, supprimer les originaux puis replacer les objets copiés à leur place. Etant alors plus récents que le NETOYER ils resterons devant.

Aleck_Ultimate · le 31 janvier 2020

Whao... Je sais que j'aie tendance à développer exagérément, mais que ce soit synthétisable a ce point là...

lecrabe · le 31 janvier 2020

Hello

Petit conseil : Ne pas utiliser les Objets WipeOut / Nettoyer !

1) Faire le Polygone manuellement ...

2) Mettre DEDANS une Hachure SOLID avec la couleur RGB: 254,254,254

(et non pas avec le vrai Blanc: 255,255,255)

3) Mettre cela en Arriere plan

4) Supprimer le Polygone

GO ...

LA SANTE, Bye, lecrabe "triste" - PS: Automne 2020, la retraite ...

Aleck_Ultimate · le 31 janvier 2020

Ne pas utiliser les Objets WipeOut / Nettoyer !

Pour quelle raison STP ? Parce que faire comme ça ce n'est pas sans défaut : ça marche quant on utilise un environnement de travail blanc, mais avec un environnement de travail sombre comme l'est l'EO (espace objet) par défaut c'est peu pratique.

lecrabe · le 31 janvier 2020

Hello

Car il y a un Bug ALEATOIRE dans AutoCAD (Jamais corrige) qui inverse parfois le Blanc / Noir

sur les WipeOuts (voire meme sur les Hachures SOLID en VRAI Blanc: 255,255,255) !

CHOSE qu'il ne fera JAMAIS avec le PRESQUE Blanc: 254,254,254 !!

LA SANTE, Bye, lecrabe "triste" - PS: Automne 2020, la retraite ...

lecrabe · le 31 janvier 2020

Hello

Et maintenant tu diras un petit Merci a Patrice et un ENORME Merci au regrette Patrick_35 !!

LA SANTE, Bye, lecrabe "triste" - PS: Automne 2020, la retraite ...

;; 
;; http://cadxp.com/topic/38953-wipeout/page__p__230975
;; 
;; Routine: RWH_254  (Ex RWH)  par P35 pour Patrice
;; 
;; Remplacer un wipeout par une hachure "SOLID" de couleur 254,254,254
;; 
;; Modifier avec 254,254,254 a cause d un BUG Aleatoire avec les PDFs !! 
;; et parfois avec d'autres logiciels ... 
;;

(vl-load-com) 

(defun c:RWH_254 (/ blo col dat dic doc ent hac ele lst obj pol rgb)
 (setq doc (vla-get-activedocument(vlax-get-acad-object))
col (vlax-create-object (strcat "AutoCAD.AcCmColor." (substr (getvar "acadver") 1 2)))
 )
 (vla-startundomark doc) 

; (vla-setrgb col 255 255 255) 
 (vla-setrgb col 254 254 254) 

 (vlax-for blo (vla-get-blocks doc)
   (or (wcmatch (vla-get-name blo) "*|*")
(eq (vla-get-isxref blo) :vlax-true)
     (progn
(vlax-for ent blo
  (and (eq (vla-get-objectname ent) "AcDbWipeout")
    (progn
      (setq hac (vla-addhatch blo acHatchPatternTypePredefined "SOLID" :vlax-true)
	    lst (gc:RasterVertices (vlax-vla-object->ename ent))
	    pol (vla-addlightweightpolyline blo
					    (vlax-safearray-fill
					      (vlax-make-safearray vlax-vbdouble (cons 0 (1- (* (length lst) 2))))
					      (apply 'append (mapcar '(lambda (x) (list (car x) (cadr x))) lst))
					    )
		)
      )
      (vlax-put pol 'closed :vlax-true)
      (vlax-invoke hac 'appendouterloop (list pol))
      (vla-evaluate hac)
      (foreach ele (list hac pol)
	(mapcar '(lambda(x) (vlax-put ele x (vlax-get ent x))) (list 'layer 'linetype 'linetypescale))
	(vlax-put ele 'truecolor col)
      )
      (setq dat (cons hac (cons pol dat)))
      (vla-delete ent)
    )
  )
)
(and dat
  (progn
    (and (vl-catch-all-error-p (setq dic (vl-catch-all-apply 'vla-item (list (vla-getextensiondictionary blo) "ACAD_SORTENTS"))))
      (setq dic (vla-addobject (vla-getextensiondictionary blo) "ACAD_SORTENTS" "AcDbSortentsTable"))
    )
    (vlax-invoke dic 'movetobottom dat)
    (setq dat nil)
  )
)
     )
   )
 )
 (vlax-release-object col)
 (vla-regen doc acallviewports)
 (vla-endundomark doc)
 (princ)
)


;; Différentes routines de GC trouves sur theswamp.org
;; http://www.theswamp.org/index.php?topic=36270.msg418035#msg418035
;; Convertion des pixels d'une image en coordonnées Autocad
;; gc:RasterVertices
;; Returns the image raster (or wipeout) boundary vertices list (WCS) 

(defun gc:RasterVertices (img / elst ins u v size norm mat disp pts)
 (setq	elst (entget img)
ins  (cdr (assoc 10 elst))
u    (cdr (assoc 11 elst))
v    (cdr (assoc 12 elst))
size (cdr (assoc 13 elst))
norm (gc:CrossProduct u v)
u    (trans u 0 norm)
v    (trans v 0 norm)
mat  (trp (list u (mapcar '- v) '(0. 0. 1.)))
disp (mapcar '+
	     (trans ins 0 norm)
	     (gc:ScaleVector v (cadr size))
	     (gc:ScaleVector u 0.5)
	     (gc:ScaleVector v -0.5)
     )
pts  (if (= 1 (logand 1 (cdr (assoc 71 elst))))
       ((lambda	(l)
	  (list	(car l)
		(list (caadr l) (cadar l) (caddar l))
		(cadr l)
		(list (caar l) (cadadr l) (caddar l))
	  )
	)
	 (gc:massoc 14 elst)
       )
       (cdr (gc:massoc 14 elst))
     )
 )
 (mapcar
   '(lambda (p)
      (trans (mapcar '+ (mxv mat p) disp) norm 0)
    )
   pts
 )
)


;; gc:ScaleVector
;; Multiply a vector by a scalar 

(defun gc:ScaleVector (v s) (mapcar (function (lambda (x) (* x s))) v))

;; gc:CrossProduct
;; Returns the cross product of two vectors
(defun gc:CrossProduct (v1 v2)
 (list	(- (* (cadr v1) (caddr v2)) (* (caddr v1) (cadr v2)))
(- (* (caddr v1) (car v2)) (* (car v1) (caddr v2)))
(- (* (car v1) (cadr v2)) (* (cadr v1) (car v2)))
 )
)


;; MXV
;; Apply a transformation matrix to a vector -Vladimir Nesterovsky- 

(defun mxv (m v)
 (mapcar (function (lambda (r) (apply '+ (mapcar '* r v)))) m)
)


;; TRP
;; Transpose a matrix -Doug Wilson- 

(defun trp (m) (apply 'mapcar (cons 'list m)))

;; gc:massoc
;; Returns the list of all values for the code in an association list
(defun gc:massoc (code alst)
 (if (setq alst (member (assoc code alst) alst))
   (cons (cdar alst) (gc:massoc code (cdr alst)))
 )
)

philsogood · le 31 janvier 2020

hello

pour une fois je suis d'accord avec lecrabe

rien ne vaut une bonne hachure solide avec la couleur qui va bien!!

g plein de blocs fait ainsi (et je n'ai aucun problème)!! ;)

Phil

lecrabe · le 31 janvier 2020

Hello

Comment tu oses dire :

pour une fois je suis d'accord avec lecrabe

Mais on doit toujours etre d'accord avec lecrabe !

LA SANTE, Bye, lecrabe "triste" - PS: Automne 2020, la retraite ...

rebcao · le 1 février 2020

Bonjour,

Effectivement, parfois l'ORDRE DE TRACE "déconne" !

AutoCAD préfère que les objets soient traités dans l'ordre de création, et là ça marche mieux ! Avec la valeur 127 pour la variable système SORTENTS... seule garantie pour afficher les objets dans l'ordre de création du plus ancien au plus récent !

Ce que je fais, je compose mon bloc, je crée le contour "NETTOYER" (WIPEOUT) je COUPE les objets du bloc et je COLLE par dessus le WIPEOUT et de ce fait on a bien TOUS LES OBJETS crées au-dessus du WIPEOUT...

Christian

nG! Hebus · le 3 février 2020

Sinon !

Ordre tracé ?

enfin bon, sélection similaire du bloc en question, ordre tracé -> avanttout !

@Lecrabe : c'est quoi ça? On t'a pas dit qu'il fallait mourir au taf :) -> "PS: Automne 2020, la retraite .."

OlivierR · le 20 novembre 2023

Bonjour à tous,

Des collègues insistent pour utiliser les wipeout. Le bug du noir/blanc sur les PDF existe t'il toujours ?

Olivier

lecrabe · le 21 novembre 2023

Hello

A ma connaissance OUI ... En attente d autres avis !?

Bye, lecrabe

OlivierR · le 21 novembre 2023

Merci lecrabe.

Steven · le 21 novembre 2023

Le 20/11/2023 à 18:36, OlivierR a dit :

Bonjour à tous,

Des collègues insistent pour utiliser les wipeout. Le bug du noir/blanc sur les PDF existe t'il toujours ?

Olivier

Aucun problème de mon côté avec les Wipeout et les PDF et ce, depuis longtemps.

OlivierR · le 22 novembre 2023

Merci Steven

LUDWIG · le 29 mars

Le 20/11/2023 à 18:36, OlivierR a dit :

Bonjour à tous,

Des collègues insistent pour utiliser les wipeout. Le bug du noir/blanc sur les PDF existe t'il toujours ?

Olivier

Bonjour,

J'ai toujours utilisé des Wipeout dans mes blocs (pourtant compliqué, plein de paramètres et actions) et pas de soucis de couleur des PDF.

MAIS... des collègues ont eu ce souci.

J'ai corrigé en remplaçant l'imprimante "DWG to PDF" qu'ils avaient par la mienne. Pas sûr que le souci vienne de là, mais ça a marché !

Connexion

Bloc avec objet Nettoyer

Messages recommandés

AdrienMEURET

Aleck_Ultimate

zza427

Aleck_Ultimate

AdrienMEURET

Aleck_Ultimate

lecrabe

Aleck_Ultimate

lecrabe

lecrabe

philsogood

lecrabe

rebcao

nG! Hebus

OlivierR

lecrabe

OlivierR

Steven

OlivierR

LUDWIG

Forums

Naviguer

Activité

Information importante