coordonnées négatives

[pointpower]

Bonjour,

 

Je souhaiterais changer les coordonnées de certains de mes blocs juste les passer en positifs. J'essaye désespérement de les sélectionner par la sélection rapide mais ça marche pas, ce que j'aimerais ensuite c'est tout passé en + sans toucher les valeurs avec une formule du genre abs(*varié*) dans x et y.

 

 

Merci de votre aide.

[Tramber]

Salut,

 

J'aimerais t'aider mais... je comprends que dalle :P

Qu'est-ce qui ne marche pas dans ta selection ?

... et ensuite ?

[lecrabe]

Hello

 

No comprendo !

 

lecrabe

[FormaBois]

Rien compris non plus :blink:

[bryce]

Bonjour,

 

Tu ne pourras pas utiliser une formule comme abs dans la palette Propriétés...

 

Je te propose un Lisp qui filtre les blocs ayant une coordonnée X et/ou Y négative, et modifie ces coordonnées d'insertion en positif (c'est que j'ai compris de ta demande):

 

(defun c:ABSBL ( / acdoc filter ss i b code10 )
 (vl-load-com)
 (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object))
   filter '( (0 . "INSERT")(-4 . "<OR")(-4 . "<,*,*")(10 . (0 0 0))(-4 . "*,<,*")(10 . (0 0 0))(-4 . "OR>") ))
 (if (cadr (ssgetfirst))
   (setq ss (ssget "_I" filter))
   (progn
     (prompt "\nSélectionnez les blocs à modifier ou <entrée pour tous> : ")
     (or
       (setq ss (ssget filter))
       (setq ss (ssget "_X" filter))
     )
   )
 )
 (if ss
   (progn
     (vla-startundomark acdoc)
     (setq i 0)
     (repeat (sslength ss)
       (setq b (entget (ssname ss i))
         code10 (cdr (assoc 10 B))
       )
       (setq code10 (mapcar 'abs code10))
       (entmod (subst (cons 10 code10) (assoc 10 B) B))
       (setq i (1+ i))
     );repeat
     (setq ss nil)
     (vla-endundomark acdoc)
   );progn
 )
 (princ)
)

[pointpower]

Re,

 

Oui c'est bien cela Bryce, je te remercie tu es le seul à avoir compris...

 

Mais j'aurais aimé pouvoir le faire sans lisp avec une sélection rapide puis je modifie la propriété en y mettant une formule du style ABS(...)

 

 

Encore merci

 

A+