Cercle continu

[jalna]

Bonjour,

 

Je recherche le lisp de (gile) je crois qui me permet de faire des cercles en continus depuis le même point de base (tiens cela serait bien qu'il soit incorporé dans AutoCAD)

 

Merci

[didier]

Coucou

 

je te copie un truc assez ancien..

en espérant qu'en me haussant sur la pointe des pieds

j'arrive à la cheville de (Gile)

(defun c:cm ( / centre rayon)
(command "cmdecho" "0")  
(setq centre (getpoint"\nPointez le centre du cercle multiple\n"))
(while
(setq rayon(getreal"\nValeur du rayon ?"))
(command "_CIRCLE" centre rayon)
);while
);defun

Amicalement

[VDH-Bruno]

Salut jalna,

 

Pour faire plus "beau" remplace:

(setq rayon(getreal"\nValeur du rayon ?"))

 

par

(setq rayon (getdist centre "\nValeur du rayon ?"))

 

A+

[Tramber]

Et moi j'édite par une poignée extérieure un cercle existant en tapant C pour "Copier", histoire de ne monter aucun programme. Signe de ma paresse extrême !

[jalna]

Ok

Super merci pour tout

[jalna]

Et merci à VDH et Tramber

[didier]

Coucou

 

Signe de ma paresse extrême

si un jour on doit faire un match nous serons en finale...

 

pourtant cette routine a une utilité

lors de la demande de cercles multiples vraiment nombreux,

tu ne regardes plus l'écran, tu lis ton croquis et tu tapes les valeurs.

 

j'avais fait ça dans le temps où on chainait les cotes en cumulées

avec un seul point de départ et des dizaines de valeurs

 

amicalement

[VDH-Bruno]

Et moi j'édite par une poignée extérieure un cercle existant en tapant C pour "Copier", histoire de ne monter aucun programme. Signe de ma paresse extrême !

 

Clap clap clap je l’avais oublié celle-là merci Tramber de me rafraichir la mémoire, sinon pour me faire la main et comme je l’ai fait. Ci-joint les versions du code de didier avec command décliné:

 

A la sauce entmake

(defun c:cm (/ centre rayon)
 (if (setq centre (getpoint "\nPointez le centre du cercle multiple\n"))
   (while (setq rayon (getdist centre "\nValeur du rayon ?"))
     (entmake
(list '(0 . "CIRCLE") (cons 10 centre) (cons 40 rayon))
     )
   )
 )
 (princ)
)

 

Et à la sauce ActiveX

(defun c:cm (/ centre rayon mspace)
 (if (setq mspace (vla-get-modelspace
	     (vla-get-activedocument (vlax-get-acad-object))
	   )
    centre (getpoint "\nPointez le centre du cercle multiple\n")
     )
   (while (setq rayon (getdist centre "\nValeur du rayon ?"))
     (vla-addCircle mspace (vlax-3d-point centre) rayon)
   )
 )
 (princ)
)

 

A+ Bruno

(Ps : Bien souvent la paresse oblige à être astucieux, donc ce n’est pas toujours un vilain défault..)

[Tramber]

Merci merci :(rires forts):

 

Didier a raison, ca marche pas quand l'objet initial n'est plus à l'écran. J'aurais toujours voulu une variable pour cela... car j'ai toujours pensé que cette limitation était volontaire de la part d'Autodesk.

[VDH-Bruno]

Salut jalna

 

Je recherche le lisp de (gile) je crois qui me permet de faire des cercles en continus depuis le même point de base

 

Bon tout à fait par hasard j’ai retrouvé le sujet auquel tu faisais allusion cercle multiple avec même centre...

 

Il y a la version de (gile) (à ses débuts je pense..), Patrick-35 (astucieuse et simple), et une solution Diesel (pour les LTsiens) de rebcao..

 

Voilà je pense que le sujet est complet :D :D :D

 

A+ Bruno

[VDH-Bruno]

Re,

 

Pour être vraiment complet sur le sujet, peut-être la version la plus concise et la plus élégante.. (avec absence de message d’erreur)

 

((lambda (cen) (while (vl-cmdf "_.circle" cen pause)) (princ)) (getpoint "\nCentre du cercle: "))

 

(Ps : Merci à Patrick_35 qui m’a inspiré avec son command pause)

 

A+ Bruno