cotation en pourcentage

[bekibo]

Bonjour, je voudrai juste indiquer la cote de mes angles en pourcentage et non en degré.....

[Tramber]

Alors là c'est facile :

dans ton style de cote ou dans les proriétés d'une, choisis une cotation en gradians comme format de l'angle.

Mais il te sera plus difficile d'appliquer un coef car cela n'est possible que sur les cotations de longueur.

 

 

[Edité le 8/6/2009 par Tramber]

[bekibo]

BonjouTrambler,

 

j'ai effectivement appliqué un coeff pour transposer mes angles, mais je n'arrive toujours pas à indiquer sur le plan la pente en pourcentage; sinon, il faut que je l'écrive en format texte.

[(gile)]

Alors là c'est facile :

dans ton style de cote ou dans les proriétés d'une, choisis une cotation en gradians comme format de l'angle.

Mais il te sera plus difficile d'appliquer un coef car cela n'est possible que sur les cotations de longueur.

 

:casstet: Là, j'ai un doute...

 

Le "gradian" (il me semble qu'on parle plutôt de grade en français, encore une traduction "autodeskienne"....) est une unité angulaire comme le degré ou le radian.

L'expression d'une pente (angle) en pourcentage correspond à la tangente de l'angle multipliée par 100 (autrment dit : le rapport entre le dénivelé et la distance horizontale).

 

Une pente de 100% correspond donc à un angle de 45°, pi/4 radians ou 50 grades.

 

Je ne connais pas d'autre moyen que de forcer la cote pour faire ce que bekibo demande.

[lili2006]

Bonjour à toutes et tous,

 

Entièrement d'accord avec (gile),

 

50 grades

 

Encore écris => 50 gon ou 50 gons dans le domaine de la topographie (symbole gon gônia : angle, en grec) )

 

Mais, on peut aussi appeler cette mesure angulaire "Gradian", bof ! :o

[Tramber]

Une pente de 100% correspond donc à un angle de 45°, pi/4 radians ou 50 grades.

 

Ok, mais il est clair que le gradian et la valeur de pente n'ont rien à voir sauf peut-être dans ce cas précis. Mais tout le monde sait que TAN 45 =1 ! Cas exceptionnel.

 

[Edité le 8/6/2009 par Tramber]

[bekibo]

Merci pour ce débat;

donc si je comprends bien, j'en reste à ma méthode?!! "cotation forcée"

[Tramber]

Oui, à moins d'un programme qui pourrait la forcer à ta place et faire la convertion en valeur de pente. Ceci dit, il me parait génant de coter une pente en % sur la base d'une cotation d'angle. D'ordinaire, c'est un texte écrit le long de la pente.

 

Veux-tu faire un programme Autolisp ?

[bekibo]

je n'en ai malheureusement pas la capacité :exclam:

[Tramber]

(defun c:cot%()
 (vl-load-com)
 (setq vlcot(vlax-ename->vla-object(car(entsel))))
 (vla-put-TextOverride vlcot
   (strcat"Pente à"(rtos(* 100(/(sin(vla-get-Measurement vlcot))(cos(vla-get-Measurement vlcot))))2 2)"%"))
 )

 

Enregistre ce texte dans un fichier *.lsp puis charge le (glisser-déposer suffit)

 

Lance la commande COT% et dis-nous déjà si tu veux une amélio. Le principe est simple, au choix des objets, tu cliques une cotation d'angle.

 

A toi de vérifier la formule math par les résultats.

[bekibo]

Merci beaucoup, je vais essayer

[(gile)]

Un autre qui crée un objet texte le long de la pente.

Il suffit de cliquer 2 points.

 

(defun c:pente% (/ p1 p2 a)
 (if
   (and
     (setq p1 (getpoint "\nPremier point: "))
     (setq p2 (getpoint "\nDeuxième point: "))
     (setq a (angle p1 p2))
   )
    (entmake
      (list
 '(0 . "TEXT")
 '(100 . "AcDbEntity")
 '(100 . "AcDbText")
 '(10 0. 0. 0.)
 (cons 40 (getvar 'textsize))
 (cons 1
       (strcat (rtos (abs (* 100 (/ (sin a) (cos a)))) 2 2) " %")
 )
 (cons 50
       (if (minusp (cos a))
	 (+ pi a)
	 a
       )
 )
 '(72 . 1)
 (cons 11 (mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.)) p1 p2))
 '(73 . 1)
      )
    )
 )
 (princ)
)

[Tramber]

(gile) s'ennuie tellement qu'il fait du ENTMAKE !

[bekibo]

Commande inconnue "COT%". :casstet:

 

Je l'ai pourtant charger comme un fichier lps :calim:

[Tramber]

test.LSP, par exemple !

 

Au glisser-déposer, tu devrais avoir une confirmation de chargement.

 

NB : tu peux ajouter le code de (gile) à ce fichier et aussi lancer PENTE%.

 

Mais d'abord, essaie de nous charger ce fichier, ca va marcher. (gile va te donner un lien pour son cours sur les chargments de programmes, n'est-ce pas (gile) ?)

[bekibo]

Merci à tous les deux

[(gile)]

(gile) s'ennuie tellement qu'il fait du ENTMAKE !

 

J'aime bien entmake, si on veux ensuite changer/ajouter certaines propriétés, il suffit de modifier/ajouter une entrée dans la liste ;)

 

bekibo,

tu trouveras sur cette page les explications concernant le chargement et l'exécution des LISP.

[brunomu]

Sauf erreur de ma part, la routine de gile ne marche que dans le SCG ?

[(gile)]

Salut

 

Effectivement.

Voilà deux autres versions qui ne fonctionnent qu'en 2d (plan XY du SCU courant parallèle au plan du SCG).

 

La première mesure la pente par rapport à l'axe X du SCU courant :

(defun c:pente% (/ p1 p2 a)
 (if
   (and
     (setq p1 (getpoint  "\nPremier point: "))
     (setq p2 (getpoint p1 "\nDeuxième point: "))
     (setq a (angle p1 p2))
   )
    (entmake
      (list
 '(0 . "TEXT")
 '(100 . "AcDbEntity")
 '(100 . "AcDbText")
 '(10 0. 0. 0.)
 (cons 40 (getvar 'textsize))
 (cons 1
       (strcat (rtos (abs (* 100 (/ (sin a) (cos a)))) 2 2) " %")
 )
 (cons 50
       (+ (angle '(0. 0. 0.) (getvar 'ucsxdir))
	  (if (minusp (cos a))
	    (+ pi a)
	    a
	  )
       )
 )
 '(72 . 1)
 (cons 11 (mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.)) (trans p1 1 0) (trans p2 1 0)))
 '(73 . 1)
      )
    )
 )
 (princ)
)

 

La seconde mesure la pente par rapport au SCG mais fonctionne quelque soit le SCU courant :

(defun c:pente%	(/ p1 p2 a)
 (if
   (and
     (setq p1 (getpoint "\nPremier point: "))
     (setq p2 (getpoint p1 "\nDeuxième point: "))
     (setq a (angle (setq p1 (trans p1 1 0)) (setq p2 (trans p2 1 0))))
   )
    (entmake
      (list
 '(0 . "TEXT")
 '(100 . "AcDbEntity")
 '(100 . "AcDbText")
 '(10 0. 0. 0.)
 (cons 40 (getvar 'textsize))
 (cons 1
       (strcat (rtos (abs (* 100 (/ (sin a) (cos a)))) 2 2) " %")
 )
 (cons 50
       (if (minusp (cos a))
	 (+ pi a)
	 a
       )
 )
 '(72 . 1)
 (cons 11 (mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.)) p1 p2))
 '(73 . 1)
      )
    )
 )
 (princ)
)

[brunomu]

Ça marche, c'est cool ! Merci.

 

Juste un truc : comment faire pour que le texte soit créé dans le style de texte courant ?

[ronsinette]

Merci pour ces lisp, cela m'a été très utile!