Fermeture de plusieurs fichiers

[Fruity]

Bonjour

 

Toujours dans les choses qui ne sont jamais corrigées, avec le tps, ca a peut-être changé:

Comment fermer rapidement une vingtaine de plans ouverts? Ouverts uniquement pour lancer des impressions ou des pdf, donc sans aucune modifications. Devoir attendre la question si il y a eu des modifications et cliquer sur "Non" a chaque fichier est une perte de tps considérable.

A part killer le processus, j'aimerais une solution propre (répondre "non, à tous les fichiers" tout simplement).

[La Lozère]

Peut-être une demi réponse en faisant un clic droit sur une présentation et "Enregistrer tout", puis un autre clic droit pour "Fermer tout"

[DenisHen]

Salut.

 

Peut-être avec "CLOSEALL" ?

[Fruity]

Peut-être une demi réponse en faisant un clic droit sur une présentation et "Enregistrer tout", puis un autre clic droit pour "Fermer tout"

En effet, ca peut fonctionner en faisant ainsi, mais c'est pas top de re-sauvegarder des fichiers qui ne m'appartiennent pas forcement, et donc changer la date d'enregistrement (ce qui peut être utile parfois).

 

Quant a Closeall, bah c'est "fermer tout", ca n’empêche pas la demande de sauvegarde.

[LrDb]

Bonjour

http://www.cadforum.cz/cadforum_en/how-to-quit-all-open-drawings-without-saving-tip7723

[Fruity]

Bonjour

http://www.cadforum.cz/cadforum_en/how-to-quit-all-open-drawings-without-saving-tip7723

 

Woo ca marche niquel, merci beaucoup!

je recopie le lisp ici pour de futurs recherches.

 

;Quit all drawings without saving (CAD Studio - www.cadforum.cz)
(vl-load-com)
(defun C:QuitAll ( / dwg)
(vlax-for dwg (vla-get-Documents (vlax-get-acad-object))
 (if (= (vla-get-active dwg) :vlax-false)(vla-close dwg :vlax-false))
)
(command "._close" "_y")
)

[Fruity]

Woo ca marche niquel, merci beaucoup!

je recopie le lisp ici pour de futurs recherches.

 

 

Je remonte ce sujet car j'ai quelques soucis.

J'ai modifié le lisp:

 

  ;-----------------------------------------------------------------
 ; TOUT QUITTER SANS ENREGISTRER
 ;-----------------------------------------------------------------


(vl-load-com)
(defun C:QuitAlln ( / dwg)
(vlax-for dwg (vla-get-Documents (vlax-get-acad-object))
 (if (= (vla-get-active dwg) :vlax-false)(vla-close dwg :vlax-false))
)
(command "._close" "_y")
)


 ;-----------------------------------------------------------------
 ; TOUT QUITTER ET ENREGISTRER
 ;-----------------------------------------------------------------


(vl-load-com)
(defun C:QuitAlly ( / dwg)
(vlax-for dwg (vla-get-Documents (vlax-get-acad-object))
 (if (= (vla-get-active dwg) :vlax-false)(vla-close dwg :vlax-false))
)
(command "._close" "_n")
)

 

 

Or, je viens de remarquer que seul le fichier affiché est sauvegardé. Les autres se ferment sans enregistrer! (je m'en rends compte 6 mois après, j'ai dû perdre un paquet de modif!).

D'ailleurs quand j'essaie de déchiffrer le lisp, j'ai du mal.

Je ne pige pas par exemple pkoi pour enregistrer, on entre la commande "n", et inversement "y" pour ne pas enregistrer.

Ca devrait être l'inverse puisque la question est "voulez-vous enregistrer?" (et pourtant ca marche).

Et il doit y avoir un truc que j'ai raté au niveau des "get"..

[Fruity]

Up , personne?

[bonuscad]

Alors comment comprendre cette syntaxe?

 (vlax-for dwg (vla-get-Documents (vlax-get-acad-object))
 (if (= (vla-get-active dwg) :vlax-false)(vla-close dwg :vlax-false))
)

Je dirais : Pour chaque dessin ouvert dans la session d'autocad, si le dessin n'est pas actif alors fermer le dessin sans sauvegarder.

Si tu veux sauvegarder, alors

(vla-close dwg :vlax-true)

 

Voir l'aide

 

[Patrick_35]

Salut

 

Vite fait. La sauvegarde est faite même si un dessin ouvert n'est pas modifié (DBMOD = 0).

Si le dessin est en lecture seul, la sauvegarde ne fonctionnera pas.

(defun C:QuitAll ( / cur dwg)
 (vl-load-com)
 (vlax-for dwg (vla-get-documents (vlax-get-acad-object))
   (if (equal (vla-get-activedocument (vlax-get-acad-object)) dwg)
     (setq cur dwg)
     (progn
(vl-catch-all-apply 'vla-saveas (list dwg (vla-get-fullname dwg)))
(vla-close dwg :vlax-false)
     )
   )
 )
 (vl-catch-all-apply 'vla-saveas (list cur (vla-get-fullname cur)))
 (vl-cmdf "_.quit")
 (princ)
)

 

@+

[Patrick_35]

Je dirais : Pour chaque dessin ouvert dans la session d'autocad, si le dessin n'est pas actif alors fermer le dessin sans sauvegarder.

Si tu veux sauvegarder, alors

(vla-close dwg :vlax-true)

Salut Bonus

 

C'est bien ce qu'indique la doc, mais pour avoir travaillé avec ObjectDbx, j'ai eu la mauvaise surprise de constater que cela ne fonctionnait pas. Pas de sauvegarde. Peut-être que les modifs via le lisp n'étaient pas prises en compte pour que le (vla-close ... :vlax-true) fonctionne.

 

La parade, vla-saveas.

 

@+

[Fruity]

Salut

 

Vite fait. La sauvegarde est faite même si un dessin ouvert n'est pas modifié (DBMOD = 0).

Si le dessin est en lecture seul, la sauvegarde ne fonctionnera pas.

(defun C:QuitAll ( / cur dwg)
 (vl-load-com)
 (vlax-for dwg (vla-get-documents (vlax-get-acad-object))
   (if (equal (vla-get-activedocument (vlax-get-acad-object)) dwg)
     (setq cur dwg)
     (progn
(vl-catch-all-apply 'vla-saveas (list dwg (vla-get-fullname dwg)))
(vla-close dwg :vlax-false)
     )
   )
 )
 (vl-catch-all-apply 'vla-saveas (list cur (vla-get-fullname cur)))
 (vl-cmdf "_.quit")
 (princ)
)

 

@+

 

ha cool, ca semble fonctionner merci.

Par contre ca ferme autocad à la fin.

Si je remplace _.quit par _.close ca a l'air de fonctionner. J'ai bon?

[Patrick_35]

Tu remplaces

(vl-cmdf "_.quit")

par

(vl-cmdf "_.close")

 

@+

[Fruity]

Tu remplaces

(vl-cmdf "_.quit")

par

(vl-cmdf "_.close")

 

@+

 

 

Yes merci, j'avais bon (j'ai édité mon post en meme tps que ta réponse :) )