Droite perpendiculaire ellipse

[nicolas2]

Bonjour à vous.

J'ai une ellipse, j'ai un point sur cette ellipse et je veux tracer une droite perpendiculaire à ce point ? :(

Merci pour votre aide

[RhymOne]

Bjr, question de géométrie. Voyons

Bon une technique à moi

Donc tu a une elipse avec un point dessus.

Decale l'elipse à l'interieur et a l'exterieur de 1par exemple puis tu fait une ligne partant du point vers l'elipse interieur avec accrochage perpendiculaire.

Puis tu repete l'opération avec l'elipse exterieur.

Tu insere deux points au niveau des extremites des lignes et tu efface les lignes et les elipse decalé.

Tu a donc 3 point et l'elipse tu fait une ligne en partant du point à l'exterieur vers l'elipse en accrochage perpendiculaire, puis de la ligne interieur vers l'elipse tjrs le mem accrochage.

 

Normalement la moyenne entre ces deux lignes est la bonne...

 

[Pru]

Bonjour,

 

la méthode doit être la même que sur Autocad 2009 que j'utilise.

 

Je procède comme ceci pour tracer des perpendiculaires sur mes cercles ou courbes:

 

1. fonction "Droite".

2. clic droit + crtl pour faire apparaitre le menu contextuel d'accroche aux objets.

3. "Perpendiculaire"

 

4. Tu sélectionnes ensuite ton ellipse / cercle / courbe.

 

A ce niveau, une droite virtuelle perpendiculaire a ta sélection se déplacera en fonction du pointeur de ta souris. Sur une ellipse complète c'est assez visuel.

 

5. Tu sélectionnes le point voulu.

[Tramber]

JOLI :cool:

 

J'ai cherché à faire une perpendiculaire différée avec une ligne et j'ai été déçu de ne pas pouvoir. Avec une droite, ca fonctionne, en effet.

 

Bravo. L'aide dit bien :

 

"Ainsi, vous pouvez utiliser des droites pour localiser le centre d'un triangle, préparer des vues multiples d'un même élément ou définir des points d'intersection temporaires à utiliser avec les modes d'accrochage aux objets."

 

Les accrochages temporaires (utiles avec les tangentes et les intersections) sont rares et fonctionnent avec beaucoup d'objets, mais celui là est vraiment particulier.

[(gile)]

Salut,

 

Je pensais l'avoir déjà posté mais je ne le retrouve pas.

PERTAN permet de dessiner une ligne perpendiculaire (ou tangente) au point spécifié sur la courbe (ligne, polyligne, ellipse, arc, cercle, spline)

 

(defun c:pertan (/ *error* ent osm ort aut snp p1 pa drv p2)
 (vl-load-com)
 (or *acdoc*
     (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
 )

 (defun *error* (msg)
   (or	(= msg "Fonction annulée")
(princ (strcat "\nErreur: " msg))
   )
   (setvar "OSMODE" osm)
   (setvar "ORTHOMODE" ort)
   (setvar "AUTOSNAP" aut)
   (setvar "SNAPANG" snp)
   (vla-EndUndoMark *acdoc*)
   (princ)
 )

 (setq	osm (getvar "OSMODE")
ort (getvar "ORTHOMODE")
aut (getvar "AUTOSNAP")
snp (getvar "SNAPANG")
 )
 (if
   (and
     (setq ent
     (car
       (entsel "\nÉlever une perpendiculaire (ou une tangente) à: "
       )
     )
     )
     (IsCurveObject ent)
   )
    (if
      (and
 (setq p1 (getpoint "\nDu point: "))
 (setq pa (vlax-curve-getParamAtPoint ent (trans p1 1 0)))
      )
(progn
  (vla-StartUndoMark *acdoc*)
  (setq drv (vlax-curve-getFirstDeriv ent pa))
  (setvar "SNAPANG"
	  (angle (trans '(0 0 0) 0 1) (trans drv 0 1))
  )
  (setvar "ORTHOMODE" 1)
  (setvar "OSMODE" 0)
  (setq p2 (getpoint p1 "\nAu point :"))
  (vl-cmdf "_.line" p1 p2 "")
  (setvar "OSMODE" osm)
  (setvar "ORTHOMODE" ort)
  (setvar "AUTOSNAP" aut)
  (setvar "SNAPANG" snp)
  (vla-EndUndoMark *acdoc*)
)
    )
    (princ "\nEntité non valide.")
 )
 (princ)
)

;;; IsCurveObject (gile)
;;; Evalue si un objet (ename ou vla-object) est un "CurveObject"

(defun IsCurveObject (obj)
 (and
   (or	(= (type obj) 'VLA-OBJECT)
(setq obj (vlax-ename->vla-object obj))
   )
   (member (vla-get-ObjectName obj)
    '("AcDbArc"		  "AcDbCircle"
      "AcDbEllipse"	  "AcDbLine"
      "AcDbPolyline"	  "AcDb2dPolyline"
      "AcDb3dPolyline"	  "AcDbSpline"
     )
   )
 )
)

[nicolas2]

Bonjour et Merci à tous.

J'avais l'impression d'être seul avec ce problème.

En fait, je bidouillais comme vous, à la petite bricole.

J'ai pris le LISP à Gile :) , un gain de temps appréciable

Merci à tous de vous être penché sur mon problème

Longue vie à CADXP!