variables modifié par covadis

[dilack]

bonjour a tous,

je cherche à savoir quelle sont les variables modifiées par covadis.

j'ai des lips qui foire sur une version AutoCAD+covadis alors que sur une version sans covadis ces mm lisp fonctionne correctement.

 

Merci d'avance pour vos réponses.

[didier]

coucou

 

à part créer des objets spécifiques (mnt objet par exemple)

Covadis - en tant que tel - ne change pas de variables

 

peut-être que dans une commande ils en changent mais ça reste de l'AutoCAD

ne mélangeons pas ...

 

tu as un exemple de ce qui merdouille ?

 

amicalement

[Calecx]

Salut,

 

Peut-être que le nom de ton lisp est le même que le raccourcis d'une commande Covadis?

[dilack]

salut

ci joint les lignes de commande quand j'ouvre directement autocad

 

Fichier de personnalisation chargé avec succès. Groupe de personnalisation: ACAD
Fichier de personnalisation chargé avec succès. Groupe de personnalisation: 
CUSTOM
Fichier de personnalisation chargé avec succès. Groupe de personnalisation: 
EXPRESS
Fichier de personnalisation chargé avec succès. Groupe de personnalisation: 
COVADIS
Régénération du modèle.
COVADIS v9.1g : chargement du module d'activation en cours ...
... terminé. Copyright (C) 1993-2007 Géomédia S.A.
COVADIS v9.1g : chargement de l'applicatif en cours ...
... terminé. Copyright (C) 1993-2007 Géomédia S.A.
COVADIS v9.1g : chargement du module "Services Configuration" ...
... terminé. Copyright (C) 1993-2007 Géomédia S.A.
COVADIS v9.1g : chargement du module "Services Echelles" ...
... terminé. Copyright (C) 1993-2007 Géomédia S.A.
COVADIS v9.1g : chargement du module "Liste des Points" ...
... terminé. Copyright (C) 1993-2007 Géomédia S.A.
Initialisation de l'environnement COVADIS ...
... terminé : 5 variables mises à jour.
AutoCAD Express Tools Copyright © 2002-2004 Autodesk, Inc.
Utilitaires de menu AutoCAD chargés.
Chargement des utilitaires de menu de COVADIS ...
... terminé.
Commande: LIGNECOMMANDE
Commande: properties

 

 

et ci joint un des lips qui merdouille sous covadis alors que sur une version de base je n'ai pas de prob

 

(defun c:pmp(/ Cmd Co Coo Compt ep Lg os Pt1 Pt2 Pts Pas s)

(defun *errmp* (msg)
(if (/= msg "Function cancelled")
(if (= msg "quit / exit abort")
(princ)
(princ (strcat "\nErreur : " msg))
)
(princ)
)
(if os
(setvar "osmode" os)
)
(setvar "cecolor" coo)
(command "_.undo" "_end")
(setvar "cmdecho" Cmd)
(setq *error* s)
(princ)
)

(defun cg_co()
(setvar "cecolor" (itoa Co))
(if (= Co 1)
(setq Co 7)
(setq Co 1)
)
)

(setq s *error*)
(setq *error* *errmp*)
(setq Cmd (getvar "cmdecho") Coo (getvar "cecolor"))
(setvar "cmdecho" 0)
(setq Ep (getstring (strcat "\nEpaisseur des polylignes <" (rtos (getvar "plinewid")) "> : ")))
(if Ep
(setvar "plinewid" (atof Ep))
)
(setq Pt1 (getpoint "\nPremier point : ") Pt2 '(0.0 0.0 0.0) Co 7 Compt 0)
(if Pt1
(progn
(setq Pts (list (cons 0 Pt1)))
(while Pt2
(initget "Undo")
(setq Pt2 (getpoint Pt1 "\nPoint suivant / Undo : "))
(if Pt2
(progn
(if (= Pt2 "Undo")
(progn
(if (/= Compt 0)
(progn
(command "_.undo" "1")
(setq Pts (vl-remove (assoc Compt Pts) Pts) Compt (1- Compt) Pt1 (cdr (assoc Compt Pts)))
)
(princ "\nRien à annuler")
)
)
(progn
(command "_.undo" "_group")
(setq os (getvar "osmode"))
(setvar "osmode" 0)
(setq Pas 0 Lg (* (getvar "ltscale") 1))
(while (< Pas (- (distance Pt1 Pt2) Lg))
(cg_co)
(command "_.pline" (if (= Pas 0)
Pt1
"@"
)
(strcat "@" (rtos Lg) "<" (angtos (angle Pt1 Pt2) 0 16))
"")
(setq Pas (+ Pas Lg))
)
(cg_co)
(command "_.pline" "@" Pt2 "")
(setvar "osmode" os)
(setvar "cecolor" coo)
(command "_.undo" "_end")
(setq Pt1 Pt2 Compt (1+ Compt) Pts (append Pts (list (cons Compt Pt2))))
)
)
)
)
)
)
)
(setvar "cmdecho" Cmd)
(setq *error* s)
(princ)
)

 

merci d'avance pour vos explications.

[didier]

coucou

 

à première vue je ne vois rien dans lequel Covadis interviendrait !

toutefois, renomme tes variables et tes commandes et relance ...

 

amicalement

[Olivier Eckmann]

Bonjour,

 

les 5 variables mises à jour correspondent par défaut à l'initialisation de l'environnement de type Géomètre, c'est à dire angles en grade, sens horaire, 0 au Nord

 

Le lisp crée des sommets de polyligne par des commandes du genre @10<50

 

Sur un poste AutoCAD sans Covadis, si le dessin est en degré, sens horaire et 0 à l'est, ces coordonnées relatives vont forcément données n'importe quoi lorsque l'on a un Covadis en grade...

 

On peut toujours décocher "Initialiser l'environnement Géomètre" pour ne pas modifier ces variables, par contre pour éviter ce genre de problème d'une manière générale en programmation, on évite de passer par la ligne de commande et on construit directement les entités avec les fonctions prévues pour (entmake) (polar)...

Dans ce cas AutoCAD travaille toujours en radians, 0 à l'est et sens trigo.

Sinon, si on veut absolument passer en ligne de commande par l'interface, les valeurs saisies étant sensible à l'environnement, il faut stocker les différentes variables ANGDIR, ANGBASE..., puis imposer les valeurs pour lesquelles le programme fonctionne puis restaurer les variables initiales comme c'est fait pour les variables OSMODE, CMDECHO et CECOLOR

 

Olivier Eckmann