obligation de remplir tous les champs avant de pouvoir imprimer

Steven · le 20 septembre 2010

Salut à tous.

Je viens d'avoir une demande bien spécifique et je ne sais pas si c'est réalisable.

En effet, mon responsable souhaiterais savoir si il est possible d'être obliger de remplir tous les renseignement d'un bloc avec attributs (en l'occurence, le cartouche) et de ne pouvoir imprimer le dessin qu'après avoir rempli tout les attributs du cartouche et si le cartouche n'est pas rempli correctement, une fenêtre de dialogue apparaît lorsqu'on souhaite imprimer en disant que le cartouche n'est pas rempli correctement et que ça empêche donc d'imprimer.

RhymOne · le 20 septembre 2010

Salut,

Peut être avec l'annotativité; genre paramètres de visibilités ...

peut être creusé par la...

lili2006 · le 20 septembre 2010

Bonjour à toutes et tous,

Avec les champs et paramètres personnalisés ?

Steven · le 20 septembre 2010

Excusez-moi mais je ne comprends pas tout :casstet:

lili2006 · le 20 septembre 2010

Re,

En effet, pas grand chose à voir avec la question,...

Je pensais en jouant avec la variable FIELDEVAL, mais cela n'empêchera pas une impression,...

bryce · le 20 septembre 2010

Bonjour,

Je pense que ce ne serait possible qu'en LISP, en "interceptant" l'appel de la commande d'impression (avec un réacteur peut-être ? :question: )...

rebcao · le 20 septembre 2010

Bonsoir,

Il faut effectivement TESTER le contenu du cartouche et avec les commande NONDEF on peut "Supprimer" une commande... On annule la commande TRACEUR et voir PUBLIER...

Si le cartouche est OK on fait un REDEF des commandes !!!

Mais bon, qu'est ce qui permet de savoir que le cartouche est cohérent ??? Je peux très bien remplir tous les attributs en mettant partout TOTO.... Pas simple !

Christian

Steven · le 21 septembre 2010

Salut Christian.

Je suis conscient qu'on peut mettre n'importe quoi dans le cartouche mais le but est de remplir tous les renseignement du cartouche, après, si le concepteur mets n'importe quoi dedans, libre à lui. Le fait est que parfois, il manque des renseignements sur la cartouche et que le but est d'avoir des sorties de plans avec un cartouche complet.

En ce qui concerne les commande NONDEF et REDEF, comment pourrait-on faire pour que celle-ci puisse se lancer automatiquement avant et après le remplissage du cartouche?

Je suppose qu'un lisp qu'il faudrait charger sur chaque bécanne est necessaire . Toutefois, il y a des PC de "passage" ou "self" pour le concepteurs de passage tel que des interimaires, par exemple. Comment faire pour que ces profil non permanent puisse avoir cette contrainte par défaut? Vais-je devoir configurer l'AutoCAD de la bécane "self" avant l'arrivé de la personne?

[Edité le 21/9/2010 par Steven]

rebcao · le 21 septembre 2010

Bonjour,

J'utilise beaucoup le principe d'un simple SCRIPT de démarrage derrière mon raccourci sur le bureau. (option /B MONSCRIPT.SCR) après la cible. Tu peux bien sur indiquer un chemin absolu vers le fichier SCRIPT (chemin réseau).

/B comme SCRIPT c'est logique !!! ;)

Le LISP reste indispensable

Christian

RhymOne · le 21 septembre 2010

Salut à tous,

 Je suis conscient qu'on peut mettre n'importe quoi dans le cartouche mais le but est de remplir tous les renseignement du cartouche, après, si le concepteur mets n'importe quoi dedans, libre à lui. Le fait est que parfois, il manque des renseignements sur la cartouche et que le but est d'avoir des sorties de plans avec un cartouche complet.

Pourquoi s'embêté si une fois imprimé on y comprend plus rien ...

J'aurais dit come rebcao:

 Mais bon, qu'est ce qui permet de savoir que le cartouche est cohérent ??? Je peux très bien remplir tous les attributs en mettant partout TOTO.... Pas simple !

Peut être qu'en conbinant lisp et champs perso....

Steven · le 21 septembre 2010

Si le concepteur veut mettre n'importe quoi dans le cartouche, libre a lui.

Si après il veut passer pour un c... auprès du chef de projet, du client ou n'importe qui d'autre, c'est son problème.

Le but est que si par exemple il y a 10 attributs à remplir, les 10 attributs doivent être obligatoirement remplis.

Si 1 seul attribut n'est pas rempli, l'impression est impossible. Peu importe ce qui est indiqué, le principal est que tous les renseignements du cartouches soient remplis.

Par exemple sur certains sites internet, lorsqu'on doit remplir un formulaire, on est obligé de mettre un nom, un prénom, une adresse et une adresse mail.

Si l'un de renseignements n'est pas rempli, on ne peut pas aller à l'étape suivante.

Soit, on peut indiquer n'importe quoi mais on ne peut cependant pas aller à l'étape suivante si on a rien renseigné.

Je souhaiterais la même chose sur AutoCAD avec le cartouche. Rendre certains renseignements obligatoires.

Si ceux-ci ne sont pas remplis (et peu importe ce qu'on y met), on ne peut pas passer à l'étape d'impression.

[Edité le 21/9/2010 par Steven]

(gile) · le 21 septembre 2010

Salut,

J'ai regardé du côté des réacteurs. S'il est assez facile d'intercepter la commande PLOT, je ne suis pas sûr qu'il soit possible de l'annuler depuis la fonction de rétro-action (callback) : pas de possibilité d'appeler command depuis une fonction de rétro-action et vla-SendCommand nest pas synchrone et s'exécute après la commande en cours.

J'ai donc opté pour la méthode décrite par Christian (rebcao) : la redéfinition de la commande.

Le code à charger à l'ouverture de chaque document (acaddoc.lsp ou AutoCAD.mnl)

Remplacer "cartouche" par le nom du bloc cartouche entre guillemets (sensible à la casse).

PS : la commande native reste accessible en la faisant précéder d'un point : .TRACEUR ou .-TRACEUR (_.PLOT ou _.-PLOT).

(defun RedefinedPlot (dlg / ss)
 (vl-load-com)
 (if (ssget "_X"
        (list '(0 . "INSERT")
          (cons 410 (getvar 'ctab))
          '(2 . "cartouche") ; remplacer par le nom du bloc cartouche
        )
     )
   (progn
     (vlax-for    obj (setq ss
              (vla-get-activeSelectionSet
                (vla-get-ActiveDocument
                  (vlax-get-acad-object)
                )
              )
           )
   (if (vl-some '(lambda (x) (= (vla-get-TextString x) ""))
            (vlax-invoke obj 'GetAttributes)
       )
     (alert "Le cartouche n'est pas enitèrement rempli")
     (progn
       (if    dlg
         (initdia)
       )
       (command "_.plot")
     )
   )
     )
   )
   (progn
     (if dlg
   (initdia)
     )
     (command "_.plot")
   )
 )
 (princ)
)

(defun c:plot () (RedefinedPlot T))
(defun c:traceur () (RedefinedPlot T))
(defun c:-plot () (RedefinedPlot nil))
(defun c:-traceur () (RedefinedPlot nil))

(if S::STARTUP
 (setq    S::STARTUP
    (append S::STARTUP
        '((command "_.undefine" "_plot")
          (command "_.undefine" "_-plot")
          (princ)
         )
    )
 )
 (defun-q S::STARTUP
      ()
      (command "_.undefine" "_plot")
      (command "_.undefine" "_-plot")
      (princ)
 )
)

Pour rétablir les commandes natives, utiliser la commande REDEF (_REDEFINE) :

(command "_.redefine" "_plot")
(command "_.redefine" "_-plot")

lili2006 · le 21 septembre 2010

Bonsoir à toutes et tous,

Le but est que si par exemple il y a 10 attributs à remplir, les 10 attributs doivent être obligatoirement remplis.

D'ou mon idée de départ,...(Réponse N° 2)

Un exemple tiré de l'idée de "Tatouage" de Bonuscad,...

(Entre tps, j'ai créer également un champ pour le dossier)

http://img.ahst.fr/data/images/cartouchec.jpg

Steven · le 21 septembre 2010

Bonsoir à toutes et tous,

Le but est que si par exemple il y a 10 attributs à remplir, les 10 attributs doivent être obligatoirement remplis.

D'ou mon idée de départ,...(Réponse N° 2)

Un exemple tiré de l'idée de "Tatouage" de Bonuscad,...
(Entre tps, j'ai créer également un champ pour le dossier)

http://img.ahst.fr/data/images/cartouchec.jpg

Le cartouche a déjà des champs personnalisés mais ça n'empêche pas l'impression si un renseignement manque ou si on fait sauté un champs. Si si, y en a qui les flinguent, c'est du vécu. Celà dit, je peux essayer un nouveau cartouche dont je vais étudier l'élaboration.

Salut,

J'ai regardé du côté des réacteurs. S'il est assez facile d'intercepter la commande PLOT, je ne suis pas sûr qu'il soit possible de l'annuler depuis la fonction de rétro-action (callback) : pas de possibilité d'appeler command depuis une fonction de rétro-action et vla-SendCommand nest pas synchrone et s'exécute après la commande en cours.

J'ai donc opté pour la méthode décrite par Christian (rebcao) : la redéfinition de la commande.

Le code à charger à l'ouverture de chaque document (acaddoc.lsp ou AutoCAD.mnl)
Remplacer "cartouche" par le nom du bloc cartouche entre guillemets (sensible à la casse).

PS : la commande native reste accessible en la faisant précéder d'un point : .TRACEUR ou .-TRACEUR (_.PLOT ou _.-PLOT).
(defun RedefinedPlot (dlg / ss)
 (vl-load-com)
 (if (ssget "_X"
        (list '(0 . "INSERT")
          (cons 410 (getvar 'ctab))
          '(2 . "cartouche") ; remplacer par le nom du bloc cartouche
        )
     )
   (progn
     (vlax-for    obj (setq ss
              (vla-get-activeSelectionSet
                (vla-get-ActiveDocument
                  (vlax-get-acad-object)
                )
              )
           )
   (if (vl-some '(lambda (x) (= (vla-get-TextString x) ""))
            (vlax-invoke obj 'GetAttributes)
       )
     (alert "Le cartouche n'est pas enitèrement rempli")
     (progn
       (if    dlg
         (initdia)
       )
       (command "_.plot")
     )
   )
     )
   )
   (progn
     (if dlg
   (initdia)
     )
     (command "_.plot")
   )
 )
 (princ)
)

(defun c:plot () (RedefinedPlot T))
(defun c:traceur () (RedefinedPlot T))
(defun c:-plot () (RedefinedPlot nil))
(defun c:-traceur () (RedefinedPlot nil))

(if S::STARTUP
 (setq    S::STARTUP
    (append S::STARTUP
        '((command "_.undefine" "_plot")
          (command "_.undefine" "_-plot")
          (princ)
         )
    )
 )
 (defun-q S::STARTUP
      ()
      (command "_.undefine" "_plot")
      (command "_.undefine" "_-plot")
      (princ)
 )
)
Pour rétablir les commandes natives, utiliser la commande REDEF (_REDEFINE) :
(command "_.redefine" "_plot")
(command "_.redefine" "_-plot")

Ca à l'air bien ça. Je vais regarder ça de plus près demain matin.

Merci à vous les gars ;)

lili2006 · le 21 septembre 2010

Re,

mais ça n'empêche pas l'impression si un renseignement manque

C'est impossible puisque la mise à jour des champs peut se commander à l'impression avec la variable "FIELDEVAL",...

Rappel => (Dans ton cas à 4)

FIELDEVAL Concept Procédure Aide-mémoire

Type Entier
Enregistré dans : Dessin
Valeur initiale : 31

Détermine le mode de mise à jour des champs. Le paramètre est stocké sous forme de code binaire en utilisant la somme des valeurs suivantes :

0
Non mise à jour

1
Mise à jour à l'ouverture

2
Mise à jour à l'enregistrement

4
Mise à jour au traçage

8
Mise à jour à l'utilisation de ETRANSMIT

16
Mise à jour à la régénération

ou si on fait sauté un champs.

J'ai du mal à voir comment ou pourquoi ???!!!!

Steven · le 22 septembre 2010

ou si on fait sauté un champs.

J'ai du mal à voir comment ou pourquoi ???!!!!

C'est très simple.

Nous savons tous que personne n'est égal en ce concerne l'utilisation d'AutoCAD dans un BE. Parfois, la réaction de certains utilisateurs qu ine comprenent pas le fonctionnement du chose, détruise la chose.

Exemple: Je ne sais pas modifier les attributs d'un bloc, bah je décompose le bloc et je double-clic sur la difinition des attributs et je modifie le texte. Point.

Si si, ça existe, c'est du vécu. Résultat des course, tu récupères le dessin, tu veux modifier les attributs du bloc et Ô surprise, le machin est décomposé. Trop bien...

Le chmaps automatique relier à la fenêtre flottant de l'espace papier pour indiquer l'échelle de sortie du dessin; bah, je vais le modifier manuellement. Il perds sa partularité d'être automatique mais tant pis.

Ceci sont des exemple que j'ai pu voir et que certains d'entre vous ont pu voir aussi.

Je ne jète pas la pierre à ceux ou celles qui peuvent faire ce genre de manip' mais je voudrait seulement éviter ce genre de chose. Pour ce qui est du cartouche, j'ai trouvé une solution. Il n'est pas décomposable. Celà dit, on peut toujours le modifier par l'éditeur de bloc mais bon, comme je l'ai dis, nous ne sommes pas tous égaux sur AutoCAD et de ce fait, la réflex d'aller dans l'éditeur de bloc ne sera pas toujours présent et ça devrait, je pense, minimiser la chose.

Je vais toutefois faire un test avec ta solution et un autre avec la solution de Gile.

lili2006 · le 22 septembre 2010

Re,

Oui, tu as raison !

A mon niveau, je le vois aussi avec mes étudiants,.... :o

Connexion

obligation de remplir tous les champs avant de pouvoir imprimer

Messages recommandés

Steven

RhymOne

lili2006

Steven

lili2006

bryce

rebcao

Steven

rebcao

RhymOne

Steven

(gile)

lili2006

Steven

lili2006

Steven

lili2006

Créer un compte ou se connecter pour commenter

Créer un compte

Se connecter

Forums

Naviguer

Activité

Information importante