polylignes3d en faces 3d

[balyoa]

Bonjour,

 

Je souhaite savoir si il est possible de convertir automatiquement des polylignes 3D fermées en 3Dface ?

 

Ma config : AutocadMap2011 + covadis 11

 

Merci d'avance pour vos réponses.

 

Yoann

[RhymOne]

Bonjour,

Ce n'est que possible en lisp en te servant de ceci:

Merci à l'auteur (au pasage)

 (vl-load-com)
(defun l-coor2l-pt (lst flag / )
 (if lst
   (cons (list (car lst) (cadr lst) (if flag (caddr lst) 0.0))
     (l-coor2l-pt (if flag (cdddr lst) (cddr lst)) flag)
   )
 )
)
(defun C:3dpolTO3dface ( / js ind count e_name lst_pt)
 (setvar "cmdecho" 0)
 (princ "\nChoix des 3DPolylignes.")
 (setq js (ssget '((0 . "POLYLINE") (-4 . "&") (70 . 9))) ind 0 count 0)
 (cond
   (js
     (setvar "CMDECHO" 0)
     (command "_.UNDO" "_Begin")
     (while (setq e_name (ssname js ind))
       (setq
         ind (1+ ind)
         lst_pt (l-coor2l-pt (vlax-get (vlax-ename->vla-object e_name) 'Coordinates) T)
       )
       (cond
         ((eq (length lst_pt) 3)
           (command "_.3DFACE"
             "_none" (trans (car lst_pt) 0 1)
             "_none" (trans (cadr lst_pt) 0 1)
             "_none" (trans (caddr lst_pt) 0 1)
             "" ""
           )
           (setq count (1+ count))
         )
         ((eq (length lst_pt) 4)
           (command "_.3DFACE"
             "_none" (trans (car lst_pt) 0 1)
             "_none" (trans (cadr lst_pt) 0 1)
             "_none" (trans (caddr lst_pt) 0 1)
             "_none" (trans (cadddr lst_pt) 0 1)
             "_none" (trans (car lst_pt) 0 1)
             "" ""
           )
           (setq count (1+ count))
         )
       )
     )
     (command "_.UNDO" "_End")
     (setvar "CMDECHO" 1)
     (princ (strcat "\n" (itoa count) " 3DFaces crées à partir de 3Dpolylignes."))
   )
   (T (prompt "\nAucune sélection valide."))
 )
 (prin1)
)

[Calecx]

Bonjour,

 

Si tu possède Covadis, il y a aussi:

 

Covadis 3D / MNT Objet / Polyligne 2D-3D --->MNT

 

 

[didier]

coucou

 

j'ai regardé le lisp fourni par rhymone

sans bien en comprendre la finalité

 

comment fonctionne t'il s'il te plaît.

 

amicalement

[Calecx]

Le sujet avait été traité ici :

 

http://www.cadxp.com/sujetXForum-6900.htm

 

voir plus bas dans la page, la demande de lecrabe

 

[RhymOne]

Merci calecx c'est bien sa...