Modifier un attribut d'un bloc

[Clément.a]

Bonjour à tous,

 

Comment modifier un attribut d'un bloc?

sans passer par

(command "attedit")

Merci

[Clément.a]

Après quelques heures d'acharnement voila le résultat :

 

(defun c:bb ( / ent ss atts)
 (vl-load-com)
 (while (null ent )
 (setq ent  (car(entsel "Séléctionné l'attribut :"))))
 (setq ss  (vlax-ename->vla-object ent))
 (setq atts (vlax-invoke ss 'getattributes))
 (vla-put-TextString (car atts) "jh"); "jh" étant le nouveau attribut
)

[alala]

Bonjour,

 

Juste une suggestion pour faire plus "simple" en partant de la même base :

 

(defun c:bobo ( / ent ss atts)
 (vl-load-com)
 (while (null ent )
 (setq ent  (car(nentsel "Séléctionnez l'attribut :"))))
 (setq ss  (vlax-ename->vla-object ent))
 (vla-put-TextString ss "jh"); "jh" étant le nouveau attribut
)

 

Et en plus ça fonctionne sur l'attribut sélectionné dans le bloc et pas uniquement sur le premier.

 

@+

[Clément.a]

Y à-t-il un

next

en Lisp?

parce que j'ai un

foreach

avec plein de condition et ça aurait été bien si y passait au suivant quand il avait verifié une condition.

(defun c:bsbs ( / ent ss atts)
 (vl-load-com)
 (while (null ent )
 (setq ent  (car(entsel "Séléctionné le bloc avec attribut :"))))
 (setq ss  (vlax-ename->vla-object ent))
 (setq atts (vlax-invoke ss 'getattributes))
 (vla-put-TextString (car atts) "jh")
 (foreach att atts
   (if (eq (vla-get-TagString att) "ITEM")
   (vla-put-TextString att item_final))
   (if (eq (vla-get-TagString att) "NB")
   (vla-put-TextString att "1"))
   (if (eq (vla-get-TagString att) "DN")
   (vla-put-TextString att dn_final))
   (if (eq (vla-get-TagString att) "LONG.")
   (vla-put-TextString att longueur_final))
   (if (eq (vla-get-TagString att) "PN")
   (vla-put-TextString att pn_final))
   (if (eq (vla-get-TagString att) "TYPE")
   (vla-put-TextString att type_final))
   (if (eq (vla-get-TagString att) "FACE")
   (vla-put-TextString att face_final))
   (if (eq (vla-get-TagString att) "ELEVATION")
   (vla-put-TextString att elev_final))
   (if (eq (vla-get-TagString att) "DESIGNATION")
   (vla-put-TextString att design_final))
   (if (eq (vla-get-TagString att) "OBSERVATION")
   (vla-put-TextString att obs_final))
   )
)

[(gile)]

Salut,

 

Regarde la fonction cond.

 

(foreach att atts
 (cond 
  ((eq (vla-get-TagString att) "ITEM")
   (vla-put-TextString att item_final))
  ((eq (vla-get-TagString att) "NB")
   (vla-put-TextString att "1"))
  ; ...
 )
)

[Clément.a]

ah oui... je suis bête, c(est que je passe toute les 3h du VBA au LISP alors je mélange un peu tout :blink:

 

merci (gile)

[Patrick_35]

Salut

 

Déjà avec COND

(cond
 ((eq (vla-get-TagString att) "ITEM")
   (vla-put-TextString att item_final))
 )
 ((eq (vla-get-TagString att) "NB")
   (vla-put-TextString att "1"))
 )
 ((eq (vla-get-TagString att) "DN")
   (vla-put-TextString att dn_final))
 )
 ((eq (vla-get-TagString att) "LONG.")
   (vla-put-TextString att longueur_final))
 )
 ((eq (vla-get-TagString att) "PN")
   (vla-put-TextString att pn_final))
 )
 ((eq (vla-get-TagString att) "TYPE")
   (vla-put-TextString att type_final))
 )
 ((eq (vla-get-TagString att) "FACE")
   (vla-put-TextString att face_final))
 )
 ((eq (vla-get-TagString att) "ELEVATION")
   (vla-put-TextString att elev_final))
 )
 ((eq (vla-get-TagString att) "DESIGNATION")
   (vla-put-TextString att design_final))
 )
 ((eq (vla-get-TagString att) "OBSERVATION")
   (vla-put-TextString att obs_final))
 )
)

 

Avec une liste

(setq lst (list (cons "ITEM"		item_final)
	(cons "NB"		"1")
	(cons "DN"		dn_final)
	(cons "LONG"		longueur_final)
	(cons "PN"		pn_final)
	(cons "TYPE"		type_final)
	(cons "FACE"		face_final)
	(cons "ELEVATION"	elev_final)
	(cons "DESIGNATION"	design_final)
	(cons "OBSERVATION"	obs_final)
  )
)
(and (setq ele (assoc (vla-get-TagString att) lst))
 (vla-put-TextString att (cdr ele))
)

 

En plus subtile en jouant avec les variables

Les Tag de tes attributs doivent avoir le même nom que les variables

(setq ITEM 0 NB 1 DN 2 LONG 3 PN 4)
(eval (read (vla-get-TagString att)))

Un exemple si le TAG = "NB", la valeur retournée est 1

 

ps : gile à été plus rapide, mais comme il y a d'autres solutions ;)

 

@+

[Clément.a]

Merci