[Résolu] Perte biblio Perso dans centre de contenu

[Circus]

Xp 32bit sp3 - Inv 2009

 

Bonjour,

 

Alors mon soucis c'est que je n'ai plus accés a mes profils perso dans le frame générator , et quand je regarde dans le centre de contenu , ils n'y sont plus non plus.

Je suis aller dans le Data management Server Console 2009 , ma bibliothèque est bien présente ! je l'ai supprimer puis réimporter...mais rien n'y fait , je relance inventor mais elle n'est toujours pas dans le centre de contenu.

J'ai eu le soucis déja ya moin de 15 jours , seul solution trouvé , désintaller inventor et le réinstaller...bref c'est pas une solution...

 

Merci d'avance.

 

[Edité le 7/2/2011 par Circus]

[bryce]

Bonjour,

 

La bibliothèque en question est-elle bien associée au projet actif ?

 

http://nsa26.casimages.com/img/2011/02/07/110207021907233206.png

 

 

 

 

[Edité le 7/2/2011 par bryce]

[Circus]

Merci bien !! c'est tout a fait ca.

 

bizarre que ca m'arrive pas pendant un moment et puis là 2 projets d'affilés je me plante...

 

Ahahah et zut j'en ai perdu du temps pour un truc si con.

 

Merci encore.

[Guillaume MASSART]

perso j'ai créé un projet vide, configuré comme il faut

Ensuite je fais des copier coller de ce projet, renommage du dossier et du fichier ipj et c'est parti

Plus de réglage de biblio ni de répertoire favoris...

 

Le script en vbs pour faire ça

Le projet type doit être dans un répertoire "projet type" avec le ipj qui s'appelle "projet type.ipj" et le script vbs doit être dans le même répertoire que le projet type (pas dans le projet type)

 

'Script de création automatique d'un nouveau projet pour INVENTOR
'Cela permet d'éviter les erreurs de copie lors de la création d'un nouveau projet à partir d'un projet type
dim chemin, oFSO, projet_nom
Set oFSO = CreateObject("Scripting.FileSystemObject")
'Récupération du chemin du script'
chemin= left(WScript.ScriptFullName,len(WScript.ScriptFullName)-len(WScript.ScriptName))
'Demande du nom du nouveau projet
projet_nom=inputbox("Quel est le nom du nouveau projet?")
'Vérification que l'utilisateur a bien mis un nom de projet'
if projet_nom="" then
msgbox "Nous n'avez pas donné de nom, ce programme va être fermé"
WScript.Quit
end if
'test du nom du projet pour savoir s'il n'existe pas déjà'
if oFSO.FolderExists(chemin & projet_nom) then
msgbox "Ce projet existe déjà"
WScript.Quit
else
'Copie du projet type vers le répertoire du projet'
oFSO.CopyFolder chemin & "projet type",chemin & projet_nom,false ' True : pour copier en "écrasant" destination si existe..

oFSO.CopyFile chemin & projet_nom & "\projet type.ipj",chemin & projet_nom & "\" & projet_nom & ".ipj",True ' True : pour copier en "écrasant" destination si existe..
oFSO.DeleteFile chemin & projet_nom & "\projet type.ipj",True  ' Le paramétre "Force" à true permet d'effacer les fichiers en lectures seules.
end if
msgbox "Le projet est disponible dans le répertoire suivant : " & chemin & projet_nom

 

[Edité le 7/2/2011 par gmassart]

[Circus]

D'habitude j'utilisai également un *.ipj déjà configuré , mais cette fois j'en ai utilisé un vieux...bref...

 

En tout cas efficace ton script , merci ! si un jour tu comptes le faire évoluer, ca serai bien de pouvoir choisir le chemin de destination.

 

Merci encore

A+

[Guillaume MASSART]

Bon bah pour toi Circus je vais y regarder, ça devrait pas poser de problème :)

[Guillaume MASSART]

C'est parti pour le code modifié

'Script de création automatique d'un nouveau projet pour INVENTOR
'Cela permet d'éviter les erreurs de copie lors de la création d'un nouveau projet à partir d'un projet type
dim chemin, oFSO, projet_nom
Set oFSO = CreateObject("Scripting.FileSystemObject")
'Récupération du chemin du script'
chemin= left(WScript.ScriptFullName,len(WScript.ScriptFullName)-len(WScript.ScriptName))
'Demande du nom du nouveau projet
projet_nom=inputbox("Quel est le nom du nouveau projet?")
'Vérification que l'utilisateur a bien mis un nom de projet'
if projet_nom="" then
msgbox "Nous n'avez pas donné de nom, ce programme va être fermé",vbCritical
WScript.Quit
end if

'choix du répertoire de destination
set oShell = CreateObject("Shell.Application")
Set oFolder = oShell.BrowseForFolder(&H0&, "Choisir un répertoire de destination", RETURNONLYFSDIRS,chemin)
If oFolder is Nothing Then 
MsgBox "Nous n'avez pas sélectionner de répertoire de destination, ce programme va être fermé",vbCritical
 WScript.Quit
Else
 Set oFolderItem = oFolder.Self
End If

'test du nom du projet pour savoir s'il n'existe pas déjà'
if oFSO.FolderExists(oFolderItem & "\" & projet_nom) then
msgbox "Ce projet existe déjà"
WScript.Quit
else
'Copie du projet type vers le répertoire du projet'
oFSO.CopyFolder chemin & "projet type",oFolderItem.path & projet_nom,false ' True : pour copier en "écrasant" destination si existe..

oFSO.CopyFile oFolderItem.path & projet_nom & "\projet type.ipj",oFolderItem.path & projet_nom & "\" & projet_nom & ".ipj",True ' True : pour copier en "écrasant" destination si existe..
oFSO.DeleteFile oFolderItem.path & projet_nom & "\projet type.ipj",True  ' Le paramétre "Force" à true permet d'effacer les fichiers en lectures seules.
end if
msgbox "Le projet est disponible dans le répertoire suivant : " & oFolderItem.path & projet_nom

[Circus]

Héhé , merci bien , c'est excellent, ca me dit encore une fois qu'il faudrait que je m'y mette à la programmation !!

 

J'ai corrigé les dernières ligne, il y avait un petit soucis, lors de la création du dossier.

pour le projet aaa , dans le chemin d:\inventor\auvent\ , ca donné comme résultat d:\inventor\auvent\auventaaa\

 

 

'Copie du projet type vers le répertoire du projet'
oFSO.CopyFolder chemin & "projet type",oFolderItem.path & "\" & projet_nom,false ' True : pour copier en "écrasant" destination si existe..

oFSO.CopyFile oFolderItem.path & "\" & projet_nom & "\projet type.ipj",oFolderItem.path & "\" & projet_nom & "\" & projet_nom & ".ipj",True ' True : pour copier en "écrasant" destination si existe..
oFSO.DeleteFile oFolderItem.path & "\" & projet_nom & "\projet type.ipj",True  ' Le paramétre "Force" à true permet d'effacer les fichiers en lectures seules.
end if
msgbox "Le projet est disponible dans le répertoire suivant : " & oFolderItem.path & projet_nom

 

Merci encore !

[Guillaume MASSART]

Ah

Arf

J'avais testé avec un lecteur réseau à la racine, le path renvoyait le "\" final...

Il faut corriger le msgbox final car le "\" manque encore :=)

 

Le code final corrigé :)

 

 

http:// http://www.piou2fois.info/cadxp/creation_nouveau_projet.zip

 

[Edité le 9/2/2011 par gmassart]