[AUTOCAD-2012] Modifier un MNT sans Covadis

[Gwen]

Bonjour,

 

J'aurais besoin de quelques informations, je suis dessinateur chez un developpeur de parc éolien et je réalise actuellement les plans pour la construction d'un parc.

 

je dispose d'un MNT(carré de ± 100 m de coté) dressé par un géomètre. j'ai mis en place les differentes plateformes pour la construction d'une des éoliennes.

Le terrain est en legère pente, mais surtout, le chemin d'accès est sur une bute. je cherche donc l'altitude idéale pour optimiser le terrassement

 

J' ai remarqué que je pouvais déplacer les 3 sommets qui composent chaque surface de mon MNT, mais impossible de rajouter un pt au milieu d'un des segments composant chaque triangle.

 

Donc, je voudrais savoir si il est possible de modifier ce MNT sans Covadis.

 

Merci d'avance.

[pbrion]

Un MNT est constitué de Face3D AutoCAD. Ce ne sont pas des polylignes, donc, il n'est pas possible d'ajouter un sommet dans une face.

Par contre, il est possible de supprimer des faces et d'en reconstruire avec la commande FACE3D. (Menu Dessin -> Modélisation -> Maillage -> Face 3D)

Les faces 3D peuvent avoir 3 ou 4 sommets maximum.

[Gwen]

Un MNT est constitué de Face3D AutoCAD. Ce ne sont pas des polylignes, donc, il n'est pas possible d'ajouter un sommet dans une face.

Par contre, il est possible de supprimer des faces et d'en reconstruire avec la commande FACE3D. (Menu Dessin -> Modélisation -> Maillage -> Face 3D)

Les faces 3D peuvent avoir 3 ou 4 sommets maximum.

 

Merci pour l'info, j'ai commencé à modéliser les talus pour le terrassemnt, j'avance plutôt vite.

Pour ceux que sa interrese, voila le lien du Site du Zéro, ou j'ai trouvé un tuto plus bien expliqué sur la 3D avec autocad.

[bonuscad]

il n'est pas possible d'ajouter un sommet dans une face

 

C'est vrai que cela peut être fastidieux de faire ça manuellement, du coup j'ai penser à faire un truc comme ça.

Après le résultat, il suffit de griper le sommet central et de l’emmener où on veut.

 

(defun C:subdivise3dface ( / ent dxf_ent typ_ent lst nb pt_div js)
 (while (/= typ_ent "3DFACE")
   (setq
     ent (entsel "\nChoix de la 3Dfaces à subdiviser: ")
     typ_ent (cdr (assoc 0 (setq dxf_ent (entget (car ent)))))
   )
 )
 (setq lst
   (list
     (cdr (assoc 10 dxf_ent))
     (cdr (assoc 11 dxf_ent))
     (cdr (assoc 12 dxf_ent))
     (cdr (assoc 13 dxf_ent))
   )
 )
 (if (equal (caddr lst) (last lst) 1E-13)
   (setq lst (list (car lst) (cadr lst) (caddr lst)) nb 3.0)
   (setq nb 4.0)
 )
 (setq pt_div
   (list
     (/ (apply '+ (mapcar 'car lst)) nb)
     (/ (apply '+ (mapcar 'cadr lst)) nb)
     (/ (apply '+ (mapcar 'caddr lst)) nb)
   )
   lst (append lst (list (car lst)))
 )
 (entdel (car ent))
 (setq js (ssadd))
 (repeat (fix nb)
   (entmake
     (list
       '(0 . "3DFACE")
       '(100 . "AcDbEntity")
       (assoc 67 dxf_ent)
       (assoc 410 dxf_ent)
       (assoc 8 dxf_ent)
       '(100 . "AcDbFace")
       (cons 10 (car lst))
       (cons 11 (cadr lst))
       (cons 12 pt_div)
       (cons 13 pt_div)
       '(70 . 0)
     )
   )
   (setq
     js (ssadd (entlast) js)
     lst (cdr lst)
   )
 )
 (sssetfirst nil js)
 (prin1)
)

[Gwen]

Encore une petite question,

 

Mon MNT est tellement complexe (pente tres prononcé a un endroit) et j'ai du mal à apprécier le devers du terrain.

 

Je voudrais donc savoir si il est possible de mettre en surbrillance les aretes delimitant les polygones d'un maillage, j'ai regardé dans les propriétes des objets et dans les option, mais j'ai pas reussi à trouver.

 

Merci par avance

[pbrion]

Je ne vois pas bien en quoi le fait de mettre en surbrillance les arêtes peut permettre de mieux apprécier le dévers !

Mais il suffit de mettre une épaisseur au calque du MNT et d'activer l'affichage des épaisseurs dans les aides au dessin.

Pour mieux voir le relief, il me semble qu'une vue 3D avec un style visuel Conceptuel ou réaliste serait plus judicieux. Eventuellement en partageant l'écran en 2 fenêtres, une pour la vue en plan et l'autre pour la vue 3D.

[bonuscad]

Peut être ceci, en repartant de la structure du code ci-dessus.

 

(defun C:Mask_PerCent ( / js ref_spl n ent dxf_ent lst nb cnt dxf_70 d_x d_z slop)
 (setq js (ssget '((0 . "3DFACE"))))
 (cond
   (js
     (initget 5)
     (setq ref_slp (getreal "\nPente (en %) de référence pour masquer les arrêtes des 3DFACEs: "))
     (repeat (setq n (sslength js))
       (setq
         ent (ssname js (setq n (1- n)))
         dxf_ent (entget ent)
         lst
         (list
           (cdr (assoc 10 dxf_ent))
           (cdr (assoc 11 dxf_ent))
           (cdr (assoc 12 dxf_ent))
           (cdr (assoc 13 dxf_ent))
         )
       )
       (if (equal (caddr lst) (last lst) 1E-13)
         (setq lst (list (car lst) (cadr lst) (caddr lst)) nb 3.0)
         (setq nb 4.0)
       )
       
       (setq lst (append lst (list (car lst))) cnt 1 dxf_70 '(0))
       (repeat (fix nb)
         (setq
           d_x (distance (list (caar lst) (cadar lst)) (list (caadr lst) (cadadr lst)))
           d_z (abs (- (caddar lst) (caddr (cadr lst))))
           slop (* (/ d_z d_x) 100.0)
         )
         (if (>= slop ref_slp)
           (setq dxf_70 (cons cnt dxf_70))
         )
         (setq cnt (* cnt 2))
       )
       (entmod (subst (cons 70 (apply '+ dxf_70)) (assoc 70 dxf_ent) dxf_ent))
     )
   )
 )
 (prin1)
)