204 - D'autres sélections

[gtrghtr]

Bonjour,

 

J'ai un nouveau sujet:

 

est ce que quelqu'un a réussis à faire fonctionner le lisp:

204 - D'autres sélections ou Cf pj

 

lorsque je l’exécute et que je teste une commande (selbefore par exemple) j'obtient:

Commande: SELBEFORE
Entité limite(<Selection set: 2e9f>)
Commande:

mais rien n'est sélectionné à l’écran. :huh:

 

comment ce fais ce ?

Je suppose que la sélection d'objet "crée avant" est la sélection "2e9f" (c'est du dictionnaire ?)

mais comment est ce que je peux savoir a quoi correspond ce "2e9f" ?

 

Merci si vous avez une idée, un autre lisp ou solution équivalente ou nouvelle version que je n'aurai pas trouvé

 

et bon weekend

 

G

lsp.lsp

[GEGEMATIC]

salut,

tu as déterré un de mes très vieux lisp, (et pas un visual lisp)

outre le fait qu'à l'époque il n'y avais pas la la notion de gripped dans sssetfirst,

c'est pour ça que tu ne vois pas le résultat à l'écran,

cette version n'étais pas aboutie, car elle ne marchera pas avec les blocs et autres entités complexes.

Essaye plutôt la version actuelle :

Gérald

 

;;*************************************************************************
;;§/SELECTIONS/ crée un jeu de selection des entités suivant un element/none
(defun c:selafter ( / sel dep )
  (setq dep (car (entsel "\nEntité limite")))
  (setq sel (pw_selafter dep))
(sssetfirst sel sel )
)
;;*************************************************************************
;;§/SELECTIONS/ selectionne les entités anterieures à l'entité dep/none
;
(defun c:selbefore ( / dep sel ent )
(setq dep (car (entsel "\nEntité limite")))
  (setq sel (pw_selbefore dep))
(sssetfirst sel sel )
)
;;*************************************************************************
;;§/SELECTIONS/montre quelle est la dernière entité créé par les grips /none
;
(defun c:showlast ( / sel)
(setq sel (ssadd (entlast)))
(sssetfirst sel sel)
)
;;*************************************************************************
;;§/SELECTIONS/ selectionne les entités anterieur à l'entité dep/dep
;; ne marche pas !
(defun pw_selbefore ( dep / ent sel etyp )

(setq ent (entnext))
(setq sel (ssadd ent))
(while (and (/= nil (setq ent (entnext ent)))(not (eq ent dep)))
 (setq etyp (cdr (assoc 0  (entget ent))))
 (if (not (member etyp '("ATTRIB" "VERTEX" "SEQEND")))
  (setq sel (ssadd ent sel))
 )

  
)
sel
)
;;*************************************************************************
;;§/SELECTIONS/  crée un jeu de selection des entités suivant un element/ent
;;fonction ralentie par la 2006, qui n'axepte pas les sequend
;;donc necessité de faire un entget pour chaque entité
;;
(defun pw_selafter (ent / sel etyp)
 ;;si le dessin etait vierge, ent = nil
 (if ent
   (setq sel (ssadd))
   (if	(setq ent (entnext))
     (progn (setq sel (ssadd))
     (setq sel (ssadd ent sel))
     )
   )
 )
 (if ent
   (progn
     (while (setq ent (entnext ent))
(setq etyp (cdr (assoc 0 (entget ent))))
(if (not (member etyp '("ATTRIB" "VERTEX" "SEQEND")))
  (setq sel (ssadd ent sel))
)
     )
     (if (> (sslength sel) 0)
      sel
nil
     )
   )
   nil
 )
)

[gtrghtr]

:) :)

Effectivement, cette nouvelle version fonctionne bien, c'est parfait merci beaucoup.

je vais m' attaquer à le décortiquer et comprendre son fonctionnement, parce que la j'ai pas encore tout compris (déjà la subtilité entre lisp et visual lisp ...)

 

MERCI et bonne semaine

[GEGEMATIC]

:) :)

(déjà la subtilité entre lisp et visual lisp ...)

salut,

dans ce code, il n'y a aucune fonction visual-lisp, celles qui commencent par vl-, vlr- , vla- ou vlax-.

c'est tout.

je pense qu'à l'époque, je bossais sur une v14, qui n'avait pas le visual-lisp en standard (il fallait l'installer à part, et perdu dans ma savoie, je n'étais même pas au courant ...)

Gérald