menu contextuel dans editattribut

[sbosarl]

bonjour,

avec les commande Mtexte et texte ont as un menu (clic droit)

-> changer la case -> majuscule ou minuscule (ctrl+shift+u ou l)

pour l'edition des attributs ont n'as pas cette option ?

as t on la possiblité de faire de meme avec les attributs ?

[zebulon_]

Bonjour,

 

si on a des attributs à lignes multiples, on dispose d'un éditeur un peu plus évolué et de la possibilité de transformer un attribut de minuscule en majuscule ou inversement. Pour des attributs simples, cela ne semble pas être le cas.

 

Sinon, il y a cette possibilité :

 

(vl-load-com)

(defun attstrcase (flag / e obj tx)
 (setq e (car (nentsel "\nSélectionner un attribut : ")))
 (cond
   ((null e)
     (alert "Rien sélectionné !")
   )
   ((= (cdr (assoc 0 (entget e))) "ATTRIB")
     (setq obj (vlax-ename->vla-object e))
     (setq tx (vla-get-textstring Obj))
     (vla-put-textstring obj (strcase tx flag))
   )
   (T
     (alert "Pas un attribut !")
   )
 )
)

(defun c:attU ()
 (attstrcase nil)
 (princ)
)

(defun c:attL ()
 (attstrcase T)
 (princ)
)

(prompt "\nattU pour mettre un attribut en majuscules")
(prompt "\nattL pour mettre un attribut en minuscules")
(princ)

 

mais cela gère l'ensemble du texte de l'attribut, alors qu'avec un éditeur on peut sélectionner une partie du texte.

 

Amicalement

Vincent

[sbosarl]

bonjour, et merci

je vais tester se lsp et voir pour changer quelle attribut simple en multiligne

[sbosarl]

re,

le lsp correspont bien au attente , je revient quand meme sur un point

en testant j'ais selectionner mes attribut par ctrl+attribut

l'edition de l'attribut ce comporte comme un text ou un mtext avec sa ligne changer case

[zebulon_]

re,

le lsp correspont bien au attente , je revient quand meme sur un point

en testant j'ais selectionner mes attribut par ctrl+attribut

l'edition de l'attribut ce comporte comme un text ou un mtext avec sa ligne changer case

 

Bonjour,

 

effectivement avec la commande MODIFATTRINSITU, on arrive sans le lisp

 

Je ne connaissais pas cette commande. Merci pour le retour d'expérience.

 

Amicalement

Vincent