Symboliser une trémie

[zebulon_]

Bonjour,

 

symboliser une trémie dans un ouvrage BA en donnant 3 points d'une trémie rectangulaire.

 

;;; Clockwise-p
;;; Retourne T si les points p1 p2 et p3 tournent dans le sens horaire

(defun clockwise-p (p1 p2 p3)
 (< (sin (- (angle p1 p3) (angle p1 p2))) -1e-14)
)

(defun c:tremie (/ PT1 PT2 PT3 TEMP a1 d1 a2 d2 PT3bis PTI d P1 P2 P3 P4)
 (setq
   PT1 (getpoint "\nPremier point d'un côté : ")
   PT2 (getpoint PT1 "\nDeuxième point d'un côté : ")
   PT3 (getpoint "\nTroisième point perpendiculaire au côté : ")
 )

 ;; on s'arrange pour que ça tourne toujours dans le sens horaire
 (or (clockwise-p PT1 PT2 PT3)
   (setq
     TEMP PT1
     PT1 PT2
     PT2 TEMP
   )
 )

 
 (setq a1 (angle PT1 PT2))
 (setq d1 (distance PT1 PT2))

 (setq a2 (+ a1 (* 3 (/ pi 2))))
 (setq PT3bis (polar PT3 a2 1)) 
 (setq PTI (inters PT1 PT2 PT3 PT3bis nil))
 (setq d2 (distance PT3 PTI))

 (setq PT3 (polar PT2 a2 d2))

 (setq d (min d1 d2))

 (setq P1 (polar pt1 (+ a1 (* 7 (/ pi 4))) (/ d 20)))
 (setq P2 (polar pt2 (+ a1 (* 5 (/ pi 4))) (/ d 20)))
 (setq P3 (polar pt3 (+ a1 (* 3 (/ pi 4))) (/ d 20)))
 (setq P4 (polar p2 (+ a1 (* 5 (/ pi 4))) (/ d 10)))

 (command "_solid" "_non" P1 "_non" P2 "_non" p4 "_non" p3 "")
 (princ)  
)

 

Amicalement

Vincent

[lili2006]

Bonsoir à toutes et tous,

 

Salut Vincent,

 

Sympa,B)

 

Pourquoi le choix d'un solide plutôt qu'une hachure (Question de curisoité,...) ?

[Tramber]

Beaucoup plus léger le solide ;)

[zebulon_]

Bonsoir à toutes et tous,

 

Salut Vincent,

 

Sympa,B)

 

Pourquoi le choix d'un solide plutôt qu'une hachure (Question de curisoité,...) ?

 

plus léger, dans le sens que c'est un seul objet. Si tu fais une hachure, il faut un contour. Cela en fait deux, le contour et la hachure.

 

Le seul avantage qu'on pourrait avoir avec une hachure est qu'elle n'est pas forcément en solide, alors que le solide...

 

Amicalement

Vincent