Assainissement PEHD

Ernest · le 16 juin 2017

Bonjour à tous,

Dans le cadre d'un projet le MOA nous demande de poser du PEHD à la place du PVC sur le réseau EU pour faire l'économie de regards en utilisant au mieux la pose en courbe.

(Non, je ne pense pas que l'idée soit judicieuse et je vais contacter un fabricant pour en avoir le cœur net, si d'ailleurs vous avez un avis sur la question je suis tout ouïe.)

Or Covadis et son module assainissement ne gèrent pas les courbes.

Y-a-t-il un espoir que ce soit un jour le cas? Peut-on faire remonter le besoin à Geomedia?

Pour traiter la chose je suis resté sur le module assainissement avec des nœuds "fictifs" sans regard pour me rapprocher au mieux des arcs voulus et ainsi ne pas avoir de longueurs trop erronées.

J'avais au départ pensé utiliser la partie réseau sec Gaz qui tolère la pose en courbe en créant ma canalisation et mon regard dans la bibliothèque, mais le regard n'est pas géré sur le profil en long (logique), et si la profondeur de pose est bien prise en compte, pas moyen de faire de chute (logique une fois encore).

lecrabe · le 16 juin 2017

Hello

Si je me souviens bien, je dois avoir en stock (parmi 2000 routines) une routine Lisp/VLisp de Gilles qui convertit une Polyligne 2D composee de segments+arcs en Polyligne 2D composee uniquement de segments avec des micro-segments qui simule le/les arc(s) d'origine !

Cela peut il t'aider ?

Bye, lecrabe

lecrabe · le 16 juin 2017

Hello

Voir ci apres la routine "Arc2Seg" de Gilles (Ecrite en 2008) qui traite les Arcs, Cercles et LWPOLYLINE ...

Cette routine est toujours operationnelle meme sur un AutoCAD MAP 2018 !

MERCI Gilles, Bye, lecrabe


;; 
;; Routine par Gilles (gile) pour Patrice
;; 
;; Generation de polygones reguliers sur les Arcs , Cercles et Arcs dans Polylignes
;; Les Xdatas sont copiees sur la nouvelle polyligne.
;;
;; Routine:  ARC2SEG  vers 1.03 par Gilles le 10 Nov 2008 
;; 
;; Transforme les Arcs, Cercles et Polyarcs en Polylignes (LWPOLYLINE) constituees de segments droits
;;
;; 1 - Correction du bug sur les arcs > 180 degres
;; 2  Pour les XDatas, soit je copie tout dans la nouvelle entite soit, 
;; dans le cas des polylignes avec suppression, je ne fais que modifier les sommets de la polyligne. 
;; 3 - J'ai peaufine le traitement des largeurs, si la largeur de depart et la largeur de fin different,
;; celle des segments changera aussi proportionnellement.
;; 4 - Generation soit sur le calque courant, soit sur le calque d'origine des objets (vs 1.03)
;;
;; 5 - Micro-Micro-Modif : ajout de (vl-load-com) - vs 1.04 
;; 

(defun c:Arc2Seg (/ arc2pol pol2pol seg del org ss n ent elst)

(vl-load-com)

 ;; Retourne la liste dxf de la polyligne (d'après un arc ou un cercle)
 (defun arc2pol
 (elst seg org / closed alpha delta cen elv rad lay nlst)
   (and (= (cdr (assoc 0 elst)) "CIRCLE") (setq closed T))
   (setq alpha	(if closed
	  (* pi 2)
	  (cdr (assoc 51 elst))
	)
  delta	(if closed
	  (/ alpha seg)
	  (/ (ang<2pi (- alpha (cdr (assoc 50 elst)))) seg)
	)
  cen	(cdr (assoc 10 elst))
  elv	(caddr cen)
  cen	(list (car cen) (cadr cen))
  rad	(cdr (assoc 40 elst))
  lay	(if org
	  (assoc 8 elst)
	  (cons 8 (getvar "CLAYER"))
	)
  nlst	(vl-remove-if-not
	  (function (lambda (x) (member (car x) '(210 -3))))
	  elst
	)
  nlst	(cons (cons 10 (polar cen alpha rad)) nlst)
   )
   (repeat (if	closed
      (1- seg)
      seg
    )
     (setq
nlst (cons (cons 10
		 (polar cen (setq alpha (- alpha delta)) rad)
	   )
	   nlst
     )
     )
   )
   (setq nlst
   (cons '(0 . "LWPOLYLINE")
	 (cons '(100 . "AcDbEntity")
	       (cons (cons 410 (getvar "CTAB"))
		     (cons lay
			   (cons '(100 . "AcDbPolyline")
				 (cons (cons 90
					     (if closed
					       seg
					       (1+ seg)
					     )
				       )
				       (cons (cons 70
						   (if closed
						     1
						     0
						   )
					     )
					     (cons (cons 38 elv) nlst)
				       )
				 )
			   )
		     )
	       )
	 )
   )
   )
 )

 ;; Retourne la liste dxf de la polyligne modifiée (d'après une polyligne)
 (defun pol2pol (elst	seg   org   /	  cnt	closed	    nlst  p0
	  p1	p2    bu    larg  inc	bdata delta cen	  rad
	  alpha	n
	 )
   (setq closed (logand 1 (cdr (assoc 70 elst)))
  cnt	 0
   )
   (and (= closed 1) (setq p0 (cdr (assoc 10 elst))))
   (while elst
     (if (= (caar elst) 10)
(progn
  (setq	p1 (cdar elst)
	p2 (cdr (assoc 10 (cdr elst)))
	bu (cdr (assoc 42 elst))
  )
  (if (or (= 0 bu)
	  (and (zerop closed) (null p2))
      )
    (setq nlst (cons (cadddr elst)
		     (cons (caddr elst)
			   (cons (cadr elst)
				 (cons (car elst) nlst)
			   )
		     )
	       )
	  elst (cddddr elst)
    )
    (progn
      (and (not p2) (= closed 1) (setq p2 p0))
      (setq larg  (cdr (assoc 40 elst))
	    inc	  (/ (- (cdr (assoc 41 elst)) larg) seg)
	    bdata (BulgeData bu p1 p2)
	    delta (/ (car bdata) seg)
	    rad	  (abs (cadr bdata))
	    cen	  (caddr bdata)
	    alpha (angle cen p1)
	    n	  0
	    cnt	  (+ cnt seg -1)
      )
      (while (< n seg)
	(setq nlst (cons
		     (cons 10
			   (polar cen
				  (+ alpha (* delta n))
				  rad
			   )
		     )
		     nlst
		   )
	      nlst (cons (cons 40 larg) nlst)
	      nlst (cons (cons 41 (setq larg (+ larg inc))) nlst)
	      nlst (cons '(42 . 0.0) nlst)
	      n	   (1+ n)
	)
      )
      (setq elst (cddddr elst))
    )
  )
)
(setq nlst (cons (car elst) nlst)
      elst (cdr elst)
)
     )
   )
   (or	org
(setq nlst (subst (cons 8 (getvar "CLAYER")) (assoc 8 nlst) nlst))
   )
   ((lambda (dxf90)
      (subst (cons 90 (+ (cdr dxf90) cnt))
      dxf90
      (reverse (subst '(42 . 0.0) (assoc 42 nlst) nlst))
      )
    )
     (assoc 90 nlst)
   )
 )

 ;; Fonction principale

 (or (getenv "SegmentsNumberPerCircle")
     (setenv "SegmentsNumberPerCircle" "64")
 )
 (initget 6)
 (if
   (setq seg (getint
	(strcat	"\nNombre de segments par arc <"
		(getenv "SegmentsNumberPerCircle")
		">: "
	)
      )
   )
    (setenv "SegmentsNumberPerCircle" (itoa seg))
    (setq seg (atoi (getenv "SegmentsNumberPerCircle")))
 )
 (initget "Oui Non")
 (if (= "Oui"
 (getkword "\nEffacer les objets source [Oui/Non] ? <N>: ")
     )
   (setq del T)
 )
 (initget "Courant Origine")
 (if (= "Origine"
 (getkword
   "\nCalque des nouveaux objets [Courant/Origine] ? <C>: "
 )
     )
   (setq org T)
 )
 (prompt
   "\nSélectionner les objets à traiter ou <tous>."
 )
 (and
   (or	(setq ss (ssget '((0 . "ARC,CIRCLE,LWPOLYLINE"))))
(setq ss (ssget "_X" '((0 . "ARC,CIRCLE,LWPOLYLINE"))))
   )
   (setq n 0)
   (while (setq ent (ssname ss n))
     (setq elst (entget ent '("*")))
     (if (= (cdr (assoc 0 elst)) "LWPOLYLINE")
((if del
   entmod
   entmake
 )	   (pol2pol elst seg org)
)
(progn
  (entmake (arc2pol elst seg org))
  (and del (entdel ent))
)
     )
     (setq n (1+ n))
   )
 )
 (princ)
)


;; BulgeData
;; Retourne les données d'un polyarc (angle rayon centre)
(defun BulgeData (bu p1 p2 / alpha rad cen)
 (setq	alpha (* 2 (atan bu))
rad   (/ (distance p1 p2)
	 (* 2 (sin alpha))
      )
cen   (polar p1
	     (+ (angle p1 p2) (- (/ pi 2) alpha))
	     rad
      )
 )
 (list (* alpha 2.0) rad cen)
)

;;; Ang<2pi
;;; Retourne l'angle, à 2*k*pi près, compris entre 0 et 2*pi

(defun ang<2pi (ang)
 (if (and (<= 0 ang) (< ang (* 2 pi)))
   ang
   (ang<2pi (rem (+ ang (* 2 pi)) (* 2 pi)))
 )
)

Aucun_Intérêt · le 16 juin 2017

Salut,

Alors Covadis j'y connais rien mais y a un truc qui me saute aux yeux.

Ton MOE veux faire de l'assainissement gravitaire sans regard ? Il t'a dit pourquoi ? En refoulement, je veux bien mais en gravitaire c'est suicidaire.

Ernest · le 16 juin 2017

@lecrabe : Merci pour le Lisp camarade!

@Aucun_intérêt: Le MOE c'est nous. C'est bien le MOA qui nous transmet la doléance du Maire dont les services techniques gèrent le réseau d'assainissement de la commune, et ce sont ces derniers qui souhaitent supprimer des regards en posant en courbe avec du PEHD...

Ça me semble douteux aussi, mais les pentes sont très fortes et ils nous ont déjà fait supprimer des chutes dans les regards pour le limiter...

L'usure prématurée du tuyau peut-être un souci en raison des vitesses, mais pour ce qui est de l'autocurage il ne devrait pas y avoir de problème.

Contact va être pris avec un fabriquant, on verra bien son avis sur son produit et la possibilité d'un tel emploi.

Aucun_Intérêt · le 18 juin 2017

Ok il y a donc une problématique d'abrasivité par rapport aux pentes.

Mais ca n'enlève rien aux problèmes de regards. Il y a même le paramètre dilatation du PEHD selon ta région à prendre en compte.

Il n'est pas possible de mettre des regards avec une chute accompagnée ?

Le problème est qu'il risque d'y avoir des bouchons même avec des vitesses importantes.

En terme d'exploitation, cela va être très embêtant pour les recherches de fuites et même en cas de modification de réseaux dans les années qui suivront la mise en service.

J'interpellerai tout de même le MOA pendant une réunion (il faut absolument faire le CR qui suit pour vous couvrir) car il y a un devoir de conseil. On aime pas trop ce genre de position mais un MOE doit aussi interpeller le MOA avant que celui ci ne fasse une bêtise.

En plus de cela, je ne suis pas certain que l'Agence de l'Eau approuve ce principe. Surtout si elle met la main à la poche.

Avez vous jeté un oeil sur les solutions Polypropylène ?

Dans mon coin, on a aussi des problématiques de pentes importantes et la Métropole est partie (avec un petit coup de lobbying aussi je pense) sur le Polypro.

Réhau propose des solutions intéressantes là dessus mais je n'ai pas les prix.

Sur ce, bon week-end et n'oubliez pas de voter ^^

EDIT : j'ai récemment découvert une nouvelle technique de curage de conduite. Il s'agit de l'Ice Pigging qui est plutôt utilisée en industrie Agro alimentaire. Il s'agit d'injecter un bouchon de glace pilée et de le pousser avec un fluide (de l'eau par exemple). Ca limite beaucoup l'abrasivité et n'endommage pas le tube et en cas de blocage du bouchon de glace, on arrête tout et on attend que ca fonde. Très intéressant je trouve mais est que ca marche pour du gravitaire ..... Sinon voir les Ultrasons.

Pourquoi je dis ca, car si vous restez en PEHD sans regard (je poserai quelques vannes avec manipulation mensuelle), vous montrerez que vous vous êtes posé la question sur l'exploitation future du réseau.

Tchuss !

Demixav · le 19 juin 2017

Salut!

+1 avec Aucun_Interêt.

Suis surpris également par cette suppression de regards et ces poses en courbes. Mieux vaut ne jamais avoir de soucis sur ce réseau... :(

De plus, j'y verrai un autre point négatif si c'est un réseau à forte pente... ça sera certainement un réseau créateur de H2S en bas et/ou en haut de réseau.

Bon courage...

Aucun_Intérêt · le 19 juin 2017

En effet, j'avais pas pensé à l'H₂S. On réuni les conditions d'anaérobie car les regards assurant l'apport en O₂ sont supprimés.

Il y a donc un réel danger H₂S (intoxication et zone ATEX) non seulement pour les exploitants du réseau mais potentiellement pour les particuliers en cas de remontée par les branchements.

Si le MOA refuse de mettre des regards, il va falloir prévoir une circulation (pour peu que ta conduite ne soit pas un gravitaire forcé) haute et basse. Je pense comme ca a un système de branchements en culottes sur le collecteur remontant vers des lyres (qui risquent d'être sacrément hautes). Ca sera toujours mieux qu'un module d'injection d'air ou autre Nutriox mais très moche ....

Ernest · le 29 août 2017

Merci beaucoup pour toutes ces pistes et explications Aucun_intérêt!

Au final la MOA tient à son réseau PEHD malgré les points soulevés.

J'ai pourtant évoqué mes doutes et les vôtres mais on pense prix avant tout ici et le chef de projet semble avoir pris le parti du client...

Pour ce qui est de Covadis maintenant et de la pose en courbe, j'ai créé des nœuds intermédiaires sur mes "arcs", sans les équiper de regard.

Turtle · le 30 août 2017

Bonjour,

je viens mettre mon grain de sel !!!

Quel linéaire et diamètre de réseau, tu dois poser ?

Et pour la géolocalisation de ton réseau ?

Je ne connais pas les tarifs de ta région, mais au vu des prix par chez moi (environ 1500€ posé) , je ne vois aucun intérêt à ne pas mettre de regards au vu des inconvénients :o

Ernest · le 28 septembre 2017

Bonjour,

Le DN c'est du 200 int.

A priori la MOA n'en démord pas, on lui a fait acter par écrit qu'elle refuse notre solution technique et choisie en toute conscience cette solution.

Dossier clos en quelque sorte.

GEGEMATIC · le 2 octobre 2017

Salut a tous,

on a déjà utilisé cette solution dans le cas de traversée de périmètres de protection de captages,

avec de la forte pente.

pas de regards, mais des chambre d'inspection avec un té, une prise baillonette et un détecteur de pression qui donne l'alerte si la conduite se met en pression.

pour le H2s, si l'effluent ne stagne pas, je pense que ça devrait aller ?

ça fait bien 10 ans, pas eu de problème à ma connaissance.

a+

gégé

Aucun_Intérêt · le 3 octobre 2017

A condition que cela ne soit pas en charge.

Le cas de la protection de captage est particulier ceci dit ^^

Connexion

Assainissement PEHD

Messages recommandés

Ernest

lecrabe

lecrabe

Aucun_Intérêt

Ernest

Aucun_Intérêt

Demixav

Aucun_Intérêt

Ernest

Turtle

Ernest

GEGEMATIC

Aucun_Intérêt

Créer un compte ou se connecter pour commenter

Créer un compte

Se connecter

Forums

Naviguer

Activité

Information importante