ligne de repéres multiples

[ludo07]

Bonjour à tous.

 

Depuis 2011 ou 2010 il existe les repères de lignes multiple.

 

Je m'y intéresse que depuis quelques semaines et il est vrais que c'est très intéressant.

 

Cependant j'ai un petit soucis.

 

Comment éditer le texte multiligne de plusieurs lignes de repères?

 

En effet je sélectionne un certains nombre de ligne de repère avec le même texte. Puis dans la palette des propriétés à la ligne INDEX le texte apparaît bien. Cependant quand je clic à l'intérieur pour modifier ces lignes sélectionnées, autocad zoom sur chacun des textes multilignes de chaque ligne de repère. Je doit faire ma modification de texte sur ma première puis en suite il zoom et passe sur la deuxième....ainsi de suite.

 

Ne peut on pas comme avec des TEXTES sélectionner et changer directement pour l'ensemble des textes sélectionnés l'index dans la palette des propriétés?

 

Merki

 

A+

[Fruity]

Bonjour

Tu dois mal utiliser la fonction des reperes multiples.

Je viens de tester, et je n'ai qu'un seul texte pour toutes les fleches.

Dans l'ordre:

Tu dessines ta 1ere ligne de repère, et tu tapes le texte qui y est associé.

Puis tu cliques sur "ajouter une ligne de repère". Tu sélectionnes la flèche que tu viens de faire, et tu mets ensuite autant que nouveaux repères que tu le souhaites.

Un seul texte, et plein de flèches. Le tout étant lié.

[ludo07]

Bonsoir

 

Je te remerci de t'interresser a mon souci. Cependant j'ai pas du etre suffisament clair. C'est le grand probleme de ma vie ca.

Mon soucis est:

Apres que tu est fait une ligne repere multiple et peu importe le nombre de départ de fléche que j'ajoute. Tu en fait une deuxieme.

Maintenant selectionne tes 2 lignes de reperères multiples et essai de changer le texte dans la palette des propriete de mettre le meme texte. Moi j'y arrive pas en une fois.

Exemple: tu as 2 details distinct. Tu as mis une ligne de repere multiple indiquant "toto" sur chacun des details. Maintenant je veux remplacer "toto" par "bob". Sans editer l'un apres l'autre mais en même temps.

Moi j'y arrive pas

[CalGory]

Bonjour,

 

Tu fait Edition/Rechercher tu tape le texte rechercher et celui que tu veux mettre à la place puis sur la droite tu as Emplacement de recherche, tu selectionne Objets sélectionnés puis tu selctionnes tes différentes lignes de reperes et tu fais tout remplacer et le tour est jouer

 

En espérant avoir répondu à ce que tu chercher

 

Greg.

[ludo07]

Je vais essayer ta solution.

Et je vous tiens au courrant.

Merki

[ludo07]

Bonjour a tous.

 

Greg031, j'ai essayais ta solution et elle fonctionne.

Cependant elle ne me satisfait qu'a moitié.

En effet car tu passe par une recherche de texte puis un rempacé.

Imaginons que sur les lignes de repères multiple selectionnées tu as des textes différents et que tu veux modifié pour avoir le même texte. Cela ne fonctionne pas.

Je souhaiterais vraiment passer par la palette des propriete.

Mais j'ai pas l'impression que cela soit possible.

A+

[bryce]

Bonjour,

 

Je n'ai pas de solution pour passer par la palette des propriétés, mais voici un lisp qui permet de remplacer le texte de plusieurs lignes de repère multiples :

 

(defun C:MLED ( / acdoc ss ntext ml )
;; Remplace le texte des lignes de repère multiples sélectionnées.
;; Bryce, janvier 2012
 (vl-load-com)
 (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)) )
 (if (setq ss (ssget '((0 . "MULTILEADER") (296 . 0)) ) )
   (progn
     (setq ss (vla-get-ActiveSelectionSet acdoc))
     (setq ntext (getstring T "\nNouveau texte : "))
     (vlax-for ml ss
       (if (= 2 (vla-get-ContentType ml))
         (vla-put-TextString ml ntext)
       )
     ); vlax-for
     (vla-delete ss)
     (setq ss nil)
   ); progn
 ); if ss
 (princ)
)

(defun C:MMLED ( / *error* oldcmdecho acdoc ss e ntext ml )
;; Remplace le texte des lignes de repère multiples sélectionnées,
;; affiche l'éditeur de texte pour entrer le nouveau texte.
;; Bryce, janvier 2012
 (vl-load-com)
 
 (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)) )
 
 (defun *error* (msg)
   (and msg
     (or
       (member (strcase msg) '("FUNCTION CANCELLED" "QUIT / EXIT ABORT" "FONCTION ANNULEE" "QUITTER / SORTIR ABANDON"))
       (princ (strcat "\nErreur : " msg))
     )
   )
   (if ss (progn (vla-delete ss)(setq ss nil)))
   (setvar 'cmdecho oldcmdecho)
   (vla-endundomark acdoc)
   (princ)
 )
 
 (vla-startundomark acdoc)
 (setq oldcmdecho (getvar 'cmdecho))
 (setvar 'cmdecho 0)
 
 (if (setq ss (ssget '((0 . "MULTILEADER") (296 . 0)) ) )
   (progn
     (setq ss (vla-get-ActiveSelectionSet acdoc))
     (setq e (entlast))
     (prompt "\nNouveau texte :\n")
     (initdia)
     (command "_.mtext" (getvar 'viewctr) "_w" "0" )
     (while (= 1 (getvar 'cmdactive))
       (command pause)
     )
     (if (eq (entlast) e)
       (*error* nil)
       (progn
         (setq e (entlast)
           ntext (vla-get-TextString (vlax-ename->vla-object e))
         )
         (entdel e)
         (vlax-for ml ss
           (if (= 2 (vla-get-ContentType ml))
             (vla-put-TextString ml ntext)
           )
         ); vlax-for
       )
     )
   ); progn
 ); if ss
 (*error* nil)
)

(princ "\nCommande à utiliser: MLED, ou MMLED pour afficher l'édteur de texte")
(princ)

 

Commande MLED pour entrer le nouveau texte en ligne de commande, ou MMLED pour utiliser l'éditeur de texte.

[ludo07]

Bonjour bryce.

Vivement lundi que j'aissais ton lisp.

Merci.

A+

[ludo07]

Bonjour a tous.

Bryce, quand je copie colle le code dans autolisp. Le code se met tout sur une seule ligne????

Je pense que ce n'est pas normale. Tout est en gris.

Tu peux verifier?

Merki

[bryce]

Bonjour,

 

Colle le code dans un nouveau fichier texte, je te suggère de lire ce sujet:

http://cadxp.com/index.php?/topic/14323-charger-un-lisp/

 

Tu peux aussi télécharger directement le fichier lsp depuis ce lien (clic droit > enregistrer sous):

http://www.creao.fr/uploads/lisp/mled.lsp

[VDH-Bruno]

Bonsoir,

 

Bryce, quand je copie colle le code dans autolisp. Le code se met tout sur une seule ligne????

Je pense que ce n'est pas normale. Tout est en gris.

Cela arrive avec certaines configurations (vista en ce qui me concerne), comme tout le code se colle sur une seul ligne toutes les expressions suivant un commentaire sont grisées.. Ma parade je ne fais plus de copier coller en directe, je copie-colle sous un traitement de texte puis je copie-colle dans Visual Lisp.

 

A+

[ludo07]

Ok

 

Demain je suivrais vos conseil.

Merci

A+

[ludo07]

Ca y est je viens de tester.

Et je dis MERKI bryce.

C'est exactement ce que je voulais.

A+