Filtres de coordonnées

[zebulon_]

Bonjour,

 

Comment faire pour rendre le filtre de coordonnées .XY permanent ? Les filtres de coordonnées ne sont pas paramétrables dans l'accrochage aux objets.

 

 

[Tramber]

La réponse est non, ils ne sont pas paramètrables mais si tu utilises toujours la même commande, c'est simple de faire une macro dans un bouton et c'est peut-être encore plus rapide.

 

C'est pour la commande LIGNE ou une autre ?

[zebulon_]

Yep, pour la commande ligne.

[Patrick_35]

Bonjour,

Si j'ai bien compris, avec la variable coords

 

@+

[zebulon_]

Ben, ce que je voudrais c'est que quand je fais un ligne, ça me fasse toujours

 

_ line .xy .xy .xy .....

 

ou mieux avec le z tout de suite forcé à 0.00

 

_line .xy 0.00 .xy 0.00 .xy 0.00 etc...

[Patrick_35]

Pour le z, tu peux passer par la commande elev, mais je ne comprends pas la question, quand tu fais la commande ligne, il ne reste qu'à cliquer à l'écran autant de fois que ti le souhaites

 

@+

 

 

[zebulon_]

Oui, ELEV ça marche bien quand on digitalise (c'est pour ça que ça a été inventé), c'est à dire quand on clique sans s'accrocher à un sommet.

 

Dès qu'on utilise un accroche aux objets, autocad ne tient plus compte de ce que j'aurai pu lui dire avec la commande ELEV, d'où la nécessité d'utiliser .XY

 

[Tramber]

Glisses donc la macro :

 

^C^C_line .z 0,0,0 \.z 0,0,0 \ 

 

Pour une poly2D (qui garde, en tous points, l'altitude du premier point et qui est donc une commande 2D), la macro est à adapter, le filtre au point de départ suffit.

Ca donnerait à peu près ca :

 

^C^C_pline .z 0,0,0 

[bonuscad]

A l'aide du Lisp, on peut créer un "clone" de la commande LIGNE qui reprend les fonctionalités désirées. Si ca peut convenir, pour une version pleine bien sûr.

 

(defun err_lxy (ch)
(cond
	((eq ch "Function cancelled") nil)
	((eq ch "quit / exit abort") nil)
	((eq ch "console break") nil)
	(T (princ ch))
)
(if pt_b (command ""))
(setq last#point_cmd T *error* olderr)
(setvar "cmdecho" 1)
(princ)
)
(defun c:linexy ( / odlerr msg_f msg_n n pt_b pt_n)
(setvar "cmdecho" 0)
(setq olderr *error* *error* err_lxy)
(setq msg_f "\nSpécifiez le point suivant .XY de, ou [annUler]: "
      msg_n "\nSpécifiez le point suivant .XY de, ou [Clore/annUler]: "
      n 0
)
(while (null pt_b)
	(setq pt_b (getpoint "\nSpécifiez le premier point .XY de: "))
	(if (and (null pt_b) last#point_cmd)
		(setq pt_b (getvar "lastpoint"))
		(if (not last#point_cmd) (princ "\nAucune ligne ou arc à continuer."))
	)
)
(command "_.line" ".xy" pt_b 0.0)
(princ " Z de 0.0 ")
(initget "U ANNUler _Undo UNDO")
(while (and (setq pt_n (getpoint pt_b (if (< n 2) msg_f msg_n))) (/= pt_n "Close"))
	(if (< n 1)
		(initget "U ANNUler _Undo UNDO")
		(initget "U ANNUler Clore _Undo UNDO Close")
	)
	(if (listp pt_n)
		(progn
			(command ".xy" pt_n 0.0)
			(setq n (1+ n) pt_b pt_n)
			(princ " Z de 0.0 ")
		)
		(if (zerop n)
			(princ "\nTous les segments sont déjà annulés.")
			(progn
				(command "_undo")
				(setq n (1- n) pt_b (getvar "lastpoint"))
			)
		)
	)
)
(if (eq pt_n "Close")
	(command "_close")
	(command "")
)
(setq last#point_cmd T *error* olderr)
(setvar "cmdecho" 1)
(princ)
)

 

Fonction testée rapidement, attention!

[zebulon_]

Merci,

 

ça marche pile poil.