Des faces 3D pour rectangles 2D ! ! !

[DenisHen]

Bonjour à tous.

 

Voilà, mes collègues me font des levés topographiques avec GéoVisual, qui tourne sous MicroStation...

 

Je les importe dans AutoCAD et transforme toutes les données (calques, textes...) comme je le désire.

 

Sauf que je viens de m'apercevoir que ce logiciel, aussi curieux que cela puisse paraître, me créé des faces 3D pour faire des carrés en 2D ! ! !

 

je cherche donc une routine, si quelqu'un en a une, qui me ferait cette transformation, car je ne vois pas comment m'y prendre...

 

Denis...

[didier]

Coucou

 

Je ne viens plus très souvent mais je constate que les choses évoluent peu !

Est-ce que tu as regardé les codes DXF d'une face 3D ?

On te l'a dit, on te l'a répété, vas voir les codes DXF, TOUT y est...

En particulier les assoc avec les codes 10 11 12 et 13 (de mémoire) je n'ai plus AutoCAD sous la main

Je pense qu'une fois que ce sera fait tu nous diras"

Merci, j'y avais pas pensé !"

Amicalement tout de même...

[lrdb@home]

Bonjour,

Sauf que je viens de m'apercevoir que ce logiciel, aussi curieux que cela puisse paraître, me créé des faces 3D pour faire des carrés en 2D ! ! !

En effet, c'est incroyable....

 

Option d'export provenant de géovisual :

 

 

[DenisHen]

Est-ce que tu as regardé les codes DXF d'une face 3D ?

Absolument pas. Mais je commence à voir où tu veux en venir...

 

Est-ce récupérer les quatre sommets de la face 3D pour en faire une polyligne fermée ?

 

Je vais regarder ça... Merci, je n'y avais pas pensé... ;)

 

merci lrdb, je vais communiquer ces informations à mes collègues...

[lecrabe]

Hello

 

Donc dans mon stock de 2000 routines ...

 

MERCI Gilles comme tres souvent !

 

Bye, lecrabe

 

PS: je n'ai pas re-teste la routine !

SVP tu nous diras si c OK ?? ET avec quel AutoCAD ??

 

;; 
;; http://cadxp.com/topic/44859-transformer-une-face-3d-en-lwpolyligne/
;; 
;; Routine: 3DFace2Polyline par GC
;;

(defun c:3DFace2Polyline (/ distinct ss i face pts)

 (defun distinct (l)
   (if l
     (cons (car l) (distinct (vl-remove (car l) l)))
   )
 )
 (if (setq ss (ssget "_X" '((0 . "3DFACE"))))
   (repeat (setq i (sslength ss))
     (setq face (ssname ss (setq i (1- i)))
           pts  (distinct
                  (mapcar '(lambda (p)
                             (list (cadr p) (caddr p))
                           )
                          (vl-remove-if-not
                            '(lambda (x) (member (car x) '(10 11 12 13)))
                            (entget face)
                          )
                  )
                )
     )
     (command "_.pline")
     (foreach p pts (command p))
     (command "_close") 

;;;;;;;;;; Commentez si vous desirez GARDER les 3DFaces ! 
     (command "_.erase" face "") 

   )
 )
 (princ)
)

[DenisHen]

Salut à toi, Ô Décapode archiviste...

 

Mille mercis pour ce code, j'étais parti pour le faire, mais il aurait été beaucoup plus long... ;)

 

Ça fonctionne nickel sur mon MAP 2014... J'essairai lundi sur mon MAP 2018...

 

Encore merci...