valeur par defaut attribut

[pascal19]

Bonjour,

 

Comment peut-on redonner à un attribut sa valeur par défaut quand une autre valeur lui a été affecté ?

[zebulon_]

Bonjour,

 

Je ne m'étais jamais posé la question.

ATTSYNC ne change pas les valeurs affectées aux attributs dans les blocs existants.

Quant à BATTMAN Synchroniser, cela met à jour toutes les occurrences du bloc sélectionné avec les propriétés d'attribut actuellement définies, mais cette opération n'a aucune incidence sur les valeurs affectées aux attributs de chaque bloc.

 

Donc je sèche et je ne sais pas autrement qu'en programmation

 

(defun c:reatt (/ ATT EN B ATT_TAG B_NAME e DEF)
 (setq ATT (car (nentsel "\nAttribut à initialiser : ")))
 (if (= (cdr (assoc 0 (entget ATT ))) "ATTRIB")
   (progn
     (setq EN (entget ATT))
     (setq B (cdr (assoc 330 EN)))
     (setq ATT_TAG (cdr (assoc 2 EN)))
     (setq B_NAME (cdr (assoc 2 (entget B))))
     (setq e (tblobjname "BLOCK" B_NAME))
     (while (and (not DEF) (setq e (entnext e)))
       (and
         (= (cdr (assoc 0 (entget e))) "ATTDEF")
         (= (cdr (assoc 2 (entget e))) ATT_TAG)
         (setq DEF (cdr (assoc 1 (entget e))))
       )
     )
     ;; mettre à jour l'attribut
     (setq EN
       (subst (cons 1 DEF)
         (assoc 1 EN)
         EN
       )
     )
     (entmod EN)
     (entupd ATT)
   )
 )
 (princ)
)

 

Maintenant, il y a peut être une commande ou un express tool qui permet de faire la même chose

 

Amicalement

Vincent

Modifié le 25 mars 2015 par zebulon_

[pascal19]

Merci, je vais tester...

[VDH-Bruno]

zebulon_, un petit (entupd ATT) en sortie de code après le entmod sera du plus belle effet ;)

 

Amicalement,

Bruno

[zebulon_]

zebulon_, un petit (entupd ATT) en sortie de code après le entmod sera du plus belle effet ;)

 

 

Bonjour,

 

oui c'est vrai j'ai oublié, lorsqu'on modifie le sommet d'une polyligne 3D (ou une ancienne polyligne) ou un attribut, il faut mettre à jour l'entité complexe à l'écran avec entupd. C'est ce que dit l'aide de la fonction entupd.

Cependant, lorsque j'essaye sans cette fonction, l'affichage se regénère aussi. En tout cas chez moi.

 

 

Amicalement

Vincent

[VDH-Bruno]

Re,

Cependant, lorsque j'essaye sans cette fonction, l'affichage se regénère aussi. En tout cas chez moi.

Pas sur ma version 2007, et je n'ai pas connaissance d'une variable qui gère cela, je ne peux rien dire de plus.

 

A+

[zebulon_]

Re,

 

Pas sur ma version 2007, et je n'ai pas connaissance d'une variable qui gère cela, je ne peux rien dire de plus.

 

A+

 

j'utilise la version 2014. J'ai modifié le lisp pour rajouter entupd

 

merci

Amicalement

Vincent