[Résolu] Del_all_groups ene fonctionne pas avec AutoCAD 2013

[Steven]

Salut à tous.

 

J'ai l'impression que le lisp del_all_groups dont m'avait fait part lecrabe, ne fonctiopnne pas avec AutoCAD 2013.

Il y a un moyen de l'adapter?

[bryce]

Bonjour,

 

Celui-ci a l'air de fonctionner :

 

(defun c:DG (/ *error* acdoc groups ss i gl)
; Décompose les groupes auxquels appartiennent les objets sélectionnés.
; Brice Studer, ocobre 2011

(vl-load-com)
(setq   acdoc (vla-get-activedocument (vlax-get-acad-object))
       groups (vla-get-groups acdoc)
)

(defun *error* (msg)
 (and msg
   (or
     (member (strcase msg) '("FUNCTION CANCELLED" "QUIT / EXIT ABORT" "FONCTION ANNULEE" "QUITTER / SORTIR ABANDON"))
     (princ (strcat "\nErreur : " msg))
   )
 )
 (if ss (setq ss nil))
 (vla-endundomark acdoc)
 (princ)
)

(vla-startundomark acdoc)

(princ "\nSélectionnez les groupes à décomposer <entrée pour tous> : ")
(if (setq ss (ssget))
 (progn
   (setq i 0)
   (repeat (sslength ss)
     (mapcar
       '(lambda (x)
         (and
           (= 330 (car x))
           (= (cdr (assoc 0 (entget (cdr x)))) "GROUP")
           (or
             (member (cdr x) gl)
             (setq gl (cons (cdr x) gl))
           )
         )
       )
       (entget (ssname ss i))
     )
     (setq i (1+ i))
   )
   (foreach g gl
     (entdel g)
   )
 )
 (vlax-for g groups
   (setq gl (cons g gl))
   (vla-delete g)
 )
)

(princ (strcat "\n" (itoa (length gl)) " groupes décomposés !"))
(*error* nil)
(princ)
)

(princ "\nCommande à utiliser : DG")
(princ)

 

;)

 

PS: le code de ton lien fonctionne chez moi...

Modifié le 7 août 2012 par bryce

[Steven]

Ah bah si, del_all_groups fonctionne. Je m'acharnais à taper dell_all_groups avec ou sans s au lieu de del_all_groups. Y a des jours comme ça...

 

Celà dit, ton lisp, encore une fois, est nickel http://www.linuxmint-fr.org/components/com_kunena/template/default/images/emoticons/top.gif

 

Merci ;)

[lecrabe]

Hello Steven

 

C peut etre parce que tu utilises "trop" de PCs DELL ?

ou peut etre un abus de Ricard/Pastis cet ete ?

 

lecrabe

[Steven]

;)