Traduire des distance métriques en pieds

[pierrevigneux]

Bonsoir!

 

Quelqu'un aurait-il une routine pour écrire des (distances en mètre) équivalentes en système anglais c.a.d. en pied?

 

Bref j'ai un lotissement fait en mètre et notre client veux avoir les distances de ses lots inscrit en pied.

J,ai fait mon lotissement et cotés mes distances avec la commande de Gile seglen, maintenant faut traduire.

 

Merci!

[bonuscad]

Salut,

 

Tu as la fonction lisp (cvunit) pour faire des conversions dans des systèmes de mesure.

Regarde l'aide pour l'usage....

[pierrevigneux]

Merci bonuscad

 

En fait ce que j'espère est une routine qui écrit l'équivalent de la mesure pointée en système anglais (pied) soit qui multiple ta référence par .3048 et l'inscrit vis-avis l'autre qui est pointée.

 

Amicalement !

[bryce]

Bonjour,

 

Quelque chose comme ça ?

 

; Affiche à la fin des textes sélectionnés leur valeur convertie dans une autre unité.
; Exemple : avec M2FT, "996.5024m" devient "996.5024m (3269.365ft)"
; La précision et le format sont ceux définis dans le dessin par la commande _UNITS.
; La valeur à changer doit être au début du texte (rien devant).
; Les unités utilisables sont celles définies dans le fichier AutoCAD.unt.
; Vous pouvez ajouter des commandes supplémentaires sous la forme :
; 	(defun c:MACOMMANDE()
;	 	(cvutxt "UNITE DE DEPART" "UNITE DE CONVERSION" "SUFFIXE A AFFICHER, mettre "" pour aucun suffixe")
; 	)
;
; Brice Studer, mars 2011

(defun c:M2FT()
; conversion de m en pieds, suffixe ft
(cvutxt "m" "ft" "ft")
)

(defun c:M2FT2()
; conversion de m² en pieds², suffixe sq ft
(cvutxt "sq_m" "sq_ft" " sq ft")
)

(defun c:FT2M()
; conversion de pieds en m, suffixe m
(cvutxt "ft" "m" "m")
)

(defun c:FT2M2()
; conversion de pieds² en m², suffixe m²
(cvutxt "sq_ft" "sq_m" "m²")
)

(defun c:MM2IN()
; conversion de mm en pouces, suffixe in
(cvutxt "mm" "in" "in")
)

(defun c:IN2MM()
; conversion de pouces en mm, suffixe mm
(cvutxt "in" "mm" "mm")
)


;~~~~~~~ FIN COMMANDES UTILISATEUR ~~~~~~~

(defun CVUTXT (uni1 uni2 suff / acdoc *error* ss txt st val suff)
(vl-load-com)
(setq	acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))

(defun *error* (msg)
	(and msg
		(or	(member (strcase msg) '("FUNCTION CANCELLED" "QUIT / EXIT ABORT" "FONCTION ANNULEE" "QUITTER / SORTIR ABANDON"))
			(princ (strcat "\nErreur : " msg))
		)
	)
	(if ss (vla-delete ss))
	(vla-endundomark acdoc)
	(princ)
)
(vla-startundomark acdoc)
(if (and	(setq ss (ssget '( (0 . "TEXT") )))
			(setq ss (vla-get-activeselectionset acdoc))
	)
	(progn
		(vlax-for txt ss
			(if (/= 0 (setq val (atof (setq st (vla-get-textstring  txt)))))
				(vla-put-textstring txt (strcat st " ("(rtos (cvunit val uni1 uni2)) suff ")" ))
			)
		);vlax-for txt
	)
);if ssget
(*error* nil)
);cvutxt

(princ "\nCommandes à utiliser: M2FT M2FT2 FT2M FT2M2 MM2IN IN2MM")
(princ)

 

http://www.creao.fr/uploads/lisp/cvutxt.lsp

 

Edit: ajout des commande M2FT2 et FT2M2 pour convertir des surfaces.

 

 

 

[Edité le 3/3/2011 par bryce]

[pierrevigneux]

Merci bryce

 

Tu est un pro. Super c'est exactement ce que je demandais,

Autre question est-ce-que tu pourrais ajouter une commande, pour les surfaces de mes lots, qui ont été crées avec la commade de Gile total Area ?(c.a.d. M2 à Pi2.)

 

Merci encore!

[bryce]

J'ai ajouté deux commandes (M2FT2 et FT2M2). ;)

[pierrevigneux]

Merci encore Bryce

 

M2ft2 ne fonctionne pas avec les attrbuts de total area!

 

Si tu as une solution ?

 

 

[bryce]

Le lisp en effet ne traite que les textes pour le moment.

Je vais regarder ce que fait Total Area : il me semble que les attributs contiennent des champs, je verrai si je peux faire quelque chose... :casstet:

[(gile)]

Salut,

 

Si tu veux convertir les mètres en pieds avec TotalPerim, il suffit de mettre PERIMCONV à 0.3048. Pour les aires (TotalArea) AREACONV à 0.092903 convertira les mètres carrés en pieds carrés.

[pierrevigneux]

Salut gile

 

il suffit de mettre (TotalArea) AREACONV à 0.09290304 convertira les mètres carrés en pieds carrés.

 

C'est très fort je n'avais pas remarqué que tu pouvais convertir directement.

 

Chrome nikel !