polyligne en Spline

[fauxsuisse]

Bonjour tout le monde.

 

Existe t'il un lisp qui permettrait de sélectionner tout une série de polyligne et de les transformer directement en spline, actuellement je dois sélectionner les polyligne une par une pour les transformer en spline puis prendre la fonction spline avec la fonction objet pour les resélectionner et de les transformer en vrai spline. :P

[bryce]

Bonjour,

 

Je te propose ceci :

 

(defun c:pl2spl(/ acdoc *error* oldcmdecho ss pl i)
; Convertit les polylignes sélectionnées en splines
; Brice Studer, Mars 2011
(vl-load-com)
(setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))

(defun *error* (msg)
(and msg
	(or
		(member (strcase msg) '("FUNCTION CANCELLED" "QUIT / EXIT ABORT" "FONCTION ANNULEE" "QUITTER / SORTIR ABANDON"))
		(princ (strcat "\nErreur : " msg))
	)
)
(if ss (setq ss nil))
(setvar "cmdecho" oldcmdecho)
(vla-endundomark acdoc)
(princ)
)

(vla-startundomark acdoc)
(setq oldcmdecho (getvar "cmdecho"))
(setvar "cmdecho" 0)

(if (setq ss (ssget '( (0 . "*POLYLINE") ) ))
(progn
	(vl-cmdf "_.convertpoly" "_h" ss "")
	(setq ss (ssget "_P"))
	(setq i 0)
	(repeat (sslength ss)
		(if (= (vla-get-objectname (setq pl (vlax-ename->vla-object (ssname ss i)))) "AcDb2dPolyline")
			(progn
				(vla-put-type pl 3)
				(vl-cmdf "_.spline" "_o" (ssname ss i) "")
			)
		)
		(setq i (1+ i))
	);repeat
);progn ss
);if ss

(*error* nil)
)

(princ "Commande à utiliser: PL2SPL")
(princ)

 

http://www.creao.fr/uploads/lisp/pline2spline.lsp

 

 

 

[Edité le 21/3/2011 par bryce]

[fauxsuisse]

Un grand merci bryce

c'est parfait :P

[Maxime85]

Bonjour

Merci pour ce lisp