Sélection de groupes

[Carboleum]

 

Bonjour,

 

Est-il possible de faire une sélection de tous les groupes d'un dessin (named et/ou unnamed) ?

 

merci d'avance,

Bruno

 

[vincentp010]

Salut,

 

oui avec la commande select

"select" "groupe" "*"

[Carboleum]

 

 

merci,

 

mais il ne prend pas les unnamed groups

 

une autre idée ?

 

 

[LUDWIG]

J'avais ce lisp pour dégrouper les groupes

Tu peux peut être l'adapter avec un sssetfirst

 ;Décomposer les groupes

(defun c:supgp ()
(setq dictgroup (dictsearch (namedobjdict) "acad_group"))
(setq dictgroup (mapcar 'cdr
(vl-remove-if-not
'(lambda (x) (= 350 (car x)))
dictgroup
) ;_ Fin de vl-remove-if-not
) ;_ Fin de mapcar
) ;_ Fin de setq
;;;(initget "Oui Non")
;;;(setq reponse
;;;(getkword
;;;(strcat
;;;"\nIl y a "
;;;(itoa (length dictgroup))
;;;" groupes dans le dessin, voulez vous les supprimer ? [Oui/Non] :"
;;;) ;_ Fin de strcat
;;;) ;_ Fin de getkword
;;;) ;_ Fin de setq
(setq reponse "Oui")
 
(if (equal reponse "Non")
(exit)
) ;_ Fin de if
(setq i 0
) ;_ Fin de setq
(repeat (length dictgroup)
(entdel (nth i dictgroup))
(setq i (1+ i))
) ;_ Fin de while
(princ (strcat "\n" (itoa i) " groupes ont été suprimés."))
(princ)
) ;_ Fin de defun

[Carboleum]

 

 

Excellent! Merci!

 

(defun bl:list2ss (lst / select)
       (setq select (ssadd))
       (mapcar '(lambda (x) (ssadd x select)) lst)
       select)
(defun bl:massoc (n lst)
       (vl-remove-if-not '(lambda (x) (= n (car x))) lst))
(defun bl:group-list-all ()
       (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= 350 (car x))) (dictsearch (namedobjdict) "acad_group"))))
(defun bl:group-select-all ()
       (bl:list2ss (apply 'append (mapcar '(lambda (x) (mapcar 'cdr (bl:massoc 340 (entget x)))) (bl:group-list-all)))))

 

permet, par exemple:

 

(command "erase" (bl:group-select-all) "")