[Résolu] Développé de cercle

[Titi95]

Bonjour à tous

 

J’ai mon chef d’atelier qui me demande un développé des diamètresstandards des tuyauteries en acier pour faire les tracés avant découpe dans lestuyauteries.( pour un piquage plus petit sur une tuyauterie)

 

Plus couramment appelé « gueule de loup » En grosca ressemble à une ellipse.

 

Je crois savoir qu’Inventor le fait mais je ne l’ai pas.

 

Ou si qq sait comment on fait avec Autocad ? (si c’estpossible)

 

Ou sinon une ame charitable qui pourrait m’envoyer unfichier sous Autocad avec les développés des diamètres :

 

Ø76.1 DN65

Ø 88.9 DN80

Ø114.3 DN100

Ø139.7 DN125

Ø168.3 DN150

Ø219.1 DN200

 

merci d’avance ;)

[Titifonky]

Bonjour,

 

Il n'existe pas de développé standard pour chaque diamètre de tube, le développé dépend du diamètre du diamètre des deux tubes et de l'angle entre les deux tubes.

 

Par contre il existe des méthodes de traçage pour obtenir les développés en fonction de tout ces paramètres.

[thry0]

Bjr à tous,

 

Comme le dit Titifonky, les piquages sont directement

liés aux différents diamètres concernés et leur position respective.

Voir exemple ci joint ...

Essai.bmp

[Titi95]

oui effectivement, j'avais pas pensé à ça j'ai réflechi que sur un tube

 

par contre c'est des piquages a 90° donc ca réduit deja les possibilités

 

j'ai 6 diamètres de tube ce qui me donne une combinaison de 16 possibilités (à 90° toujours)

 

 

Titifoncky, je veux bien connaitre une technique pour les obtenir

[Titi95]

voici en image les piquage concernés

 

 

 

si une personne qui maîtrise Inventore passe par là... je peu envoyer mon fichier

[Titifonky]

Bonjour,

 

Voici l'adresse d'un site où tu trouvera les principales intersections et leurs développés ici

[DaWeeD_Gab]

bonjour,

 

Je ne bosse pas du tout sur ce genre de truc mais une idée me vient :

si tu fais tes tuyaux en 3D, tu les positionnes puis tu fais une intersection (barre d'outil "modélisation" ), tu n'obtiens pas ton résultat ?

[Calecx]

Avant j'avais un bouquin "technique et pratique du TRACAGE des METAUX en FEUILLES" de A. LETALNET, tout y est expliqué, si tu arrive à te le procurer (il semble épuisé partout).

 

Sinon, il y a Google ;) avec un tuto sur autocad ici avec un fichier dwg à télécharger.

[thry0]

Re,

 

Ci joint fichier du résultat désiré au final.

A confirmer.

Obtenu à l'aide d'un lisp trouvé sur le Net,

et dont je remercie l'auteur à cette occasion.

Gueule de loup.zip

[Titi95]

bonjour,

 

Je ne bosse pas du tout sur ce genre de truc mais une idée me vient :

si tu fais tes tuyaux en 3D, tu les positionnes puis tu fais une intersection (barre d'outil "modélisation" ), tu n'obtiens pas ton résultat ?

 

non tu as une chipse

 

 

 

ce que je voudrais c'est la mettre à plat, pour le tracer sur papier pour faire un "patron" pour la découpe sur un tuyau

[Titi95]

Titifonky, je vais regarder ton lien en détail

 

Calecx, ton lien avec le fichier est pas mal, je me demande comment il parvient au développé car il ne l’explique pas

 

Thry0, on dirait une simple vue de dessus, mais je me tropepeu être du faite qu’il est a 45°, sinon c’est quoi le nom du lisp?

[thry0]

Re,

 

La courbe bleue (Développé "à plat" de la découpe)

est le gabarit à appliquer sur ton tube pour la découpe.

A tracer à l'échelle 1 bien sur !

Pour vérification, sa longueur doit correspondre à PIxD,

périmètre du tube (!)

Un chaudronnier saura faire ...

 

Le temps de remettre la main sur le lisp et je fais suivre.

[thry0]

Bjr à tous,

 

Chose promise chose dûe, voici le lisp en question.

En anglais, mais il suffit de renseigner

le petit diamètre du tube, le grand diamètre de l'autre tube

puis l'angle d'intersection entre les deux.

Les 2 axes des tubes doivent être concourants

pas de décalage possible.

Pour ceux qui en ont l'utilité ou pour la curiosité ...

A lancer aver la Cde "PIUP" après chargement.

 

;;  PipeIntersUnroll.lsp [command name: PIUP]
;;  To draw the profile of the unrolled end of a pipe or tube that intersects an equal-
;;    or larger-diameter pipe at any non-parallel angle, and of the hole in the unrolled
;;    larger pipe.
;;  Draws line-segment Polyline approximation of profiles; user specifies precision
;;    [number of segments].
;;  Angle of incidence: 0 = parallel [not allowed], 90 degrees = perpendicular.
;;  Center-lines or their extensions must intersect [no eccentric intersections].
;;  Draws unrolled profiles as if larger-diameter pipe is vertical, and smaller-diameter
;;    pipe is coming into it, for incident angles of less than 90 degrees, from above.
;;    Surface of unrolled smaller-diameter pipe always extends upward from drawn end
;;    profile; midpoint of that profile always represents bottom of hole in larger-diameter
;;    pipe, and side of smaller pipe "slit" for unrolling is always on top.  [At incident angles
;;    > 90 degrees, this means smaller-diameter pipe surface will seem upside-down.]
;;  Places a Point entity at reference point, representing intersection of pipe center-lines,
;;    and draws unrolled profiles at distances from reference point relative to each pipe's
;;    axial direction.
;;  Kent Cooper, August 2011

(defun C:PIUP ; = Pipe Intersection Unrolled Profiles
 (/ *error* dias diab Ai seg ref Rs Rb inca As Xs Xb)
 (defun *error* (errmsg)
   (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
     (princ (strcat "\nError: " errmsg))
   ); end if
   (command)
   (setvar 'osmode osm)
   (setvar 'blipmode blipm)
   (command "_.undo" "_end")
   (setvar 'cmdecho cmde)
   (princ)
 ); end defun - *error*
 (setq cmde (getvar 'cmdecho))
 (setvar 'cmdecho 0)
 (command "_.undo" "_begin")
 (setq
   osm (getvar 'osmode)
   blipm (getvar 'blipmode)
 ); end setq
 (setq dias (getdist "\nSmaller Pipe diameter [O.D.]: "))
 (while
   (not
     (and
       (setq diab (getdist "\nLarger Pipe diameter [O.D.]: "))
       (>= diab dias)
     ); and
   ); not
   (prompt "\nMay not be smaller diameter than first pipe.")
 ); while
 (while
   (not
     (and
       (setq Ai (getangle "\nAngle of incidence between pipes: "))
       (not (or (equal Ai 0 1e-8) (equal Ai pi 1e-8)))
     ); and
   ); not
   (prompt "\nPipes may not be parallel.")
 ); while
 (setq
   seg (getint "\nNumber of Polyline segments: ")
   ref (getpoint "\nReference point: ")
     ;; represents intersection of pipe centerlines
   Rs (/ dias 2); Radius of Smaller pipe
   Rb (/ diab 2); Radius of Bigger pipe
   inca (/ pi 0.5 seg); angle per segment around smaller pipe
   i -1
 )
 (setvar 'osmode 0)
 (setvar 'blipmode 0)
 (setvar 'plinewid 0)
;;  Smaller-diameter pipe unrolled end profile:
 (command "_.point" ref "_.pline")
 (while (< i seg)
   (setq
     As (+ (* (setq i (1+ i)) inca) pi)
     Xs (* Rs (cos As))
     Xb (sqrt (- (expt Rb 2) (expt (* Rs (sin As)) 2)))
   ); setq
   (command; feed point out to Polyline
     (list
       (+ (car ref) (* (/ (* dias pi) seg) (- i (/ seg 2.0))))
       (+
         (cadr ref)
         (- (/ Xb (sin Ai)) (* Xs (/ (cos Ai) (sin Ai))))
       ); -
     ); list
   ); end command
 ); end while
 (command "")
;;  Larger-diameter pipe unrolled hole profile:
 (setq i -1)
 (command "_.pline")
 (while (< i (1- seg))
   (setq
     As (* (setq i (1+ i)) inca)
     Xs (* Rs (cos As))
     Ys (* Rs (sin As))
     Xb (sqrt (- (expt Rb 2) (expt Ys 2)))
   ); setq
   (command; feed point out to Polyline
     (list
       (+ ; X component
         (car ref)
         (if (zerop Xb); at 90 or 270 degrees, only with equal diameters
           (* Rb (sin As) (/ pi 2)) ; then - prevents divide-by-0 error
           (* Rb (atan (/ Ys Xb))); else - all other angles
         ); if
       ); +
       (+ ; Y component
         (cadr ref)
         (- (/ (* Xb (cos Ai)) (sin Ai)) (/ Xs (sin Ai))); else - all other angles
       ); +
     ); list
   ); command
 ); while
 (command "_close")
 (setvar 'osmode osm)
 (setvar 'blipmode blipm)
 (command "_.undo" "_end")
 (setvar 'cmdecho cmde)
 (princ)
); defun

[nicolas2]

Bonjour Titi.

Si tu n'as que 5 ou 6 cas, je te propose de faire tes dévelopés avec LOGITRACE.

Il me faut le Ø et l'épaisseur de tes tubes (intersection à 90°).

[Titi95]

Bonjour à tous

 

thry0àje te remercie pour le lisp, j’ai réussi à m’en servir et avoir un résultat, je vais juste prendre le temps de voir à interpréter le résultat au mieux.

 

Nicolas2 à merci de ta proposition, je voie si la réponse dethry0 me suffi.

[nicolas2]

Juste un essai entre le LISP et LOGITRACE.

- Cas 1: un tube de Ø60.3 sur un tube de Ø168.3 à 90° => OK

- Cas 2: la même chose mais avec un angle de 30°:

Tracé noir, le LISP - Tracé Rouge, LOGITRACE

http://img27.imageshack.us/img27/7994/dvelopp.jpg

OK pour la pièce femelle, mais pas pour la pièce mâle.

J'ai découpé et assemblé (papier) dans les 2 cas, cela confirme un problème au niveau du LISP

 

Ce LISP, dans le cas 1, ne fonctionne que si on utilise un gabarit papier à poser sur les 2 pièces (pas de prise en compte de l'épaisseur).

En tout cas, super boulot, bravo !

[Titi95]

thry0 --> j'ai enfin compris la lecture (des fois j'ai honte)

 

J'ai fais un test, imprimé et donné ça à mon tuyauteur, il est comblé !

 

Merci thry et au autres pour vos réponses

 

(je marque le sujet Résolu)