bloquer rotation attribut

[pascal19]

Bonjour

Peut-on bloquer l'orientation d'un attribut dans un bloc, de sorte que si l'on tourne le bloc, l'attribut reste horizontal (rotation= 0)

[rebcao]

Bonsoir,

 

de base NON !

 

A partir de 2008 on peut, grâce à l' ANNOTATIF !

 

Christian

[lili2006]

Bonsoir à toutes et tous,

 

Et en 2007, on peut grâce aux lisps de Patrick_35 =>

 

 

 ;;;=================================================================
;;;
;;; ROT_0.LSP V2.00
;;;
;;; Laisser l'angle de rotation à 0 de tous les attributs
;;;
;;; Copyright (C) Patrick_35
;;;
;;;=================================================================

(defun Attributs_rot_0(rea obj / att)
 (cond
   ((eq (cdr (assoc 0 (entget (cadr obj)))) "INSERT")
     (foreach att (vlax-invoke (vlax-ename->vla-object (cadr obj)) 'getattributes)
(vla-put-rotation att 0)
     )
   )
 )
)

(defun c:rot0()
 (if mrea_rot0
   (princ "\n\tL'angle des Attributs à 0 est déjà activée.")
   (progn
     (setq mrea_rot0 (vlr-acdb-reactor nil '((:vlr-objectModified . Attributs_rot_0))))
     (princ "\n\tActivation de l'angle des Attributs à 0")
   )
 )
 (princ)
)

(defun c:srot0()
 (if mrea_rot0
   (progn
     (vlr-remove mrea_rot0)
     (setq mrea_rot0 nil)
     (princ "\n\tDésactivation de l'angle 0 des Attributs")
   )
   (princ "\n\tL'angle des Attributs à 0 est déjà désactivée.")
 )
 (princ)
)

(vl-load-com)
(princ (strcat "\n\tPour activer l'angle des Attributs à 0, lancez la commande ROT0.\n\tPour revenir à la normale, faites la commande SROT0."))
(princ)

[pascal19]

merci pour vos réponses, ça me va trés bien

a+