Routine Cartouche

[CadFrank]

Bonjour,

 

 

Ceci est la première fois que j'écris sur se forum.

 

J'aimerais savoir si il y a une façon de faire en sorte que quand je fais un nouveau layout appartir d'un déja créé

que les pages de ma cartouche change en suite.

 

en lien j'ai mis ma cartouche.

 

Salutations!

[Patrick_35]

Bonjour,

 

 

Ceci est la première fois que j'écris sur se forum.

 

J'aimerais savoir si il y a une façon de faire en sorte que quand je fais un nouveau layout appartir d'un déja créé

que les pages de ma cartouche change en suite.

 

en lien j'ai mis ma cartouche.

 

Salutations!

Salut

 

Tu peux utiliser les champs avec les variables d'autocad comme CTAB

 

ps : ton lien est invisible ;)

 

@+

[CadFrank]

j'ai essayé de le mettre mais sa na pas fonctionné

 

il faudrais que tu puisse voir mon cartouche. mais j'ai essayer de mettre de champs et la seule chose qui apparais c'est ####

[CadFrank]

ah ben il me dise que je ne peu pas envoyer se types de fichier :unsure:

 

donc je l'ai zipper!!!

 

mouahaha que je suis perspicase

[lili2006]

Bonsoir à toutes et tous,

 

En ce qui concerne le champ "DATE", tu as du oublier de faire un "REGEN", car cela fonctionne chez moi

 

 

Et pour ce que te proposait Patrick_35 (que je salut au passage,...;)), en image =>

 

Modifié le 23 décembre 2011 par lili2006

[CadFrank]

Re bonjour,

 

C'est plus les page que j'aimerais qui soit incrementer 1 de 1 passe a 1 de 2 quand on rajoute une layout.

 

ainsi de suite si je faire un nouveau layout la premiere page est 1 de 3 la deuxième devient 2 de 3 et la derniere 3 de 3

[lili2006]

Re,

 

Ouh là, ça se complique,...

 

Perso, je ne sais pas faire, désolé,...

 

Ou alors avec les propriétés personnalisés mais ce sera à toi de remplir "manuellement" le champ,...

 

Modifié le 23 décembre 2011 par lili2006

[CadFrank]

c'est cela que je chercher a faire mais je sais pas comment.

[lili2006]

Re,

 

Je viens d'éditer mon message précédent.

 

Les propriétés persos ne te conviennent pas ?

[CadFrank]

Je ne sais pas comment les utiliser je cherche a faire un lisp pour avec le décompte de chaque layout dans mon dessins mais vu que je suis assez nous je ne sais pas comment.

[CadFrank]

sait bizarre mais je ne vois pas tes images

[CadFrank]

j'ai trouver se code mais je ne reussi pas a le faire fonctionné

 

 

(defun c:lpc()

(setq sheet 1)
(setq total (itoa (length (layoutlist))))

(foreach layout (layoutlist))

(print)

(ssget "_X" (list (cons 0 "INSERT") (cons 66 1) (cons 2 "Cartouche Aliance") (cons 410 layout)))

;sa me dit qu'il y a une erreur avec le ssget.


(strcat (itoa sheet) " of " total)

(setq sheet (1+ sheet))

)

[Patrick_35]

Tu peux numéroter tes onglets avec RON par exemple et indiquer dans le cartouche avec un champ avec la variable CTAB

 

ps : Toutes mes amitiés lili :D

 

Et bonnes fêtes à tous

 

@+

[lili2006]

Re,

 

Patrick, je vois que tu lis entièrement les messages,...:)

 

Je te retourne mes amitiés,.

 

Et en plus, tu as résolu le pb de CadFrank,..:P

 

sait bizarre mais je ne vois pas tes images

 

Je passe par la DROPBOX, j'ai l'impression que je dois être connecté pour avoir accès (a vérifier cependant,..)

Modifié le 23 décembre 2011 par lili2006

[azer]

bonjour

ce n'est pas le sujet mais propriétés du dessin surtout si il y a beaucoup de présentation

fichier propriété du dessin;personnalise

dans tes cartouche tu crée un champ catégorie du champ document.

si ça peut te permettre de gagner du temps avec tes cartouches

[CadFrank]

Quand je lance la routine Ron sa me retourne

 

 

RON ; error: no function definition: VLAX-GET-ACAD-OBJECT

[lili2006]

Re,

 

Rajoutes alors cette instruction : (vl-load-com) en tête de lisp

[CadFrank]

C'est parfait! ça fonctionne maintenant.

 

Quoi que en bout de ligne a ne fait pas se que je veux ds ma cartouche. p-e si je démontre le résultat sa peut aider.

 

 

 

voici l'effet que je veux que sa represente.

 

Merci pour tout l'aide si quelqu'un trouve la reponse alors sa sera mon cadeau de nowel :(rires forts): :(rires forts):

 

Joyeux Nowel a tous!!

[CadFrank]

(setq total (itoa (length (layoutlist))))

 

Avec ceci je suis capable d'avoir le nombre de layout...

 

y a t il une face d'utiliser ceci pour faire une modification de mon attribut

[CadFrank]

Bon J'ai un nouveau code et il fonction en parti comme je le veux.

 

Il manque qu'une chose. je peux changer les pages selon le nombre de layout. Ceci fonctionne parfaitement.

 

il ne reste qu'une chose que je ne suis pas capable de faire afficher et c'est le total de layout.

 

J'ai marque se que je pensais qui pourrais le faire fonctionner apres les points virgule de la fonction qui va suivre sous peu.

 

(defun C:paging(/ adoc atts id lay_field)
(setq adoc (vla-get-activedocument (vlax-get-acad-object)))
 (vlax-for lt (vla-get-layouts adoc)
   (vla-put-activelayout adoc lt);optional
   (vlax-for obj (vla-get-block lt)
     (if (eq "AcDbBlockReference" (vla-get-objectname obj))
(if (eq "Cartouche Aliance" (vla-get-effectivename obj))
       (if (eq :vlax-true (vla-get-hasattributes obj) )
       (progn
  (setq atts (vlax-invoke obj 'getattributes))
  (foreach x atts
    (if (eq "PAGE" (vla-get-tagstring x))
      (progn
        (setq id (vla-get-objectid (vla-get-layout (vla-objectidtoobject adoc (vla-get-ownerid obj)))))
        (setq lay_field (strcat "%<\\AcObjProp Object(%<\\_ObjId " (itoa id)">%).Taborder \\f \"%tc1\">%"))
      (vla-put-textstring x lay_field)
      )
    )

;     (if (eq "#PAGE" (vla-get-tagstring x))
;       (progn
;         (setq id (itoa (length (layoutlist))))
;       (vla-put-textstring x lay_field)
;       )
;     )

  )
       )
    )
  )
)
     )
   )
 (vla-put-activelayout adoc (vla-item (vla-get-layouts adoc) 0));activate Layout1, optional
(princ)
 )
 (prompt "\Try command: Paging...")
 (prin1)
 (vl-load-com)
 (prin1)

 

Par contre, le texte de ma réponse ne s'affiche pas..

 

aurait-il quelqu'un qui aurait la solution.

 

Se serait grandement apprécié.

 

Merci d'avance.

[bryce]

Bonsoir,

 

Vite fait...

 

(defun C:PAGING( / nombloc attpage attnumpage adoc numtabs atts id lay_field)

; Paramètres

(setq nombloc "Cartouche Aliance")  ; nom du bloc cartouche
(setq attpage "PAGE")               ; étiquette de l'attribut numéro de page
(setq attnumpage "#PAGE")           ; ; étiquette de l'attribut nombre de pages

; Fin paramètres

 (vl-load-com)
 (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
 (setq numtabs (itoa (length (layoutlist))))
 (vlax-for lt (vla-get-layouts adoc)
   ;(vla-put-activelayout adoc lt) ; optionnel
   (vlax-for obj (vla-get-block lt)
     (if (and (= "AcDbBlockReference" (vla-get-objectname obj))
             (= nombloc (vla-get-effectivename obj)) 
             (= :vlax-true (vla-get-hasattributes obj) ))
       (progn
         (setq atts (vlax-invoke obj 'getattributes))
         (foreach x atts
           (if (= attpage (vla-get-tagstring x))
             (progn
               (setq id (vla-get-objectid (vla-get-layout (vla-objectidtoobject adoc (vla-get-ownerid obj)))))
               (setq lay_field (strcat "%<\\AcObjProp Object(%<\\_ObjId " (itoa id)">%).Taborder \\f \"%tc1\">%"))
               (vla-put-textstring x lay_field)
             )
           )
           (if (= attnumpage (vla-get-tagstring x))
               (vla-put-textstring x numtabs)
           )
         )
       )
     )
   )
 )
 ;(vla-put-activelayout adoc (vla-item (vla-get-layouts adoc) 0)) ; activer Layout1, optionnel
 (princ)
)
(prompt "\nCommande à utiliser : PAGING")
(princ)

[CadFrank]

bryce Posté Hier, 05:09

Bonsoir,

 

Vite fait...

 

Je te remerci de ton aide c'est exactement ce que je cherchai a faire..

 

Aurai tu une idée ou je pourrais trouver tout les descriptions avec démonstration des fonctions Lisp/Vlisp en francais car je ne les trouve qu'en anglais je les trouves pas trop facile a comprend meme si je suis bilingue

 

Salutation et encore merci !

[Patrick_35]

Aurai tu une idée ou je pourrais trouver tout les descriptions avec démonstration des fonctions Lisp/Vlisp en francais car je ne les trouve qu'en anglais je les trouves pas trop facile a comprend meme si je suis bilingue

Salut

 

J'avais indiqué ici ou là une marche à suivre avec l'aide

 

@+

[CadFrank]

Euh ... Je sais pas trop... mais je comprend pas le ici et la ne m'apporte pas au fonction et je trouve pas plus ou les trouver

 

Je sais pas si j'ai bien d'écrit se que je veux.

 

Je veux trouver les information pour les fonction

 

vla-get-acaddocuments / vla-for etc ...

[Patrick_35]

Euh ... Je sais pas trop... mais je comprend pas le ici et la ne m'apporte pas au fonction et je trouve pas plus ou les trouver

 

Je sais pas si j'ai bien d'écrit se que je veux.

 

Je veux trouver les information pour les fonction

 

vla-get-acaddocuments / vla-for etc ...

C'est dans l'aide pour les fonctions vl-*, vlr-*, vlax-*

Pour les fonctions vla-*, c'est dans l'aide vba, et pour retrouver les fonctions, avec l'explorateur (F2) dans l'éditeur vba (comme expliqué dans les liens cités)

 

@+