LISP TRAITEMENT AFFICHAGE CONTENU MLEADER

[jcouaknine]

Bonjour,

 

Pourriez vous m'aider à trouver une solution pour mettre le contenu/texte de plusieurs lignes de repère en noir avec masque d'arrière du calque? (souhait esthétique de mon client).

 

Merci d'avance pour vos idées.

 

JC.

[bonuscad]

Bonjour,

 

Est ce bien le résultat de cette routine que tu désire?

 

(vl-load-com)
(defun c:test ( / js n ent mLeader)
(princ "\nSélectionner les lignes de repère multiples.")
(or
	(setq js (ssget "_I" '((0 . "MULTILEADER"))))
	(setq js (ssget "_P" '((0 . "MULTILEADER"))))
)
(cond
	(js
		(sssetfirst nil js)
		(initget "Existant Nouveau _Existent New")
		(if (eq (getkword "\nTraiter jeu de sélection [Existant/Nouveau] <Existant>: ") "New")
			(progn (sssetfirst nil nil) (setq js (ssadd) js (ssget '((0 . "MULTILEADER")))))
		)
	)
	(T
		(setq js (ssget '((0 . "MULTILEADER"))))
	)
)
(cond
	(js
		(repeat (setq n (sslength js))
			(setq mLeader (vlax-ename->vla-object (setq ent (ssname js (setq n (1- n))))))
			(vlax-put mLeader 'TextString (strcat "{\\C7;" (vlax-get mLeader 'TextString) "}"))
			(vlax-put mLeader 'TextBackgroundFill -1)
			(entmod (subst '(291 . 0) (assoc 291 (entget ent)) (entget ent)))
		)
	)
)
(prin1)
)

[jcouaknine]

Bonjour,

 

Apparemment, cela fonctionne à ceci près que le masque d'arrière plan est gris... et je souhaiterais aussi augmenter sa taille.

 

Comment doit-on modifier le code ?

Ou ai-je raté qquechose ?

 

merci Bonuscad.

[bonuscad]

Bonjour,

 

Change simplement la ligne

(entmod (subst '(291 . 0) (assoc 291 (entget ent)) (entget ent)))

 

par,

 

(entmod (subst '(141 . 5.0) (assoc 141 (entget ent)) (entget ent)))

 

Sachant que 5.0 est la valeur maxi pour la taille du masque (c'est une valeur d'échelle), à toi de mettre une valeur qui te convienne.

 

Cette substitution devrait répondre à tes remarques.