Points + Z

[RhymOne]

Bonjour à vous tous,

 

Je recherche un lisp qui demande à l'utilisateur de placer un point (bloc:point_topo) demande la valeur en Z du bloc ainsi insérer, l'affecte à l'attributs du bloc Alt et passe au point suivant.

Cela automatisera la mise en place de points topo. (digitalisation)

 

Peut être que cela exista mais la recherche sur ce forum est simplement inutilisable !!!

Alt contient moins de qutrre lettre !!!

 

 

Merci d'avance

[bonuscad]

Bonjour,

 

A affiner si besoin (on ne sait pas si il y a d'autres attributs présent, si le Z d'insertion doit rester à zéro)

 

((lambda ( / pt alti)
 (cond
   ((tblsearch "BLOCK" "point_topo")
     (setvar "cmdecho" 0)
     (setvar "ATTDIA" 0)
     (while (setq pt (getpoint "\nPoint d'insertion: "))
       (initget 1)
       (setq alti (getreal "\nAltitude du point: "))
       (command "_.-insert" "point_topo" pt "" "" "" alti)
     )
     (setvar "ATTDIA" 1)
     (setvar "cmdecho" 1)
   )
   (T
     (princ "\nLe bloc point_topo n'existe pas!")
   )
 )
 (prin1)
))

[RhymOne]

Merci Bonuscad, le point doit rester à 0 le nom du bloc exacte est PointBloc son attribut à changer est ALT.

Apparement l'insertion se passe bien mais la valeur d'attribut ne focntionne pas.

je te joins le fichier avec le point.

 

merci bien

[RhymOne]

J'ai modifier le lisp à ma sauce, il afllait verifier la variable ATTREQ à 0.

[bryce]

Bonjour,

 

Un peu tard, mais voici un autre Lisp :

 

(defun DIGITOPO ( insertion3D / bloc etiquette doc mspace pt attval blocOj )

 (setq bloc "BlocPoint" ; nom du bloc à insérer (doit exister dans le dessin, ou dans un des chemins de recherche d'AutoCAD)
       etiquette "ALT"  ; étiquette de l'attribut Altitude
 )
 
 (vl-load-com)
 
 (if (not (or
           (tblsearch "BLOCK" bloc)
           (setq bloc (findfile (strcat bloc ".dwg")))
          )
     )
   (progn (princ "\nBloc non trouvé !\n") (exit) )
 )
 
   (setq doc (vla-get-ActiveDocument (vlax-get-acad-object))
         mspace (vla-get-ModelSpace doc))
   
   (while (setq pt (getpoint "\nChoix du point : "))
     (setq attval (getreal "\nAltitude : "))
     (if (and insertion3D attval)
       (setq pt (reverse (cons attval (cdr (reverse pt)))) )
     )
     (setq blocObj (vla-InsertBlock mspace (vlax-3d-point pt) bloc 1 1 1 0))
     (if attval
       (mapcar
         '(lambda ( att )
           (if (= etiquette (vla-get-Tagstring att))
             (vla-put-Textstring att (rtos attval))
           )
         )
         (vlax-invoke blocObj 'getAttributes)
       )
     )
   )
   (princ)
)

(defun c:DIGITOPO2D (/)
 (digitopo nil)
)

(defun c:DIGITOPO3D (/)
 (digitopo T)
)

(princ "\nCommandes : DIGITOPO2D ou DIGITOPO3D")
(princ)

[La Lozère]

Salut,

Hors sujet, mais perso quand j'ai une recherche à faire, je ne passe jamais par le moteur de CADxp, mais par google. Et pas de problème pour moins de 4 lettres.

Du type: "cadxp alt point topo"

 

A plus.

[RhymOne]

Oui google recherche c'est mieux, mais on trouve pas souvent le sujet idéale à nos besoins.

Merci Bryce c'est parfait aussi.

 

 

Au plaisir