Editeur Etendu des Attributs dans les Palettes d'outils

[Fraid]

Bonjour,

 

Lorsque j’insère un bloc avec attributs via les palettes d'outils, c'est l'éditeur simple qui s'ouvre.

 

Y a t'il un moyen d'avoir d’éditeur étendu?

 

en fait ce qui m’énerve, c'est que ctrl+entrée ne fonctionne pas dans le simple...

[lili2006]

Bonsoir à toutes et tous,

 

Heu, je comprends pas bien

c'est l'éditeur simple qui s'ouvre.

!!

 

Que veux tu dire exactement ?

 

Merci d'avance,

[Fraid]

Quand on double clic sur attribut, l'éditeur étendu s'ouvre.

 

Quand j’insère un bloc avec attribut par une palette c'est un autre editeur.

[lili2006]

Re,

 

Pourrais-tu mettre une image STP ?

 

Cela n'est pas lié à la variable "attdia", de mémoire ?

 

Mais je ne pense pas que c'est moi qui vais t'apprendre les variables,...:P

 

D'ou ma question précédente,..:mellow:

[Fraid]

cela ne fait pas la meme chose chez toi?

 

quand tu insere un bloc avec attribut par une palette tu as l'editeur etendu?

[lili2006]

Re,

 

Désolé, je n'ai pas de AutoCAD sous le coude mais je me rappelle qu'il y a plusieurs façon de renseigner les attributs d'un bloc "glissé" depuis la palette suivant une variable,..

[bryce]

Bonjour,

 

En résumé :

- si ATTREQ = 0, AutoCAD ne demandera pas de renseigner les attributs, quelle que soit la manière dont le bloc a été inséré (commande INSERER ou via une palette)

- si ATTREQ = 1 et ATTDIA = 0, il faut renseigner les attributs en ligne de commande lors de l'utilisation de la commande INSERER. En utilisant une palette d'outils, c'est l'éditeur d'attributs simple qui s'affiche

- si ATTREQ = 1 et ATTDIA = 1, l'éditeur d'attributs simple s'affiche lors de l'insertion (avec la commande INSERER ou via une palette).

 

L'éditeur étendu ne s'affiche que lors de la modification (double-clic sur le bloc après insertion).

Il n'existe pas (à ma connaissance) de moyen simple pour afficher l'éditeur étendu directement au moment de l'insertion, en remplacement de l'éditeur simple. :(

 

Si tu as envie de tester (à tes risques et périls :P ), j'ai bricolé avec des réacteurs un truc qui marche pas trop mal a priori :

(vl-load-com)
(if (= (type *insertionreactor*) 'VLR-Command-Reactor)
 (progn
   (vlr-remove *insertionreactor*)
   (setq *insertionreactor* nil)
 )
)
(setq *insertionreactor* (vlr-command-reactor "insertionreactor" '(
                   (:vlr-commandWillStart . beforeinsertion)
                   (:vlr-commandEnded . afterinsertion)
                   (:vlr-commandCancelled . insertionfailed)
                   (:vlr-commandFailed . insertionfailed)
                 ))
)

(defun beforeinsertion ( rea data / commande )
 (setq commande (strcase (car data)))
 (if (or
       (= commande "EXECUTETOOL")
       (and (= (getvar 'attdia) 1) (member commande '("INSERT" "-INSERT")))
     )
   (progn
     (setq *attreq* (getvar 'attreq))
     (setvar 'attreq 0)
   )
 )
 (princ)
)

(defun afterinsertion ( rea data / lastent commande )
 (setq commande (strcase (car data)))
 (if (or
       (= commande "EXECUTETOOL")
       (and (= (getvar 'attdia) 1) (member commande '("INSERT" "-INSERT")))
     )
   (progn
     (setvar 'attreq *attreq*)
     (if (and
           (= *attreq* 1)
           (setq lastent (vlax-ename->vla-object (entlast)))
           (= "ACDBBLOCKREFERENCE" (strcase (vla-get-objectname lastent)))
           (= (vla-get-hasattributes lastent) :vlax-true)
           (or *acdoc* (setq *acdoc* (vla-get-activedocument (vlax-get-acad-object))))
         )
       (vla-sendcommand *acdoc* "_eattedit _l ")
     )
   ) 
 )
 (princ)
)

(defun insertionfailed ( rea data / commande )
 (setq commande (strcase (car data)))
 (if (or
       (= commande "EXECUTETOOL")
       (and (= (getvar 'attdia) 1) (member commande '("INSERT" "-INSERT")))
     )
     (setvar 'attreq *attreq*)
 )
 (princ)
)

(princ)

 

Il suffit de charger le code, il n'y a aucune commande à exécuter.

[Fraid]

Merci Bryce

 

je teste cela ce soir

 

je n'avais pas du tout penser a chercher dans ce sens.

 

je vais regarder le code de prés ;)

[Fraid]

ça marche BRAVO

 

et je vais explorer VLA-SENDCOMMAND que je ne connaissais pas.

cela m'a l'air très intéressant :D

 

merci encore

[lili2006]

Bonsoir à toutes et tous,

 

Merci Bryce,