TEXTE ALTITUDE POINT

lili2006 · le 16 octobre 2012

Bonjour à toutes et tous,

Sur un plan, j'ai des textes "altitudes projets",

J'ai donc utiliser la fonction "cov-edition => Texte => Attribut" avec l'option du dessin d'un point.

Mon plan étant en 3D, le point monte bien à l'altitude définie par le texte.

Ce que je voudrais également c'est que le texte en lui même prenne la même altitude que le point (autrement dis que le texte,..).

Est-ce possible ?

En vue 3D il m'arrive d'avoir besoin de cette info sans être obligé d'avoir également sous le coude une vue en plan...

Merci d'avance,

PS: Je suis sous v.13.e, je ne sais pas si cette info est importante,...:mellow:

didier · le 16 octobre 2012

coucou

tu mélanges bien des termes

Ce que je voudrais également c'est que le texte en lui même prenne la même altitude que le point (autrement dis que le texte,..).

je pense que tu veux dire que l'attribut du point topo prenne l'altitude du point, donc la valeur du texte

c'est bien cà ?

si oui, les attributs du pt de Covadis suivent le point (bloc)

amicalement

VDH-Bruno · le 16 octobre 2012

Bonjour lili2006

Au risque de répondre à côté, ne connaissant rien de covadis, si didier est dans le vrai :

je pense que tu veux dire que l'attribut du point topo prenne l'altitude du point, donc la valeur du texte

Les routines de la discussion suivante font cela :

http://cadxp.com/index.php?/topic/33778-resolu-point-topographique-covadis-2d-3d/page__p__182436__fromsearch__1#entry182436

Sinon si c’est des textes ou textes multiples à élever teste ses quelques lignes de codes, voir si cela peut dépanner..

;; Positionne en Z (SCG) des textes et des mtext suivant la valeur de leur texte (code 1)
(defun c:lili1 (/ pt i sel edxf val)  
        (prompt "\nSélectionnez les textes à éléver à leurs altitudes respectives...")  
        (repeat (setq i (if (setq sel (ssget '((0 . "*TEXT"))))
                          (sslength sel)
                          0
                        )
                ) 
          (setq edxf (entget (ssname sel (setq i (1- i)))))
          (setq pt (cdr (assoc 10 edxf)))
          (if (numberp (setq val (read (cdr (assoc 1 edxf)))))
            (entmod (subst (cons 10 (list (car pt) (cadr pt) val)) (cons 10 pt) edxf))
          )
        )
         
  (princ)
)

Cordialement,

VDH-Bruno · le 16 octobre 2012

Re,

Sinon au cas où, une petite dernière tapé à la va-vite, qui met le Z de l’attribut à la même valeur que le Z du point d’insertion de la référence de bloc correspondante..

;; Positionne les attributs au même Z (SCG) que la référence de bloc
(defun c:lili2 (/ pt i sel eblk ent edxf zpins)
 (prompt "\nSélectionnez les références de blocs dont les attributs sont à traiter...")
 (repeat (setq i (if (setq sel (ssget '((0 . "INSERT") (66 . 1))))
                   (sslength sel)
                   0
                 )
         )
   (setq eblk  (ssname sel (setq i (1- i)))
         zpins (caddr (cdr (assoc 10 (entget eblk))))
         ent   (entnext eblk)
   )
   (while (= "ATTRIB" (cdr (assoc 0 (setq edxf (entget ent)))))
     (entmod
       (subst (cons 10 (list (car (setq pt (cdr (assoc 10 edxf)))) (cadr pt) zpins)) (assoc 10 edxf) edxf)
     )
     (setq ent (entnext ent))
   )
   (entupd eblk)
 )
 (princ)
)

A+

lili2006 · le 16 octobre 2012

Re,

Salut Didier et Bruno,

je pense que tu veux dire que l'attribut du point topo prenne l'altitude du point, donc la valeur du texte

A la base c'est uniquement du texte (ou mtext que j'ai décomposé pour avoir le "grip" du texte et pouvoir utiliser la commande : "cov-edition => Points Topo => Affecte Z selon Texte avec l'option du dessin d'un point.").

Suite à cette commande, le texte reste un texte et le point passe bien à l'altitude souhaitée.

Je ne peux donc pas utiliser la fonction "cov-edition => Points Topo => (fonction attributs) puisque ce n'est pas un attribut (et encore moins un point topo,..!)!

J'ai souvenir avoir déjà eu ce besoin sans "galérer" plus que ça,...J'ai du oublié une manip. vraisemblablement,...

Pour vous faire une idée, je fichier joint en "zoom" sur un des points à traiter (calque "V_COTE_TA),...

Bruno, j'ai testé

"lili1" fonctionne parfaitement, dommage que l'on ne puisse pas faire une sélection "filtrée" ou mieux, par calques,..Par contre coupler à la commande covadis "cov-edition => Points Topo => Affecte Z selon Texte avec l'option du dessin d'un point.", j'obtiens bien le résultat souhaité, et dans un premier temps, c'est une très bonne chose, merci encore,

"lili2" ne fonctionne que sur des attributs,...

Autrement dis, si covadis ne le fait pas (je suis cependant sceptique,..), il faudrait :

Créer un point au droit du point d'insertion du texte

Transformer ce point et ce texte en bloc (le texte deviendrait alors un attribut)

Monter à l'altitude décrite par le texte devenu un attribut le bloc point ainsi créé.

Merci encore,

VDH-Bruno · le 16 octobre 2012

Bonsoir,

"lili1" fonctionne parfaitement, dommage que l'on ne puisse pas faire une sélection "filtrée" ou mieux, par calques,..

Nouvelle version à tester:

(defun c:lili1 (/ pt i sel edxf val ent compt x)
 (setq compt 0)

 (or
   (and (setq sel (cadr (ssgetfirst)))
 (= 1 (sslength sel))
 (setq ent (ssname sel 0))
   )

   (while (not ent)
     (prompt
"\nPointez un texte en référence des textes à éléver..."
     )
     (and (setq sel (ssget "_+.:E:S" '((0 . "*TEXT"))))
   (setq ent (ssname sel 0))
     )
   )
 )
 (sssetfirst nil nil)

 (repeat (setq	i (if (setq
		sel (ssget "_X"
			   (list '(0 . "*TEXT")
				 (assoc 8 (entget ent))
			   )
		    )
	      )
	    (sslength sel)
	    0
	  )
	x i
  )
   (setq edxf (entget (ssname sel (setq i (1- i)))))
   (setq pt (cdr (assoc 10 edxf)))
   (cond ((numberp (setq val (read (cdr (assoc 1 edxf)))))
   (entmod (subst (cons 10 (list (car pt) (cadr pt) val))
		  (cons 10 pt)
		  edxf
	   )
   )
   (setq compt (1+ compt))
  )
   )
 )

 (alert (strcat (itoa x)
	 " texte"
	 (if (< 1 x)
	   "s "
	   " "
	 )
	 "sélectionné"
	 (if (< 1 x)
	   "s..."
	   "..."
	 )
	 "\n"
	 (itoa compt)
	 " texte"
	 (if (< 1 compt)
	   "s "
	   " "
	 )
	 "traité"
	 (if (< 1 compt)
	   "s!!!"
	   "!!!"
	 )
 )
 )

 (princ)
)

J’ai modifié la sélection en proposant de sélectionner un texte en référence, puis en filtrant selon tes critères (la fonction supporte maintenant la sélection avant).

En espérant que cela convienne, car pour une autre amélioration je crains qu’il faille attendre 3 semaines après mon retour de vacances, car ma fin de semaine s’annonce chargé.

Pour lili2 ne connaissant pas covadis, en te lisant j’ai eu un doute en pensant que ta commande "cov-edition => Texte => Attribut" avec l'option du dessin d'un point. «Montait» un bloc point sans modifier le z de son attribut, c’est dans cette optique qu’avait été écrit lili2.

A+

Turtle · le 17 octobre 2012

Salut Lili2006,

pourquoi ne pas immatriculer tes points avec Covadis et comme cela tu auras également les attributs Altitudes ?

Olivier Eckmann · le 17 octobre 2012

Bonjour,

en utilisant MAP, on fait une requête sur les textes avec modification de propriétés:

modifier la propriété ELEVATION avec la valeur CHAINE

Olivier

lovecraft · le 17 octobre 2012

Bonjour à tous,

La méthode d'Olivier en Vidéo:

https://docs.google.com/open?id=0B_85Ome3N80dZEstXzJaZHh1MTg

Cordialement,

Laurent

lili2006 · le 17 octobre 2012

Bonjour à toutes et tous,

Tout d'abord merci à tous pour vos pistes,...

Bruno, je teste dés que possible cette nouvelle mouture,...

Turtle,

pourquoi ne pas immatriculer tes points avec Covadis et comme cela tu auras également les attributs Altitudes ?

C'est vraisemblablement cette étape que j'avais zappé,...

Laurent et Olivier,

Ben oui, la plupart des administrations ont MAP, voire civil 3d (même si il ne le savent pas,...!!) donc à tester également.

Je teste et revient alors,...

lili2006 · le 17 octobre 2012

Re,

J'ai testé vite fait ton prog. Bruno, c'est Nickel !

Plus qu'à transformer tout ça en bloc avec attribut,...

Je teste dans l'AM l'immatriculation d'entité,...

speedy · le 17 octobre 2012

Bonjour à toutes et à tous

Le code de Bruno pour mettre les textes en Z fonctionne bien, mais Lilian avec Covadis depuis le Menu Covadis 3d - Construction 3d – immatriculation d'entités, tu peux créer tes blocs tcpoint en une seule sélection de tes points...

@+

Michel

lili2006 · le 17 octobre 2012

Re,

avec Covadis depuis le Menu Covadis 3d - Construction 3d – immatriculation d'entités

Ou encore Cov2D => Points Topo => Immatriculation d'entités

En effet, c'était cette fonction que j'avais oublié,...(Rappel également de turtle que je remercie à nouveau ici.)

Mais j'étais également intéressé par d'autres alternatives éventuelles, je regarde dés que possible la fonction de Map,..

Merci à tous,

Ouf, je viens de retrouver la palette que j'avais faite pour la gestion "propre" de la préparation d'un MNTObjet,...Et il y avait bien cette fonction qui m'avait échappée,..

lovecraft · le 17 octobre 2012

Sympa ta petite palette Lilian ;)

@plus

Laurent

lili2006 · le 17 octobre 2012

Re,

Salut Laurent,

Merki,

Encore à poffiner vraisemblablement,...

(Je reviens sur ce sujet dés que possible)

lovecraft · le 18 octobre 2012

Bonjour,

Comme j'ai entendu parler de Civil3D, vous trouverez ci-dessous le méthode avec celui-ci en vidéo:

https://docs.google.com/open?id=0B_85Ome3N80dZWpINWtiazVMNnc

Cordialement,

Laurent

lili2006 · le 18 octobre 2012

Bonsoir à toutes et tous,

Whaou, cool, merci Laurent,

Je teste dés que possible,...;)

lili2006 · le 20 octobre 2012

Bonjour à toutes et tous,

Pas mal aussi avec MAP,...:)

Je ne peux pas tester sur Civil 3D car la V2013 ne s'installe pas sous vista,..gruuuuuuuuuuu .:angry:

Merci encore à tous,

Connexion

TEXTE ALTITUDE POINT

Messages recommandés

lili2006

didier

VDH-Bruno

VDH-Bruno

lili2006

VDH-Bruno

Turtle

Olivier Eckmann

lovecraft

lili2006

lili2006

speedy

lili2006

lovecraft

lili2006

lovecraft

lili2006

lili2006

Créer un compte ou se connecter pour commenter

Créer un compte

Se connecter

Forums

Naviguer

Activité

Information importante