cote d'angle supérieure à 180°

orionis · le 28 mai 2014

Bonjour à tous,

je cherche à coter un angle supérieur à 180°, a priori ce n'est pas possible? Je me retrouve à chaque fois avec l'angle complémentaire.

Existe-t-il un moyen de contourner ce blocage?

(gile) · le 28 mai 2014

Salut,

À la première invite de la commande COTANG :

"Choix de l'arc, cercle, ligne ou : "

tu valides "indiquez un sommet" par Entrée, puis tu spécifies le sommet de l'angle, la première extrémité, la seconde et tu peux placer ta cote dans la zone de l'angle supérieure à 180°.

Fundream · le 28 mai 2014

Il faut que tu selectionne les sommets de l'angle et non les lignes

EDIT : Grillé :angry:

rebcao · le 28 mai 2014

Bonjour,

Oui, il faut utiliser l'option <INDIQUER SOMMET> de la commande cote angulaire... tu fais simplement ENTREE.

Christian

orionis · le 28 mai 2014

Ah ben oui, ça marche!

Merci.

nicolas2 · le 14 février 2018

Bonjour à tous,

Est-il possible de faire apparaitre la cotation comme ceci ?

http://zupimages.net/viewer.php?id=18/07/x7rw.jpg

Merci.

lili2006 · le 14 février 2018

Bonjour à toutes et tous,

Oui ! Au lancement de la commande cotation angulaire, faire une entrée à vide pour pouvoir sélectionner le point, puis les branches,..

Commande: _dimangular
Choix de l'arc, cercle, ligne ou <indiquez un sommet>:
Indiquez le sommet de l'angle:
Indiquez la première extrémité de l'angle:
Indiquez la seconde extrémité de l'angle:
Indiquez la position de la dimension de l'arc de cote ou [textMult/TExte/Angle/Quadrant]:
Texte de cote = 180

Christian l'avais déjà écrit ici

nicolas2 · le 20 février 2018

Bonjour à toutes et tous,

Merci Lili !

Quand on prend l'habitude d'utiliser une commande, on ne prend plus le temps de lire toutes les options proposées...

Une question cependant :

Serait il possible de coter les angles de la même façon, mais à la volée ?

- Cliquer sur l'axe 0°-180° (pour donner une base)

- Cliquer sur l'axe 22.5° [cela permet de trouver le sommet (axes concourants)]

- Déposer le texte manuellement en bout d'axe

- Cliquer sur l'axe suivant sans redonner la base 0°-180°, déposer le texte

- Cliquer sur l'axe suivant...

Faudrait il se tourner du côté LISP ?

Merci à vous.

(gile) · le 20 février 2018

Salut,

Je ne suis pas sûr de comprendre la demande.

Il me semble que s'il s'agit de reproduire l'image en lien, un bloc devrait faire l'affaire.

nicolas2 · le 20 février 2018

Bonjour,

En PJ un exemple de deux appareils complètement différents:

http://zupimages.net/viewer.php?id=18/08/vewf.jpg

Sur le premier appareil, par exemple, il faut que je fasse 12x la même manipulation (cotation angulaire, indiquer un sommet, indiquer le sommet de l'angle, indiquer la 1iére extrémité de l'angle,...) pour arriver à coter tous les angles.

Les appareils sont toujours différents, mais la cotation suit toujours la même logique.

Merci pour votre aide.

(gile) · le 20 février 2018

OK, je te propose un petit LISP, il faut que dans le style de cote, la "Position du texte", case "Horizontal" soit sur : "Au dessus de la ligne d'attache 1".

(defun c:test (/ cen org pt)
 (if
   (and
     (setq cen (getpoint "\nSommet de l'angle: "))
     (setq org (getpoint cen "\nExtrémité de l'axe de base: "))
   )
    (progn
      (command "_.DIMANGULAR" "" "non" cen "non" org "non" org "non" org)
      (while (setq pt (getpoint cen "\nExtrémité de l'angle suivant: "))
        (command "_.DIMANGULAR" "" "non" cen  "non" pt "non" org "non" pt)
      )
    )
 )
 (princ)
)

nicolas2 · le 20 février 2018

Merci Gile !

Quelques questions :

1- Sur mes plans, j'ai aussi de la cotation angulaire "traditionnelle", pour des détails de mécanique notamment (voir le lien), serait il possible de garder cette possibilité de cotation "traditionnelle" et aussi la cotation comme dans votre LISP ?

3- Serait il possible que la position des textes soit conforme au croquis "En final", c'est à dire centré et en bout de l'axe [sur le LISP, si j'essaie de le bouger par la suite, une fois la côte posée, le texte change d'angle (position)]?

2- Serait il possible d'avoir l'écriture des angles 0°-180° horizontale ?

http://zupimages.net/viewer.php?id=18/08/jvlw.jpg

Merci encore pour votre aide.

(gile) · le 20 février 2018

1- Il suffit de définir deux styles de cotation.

2- 3- C'est plus compliqué en utilisant les cotations. Je te propose une solution avec juste des lignes et des textes.

(defun c:test (/ cen org dist ang0 ang pt)
 (if
   (and
     (setq cen (getpoint "\nCentre de la cotation: "))
     (setq org (getpoint cen "\nExtrémité de l'axe de base: "))
   )
    (progn
      (setq dist (distance cen org)
            ang0 (angle cen org))
      (command "_.line" "_non" cen "_non" org "")
      (command "_.text" "_justify" "_BC" "_non" org "" 0.0 "0°")
      
      (setq pt (polar cen (+ pi ang0) dist))
      (command "_.line" "_non" cen "_non" pt  "")
      (command "_.text" "_justify" "_TC" "_non" pt "" 0.0 "180°")
      
      (setq pt (polar cen (- ang0 (* 0.5 pi)) dist))
      (command "_.line" "_non" cen "_non" pt  "")
      (command "_.text" "_justify" "_ML" "_non" pt "" 0.0 "90°")
      
      (setq pt (polar cen (- ang0 (* 1.5 pi)) dist))
      (command "_.line" "_non" cen "_non" pt  "")
      (command "_.text" "_justify" "_MR" "_non" pt "" 0.0 "270°")
      
      (while (setq pt (getpoint cen "\nExtrémité de l'angle suivant: "))
        (setq ang (angle cen pt))
        (command "_.line" "_non" cen "_non" pt  "")
        (command "_.text"
                 "_justify"
                 "_ML"
                 "_non"
                 pt
                 ""
                 (angtos ang (getvar 'aunits) 16)
                 (strcat (angtos (- ang0 ang)) "°")
        )
      )
    )
 )
 (princ)
)

DenisHen · le 20 février 2018

Salut à tous...

On n'est pas dans le forum AutoCAD LT 2013 ?

lecrabe · le 20 février 2018

Hello

YES Mr DenisHen !

Enfin un contributeur qui lit bien !

Néanmoins MERCI Gilles pour les Routines !!

Bye, lecrabe

(gile) · le 20 février 2018

C'est nicolas2 qui a déterré ce sujet et évoquer un LISP pour son problème.

Il aurait peut-être dû commencer un nouveau sujet, mais bon, c'est fait.

DenisHen · le 20 février 2018

YES Mr DenisHen !

Je disais ça car je ne comprenais pas ce que pouvait faire nicolas2 avec un LISP sous LT...

C'est nicolas2 qui a déterré ce sujet et évoquer un LISP pour son problème.

Je ne t'incriminais nullement (gile)...

Ni nicolas2... errare humanum est, et je suis bien placé pour le savoir... ;)

nicolas2 · le 20 février 2018

Je ne suis clairement pas dans le bon forum, milles excuses !

Merci Gile de prendre du temps pour mon problème.

http://zupimages.net/viewer.php?id=18/08/jorb.jpg

- Serait il possible de modifier l'angle d'écriture au delà du 180° ?

- Serait il possible de ne pas écrire automatiquement 0°-90°-180°-270°, mais le gérer comme les autres écritures (à part le fait que l'écriture soit horizontale) ? En fait, si nous rajoutons un autre angle non prévu au départ (exemple 45°) et que nous relançons le LISP pour ce nouvel angle, le LISP va réécrire 0°-90°-180°-270° sur l'écriture déjà existante je crois (?)

Merci encore à vous.

(gile) · le 20 février 2018

Voilà une version plus aboutie.

(defun c:cotcirc (/ *error* space cen pt ang ht just rot text)
 (vl-load-com)
 (or *acdoc*
     (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
 )
 (defun *error* (msg)
   (and msg
        (/= msg "Fonction annulée")
        (prompt (strcat "\nErreur : " msg))
   )
   (vla-EndUndoMark *acdoc*)
   (princ)
 )
 (if (setq cen (getpoint "\nCentre de la cotation: "))
   (progn
     (vla-StartUndoMark *acdoc*)
     (setq space (vla-get-Block (vla-get-ActiveLayout *acdoc*)))
     (while (setq pt (getpoint cen "\nExtémité de l'angle: "))
       (setq pt (trans pt 1 0)
             cen (trans cen 1 0)
             ang (angle cen pt)
             ht (getvar 'textsize))
       (cond
         ((equal ang (* pi 0.5) 1e-9)
          (setq just acAlignmentBottomCenter
                rot  0.0
          )
         )
         ((equal ang (* pi 1.5) 1e-9)
          (setq just acAlignmentTopCenter
                rot  0.0
          )
         )
         ((< (* pi 0.5) ang (* pi 1.5))
          (setq just acAlignmentMiddleRight
                rot  (+ pi ang)
          )
         )
         (T
          (setq just acAlignmentMiddleLeft
                rot  ang
          )
         )
       )
       (vla-AddLine space (vlax-3d-point cen) (vlax-3d-point pt))
       (setq text (vla-AddText space (strcat (angtos (- (* 0.5 pi) ang)) "°") (vlax-3d-point pt) ht))
       (vla-put-Rotation text rot)
       (vla-put-Alignment text just)
       (vla-put-TextAlignmentPoint text (vlax-3d-point pt))
     )
   )
 )
 (*error* nil)
)

nicolas2 · le 20 février 2018

Merci Gile !

Une dernière petite demande si je peux me permettre :

Le même mais sans tracer les traits, uniquement l'écriture ?

(gile) · le 20 février 2018

Il suffit de supprimer la ligne (ou de la mettre en commentaire avec deux points-virgules au début) :

(vla-AddLine space (vlax-3d-point cen) (vlax-3d-point pt))

nicolas2 · le 21 février 2018

Bonjour à tous,

et MERCI Gile pour votre aide !

Longue vie à CADXP.

Connexion

cote d'angle supérieure à 180°

Messages recommandés

orionis

(gile)

Fundream

rebcao

orionis

nicolas2

lili2006

nicolas2

(gile)

nicolas2

(gile)

nicolas2

(gile)

DenisHen

lecrabe

(gile)

DenisHen

nicolas2

(gile)

nicolas2

(gile)

nicolas2

Créer un compte ou se connecter pour commenter

Créer un compte

Se connecter

Forums

Naviguer

Activité

Information importante