Cnversion de solide en hachure

[grand_sapin]

Bonjour à tous

 

suite à une réception de plan de ZAC d'un archi qui travaille sous Vectorworks (cousin à solidworks), je me retrouve avec la moitié de mes hachures sous forme de solide (pas hachure solid, l'objet solide)

 

Y a-t-il un moyen de les convertir en hachure facilement et surtout pour un grand nombre (environ 800)

 

D'avance Merci

 

Sapin

[lecrabe]

Hello

 

Les SOLIDs AutoCAD (comme les ELLIPSEs vraies, les SPLINEs) ne sont pas decomposables !

 

Donc j'imagine qu'il te faut un progr en Lisp/VLisp qui construisent des Polylignes closes

sur le contour des entites SOLIDs (a partir d'une selection AutoCAD classique)

puis avec la routine FUSION.lsp de Gilles

tu devrais obtenir la polylligne close du CONTOUR ...

 

Il y a peut etre eu sur ce forum ou ailleurs une routine Lisp/VLisp

pour dessiner ces fameuses polylignes par dessus les SOLIDs !?

 

lecrabe

[lecrabe]

Hello

 

Apres avoir fouille dans mes archives, c ENCORE notre fabuleux Gilles qui "sort"

 

La routine Solid2Pline.lsp de Gilles efface les SOLIDs

mais bon c pas grave et tu peux modifier en consequence la routine !

;; (entdel ent)

Ainsi les SOLIDs ne seront pas effaces !

 

Tu nous tiens au courant ... et comme d'habitude MERCI Gilles !

 

lecrabe

 

;;
;; SOLID2PLINE par GC
;; transforme les solides 2d sélectionnés en polylignes fermées
;;

(vl-load-com)

(defun c:Solid2Pline (/ ss n ent elst elv)
 (princ "\nSélectionnez les solides ou <tous>: ")
 (if
   (setq ss (cond ((ssget '((0 . "SOLID"))))
	   (T (ssget "_X" '((0 . "SOLID"))))
     )
   )
    (while (setq ent (ssname ss
		      (setq n (if n
				(1+ n)
				0
			      )
		      )
	      )
    )
      (setq elst (vl-remove-if
	    '(lambda (x) (member (car x) '(-1 0 5 100 39)))
	    (entget ent)
	  )
     elv  (cadddr (assoc 10 elst))
      )
      (entmake
 (append
   (list
     '(0 . "LWPOLYLINE")
     '(100 . "AcDbEntity")
     '(100 . "AcDbPolyline")
     (assoc 67 elst)
     (assoc 410 elst)
     (assoc 8 elst)
   )
   (if (equal (cdr (assoc 12 elst)) (cdr (assoc 13 elst)) 1e-9)
     (list
       '(90 . 3)
       '(70 . 1)
       (cons 38 elv)
       (assoc 10 elst)
       (cons 10 (cdr (assoc 11 elst)))
       (cons 10 (cdr (assoc 12 elst)))
       (assoc 210 elst)
     )
     (list
       '(90 . 4)
       '(70 . 1)
       (cons 38 elv)
       (assoc 10 elst)
       (cons 10 (cdr (assoc 11 elst)))
       (cons 10 (cdr (assoc 13 elst)))
       (cons 10 (cdr (assoc 12 elst)))
       (assoc 210 elst)
     )
   )
 )
      )
      (entdel ent)
    )
 )
 (princ)
)

[grand_sapin]

super le crabe !

 

et comme tu dis merci gile !

 

j'avais fait une recherche sur Cadxp, mais étant resté sur l'idée de conversion, je n'avais pas étudié la possibilité de création de contours.

 

j'essaye ça tout de suite

 

petite parenthèse, est-ce que quelqu'un connait ce logiciel, Vectorworks, et pourquoi il n'est pas cohérent dans sa transformation en DWG ?

 

Sapin

[lecrabe]

Hello Mr Conifere

 

Alors tu as resolu comment ?

 

SOLID --> PLINE puis FUSION ?

ou autre methode ?

 

lecrabe

[grand_sapin]

Hello,

 

ça marche impecc', et je n'ai pas eu besoin d'utiliser fusion vu que mes solides représentaient bien l'intégralité de ma hachure.

 

Merci encore

 

Sapin