Chaudronnerie Fond GRC

[nicolas2]

Bonjour et merci à tous pour votre aide !

Je voudrais modifier le programme suivant en inserrant des formules mathématiques sur les lignes surlignées en jaune :

 

DiamExt (getreal "\nDiamètre extérieur: ")

[surligneur] RayInt (getreal "\nRayon intérieur: ")

RayCar (getreal "\nRayon de carre: ")[/surligneur]

Ep (getreal "\nEpaisseur: ")

HtBD (getreal "\nHauteur du bord droit: ")

[surligneur] HtTot (getreal "\nHauteur totale: ")[/surligneur]

PtIns (getpoint "\nPoint d'insertion: ")

X0 (- (nth 0 PtIns) (/ DiamExt 2))

X1 (+ (nth 0 PtIns) (/ DiamExt 2))

Y0 (- (+ (nth 1 PtIns) HtTot) RayInt Ep)

Y1 (+ (nth 1 PtIns) HtBD)

 

En sachant que :

Rayint = DiamExt

RayCar = 1/10ième de DiamExt

HtTot = HtBD + Ep + h2 en sachant que h2 = Rayint - (Racine ((Rayint - RayCar)² - (DiamExt/2 - Ep - RayCar)² ) )

 

Merci encore pour votre aide

[bonuscad]

Bonjour,

 

Retranscrit correctement, cela pourrait se faire comme ceci:

 

(setq

DiamExt (getreal "\nDiamètre extérieur: ")

RayCar (/ DiamExt 10.0)

Ep (getreal "\nEpaisseur: ")

HtBD (getreal "\nHauteur du bord droit: ")

HtTot (+ HtBD Ep (- DiamExt (sqrt (- (expt (- DiamExt RayCar) 2.0) (expt (- (* DiamExt 0.5) Ep RayCar) 2.0)))))

PtIns (getpoint "\nPoint d'insertion: ")

X0 (- (car PtIns) (* DiamExt 0.5))

X1 (+ (car PtIns) (* DiamExt 0.5))

Y0 (- (+ (cadr PtIns) HtTot) DiamExt Ep)

Y1 (+ (cadr PtIns) HtBD)

)

[Bred]

Salut,

 

Rayint = DiamExt

Tu remplace donc dans les formules RayInt par DiamExt

(setq Y0 (- (+ (nth 1 PtIns) HtTot) DiamExt Ep))

 

RayCar = 1/10ième de DiamExt

pour diviser, voici comment ela s'écris :

(setq RayCar (/ DiamExt 10))

 

HtTot = HtBD + Ep + h2 en sachant que h2 = Rayint - (Racine ((Rayint - RayCar)² - (DiamExt/2 - Ep - RayCar)² ) )

j'espère ne pas me tromper (j'ai pas tester...):

(setq h2 (- Rayint (sqrt (- (expt (- Rayint RayCar) 2) (expt (- (/ DiamExt 2) Ep RayCar) 2)))))

(setq HtTot (+ HtBD Ep h2))

 

Edit : Ha! doubler par bonuscad !

 

[Edité le 8/1/2009 par Bred]

[nicolas2]

Merci à vous 2, tout fonctionne à merveille.

Je vais essayer de faire la même chose pour un fond elliptique :

- le rapport de mon ellipse entre le grand axe et le petit axe est de 1.9

(ex : si mon grand axe est de 1000mm , mon petit axe sera de 526.31mm)

[nicolas2]

Re-bonjour à vous 2 , j'ai cliqué trop vite, je vais joindre une image à mon futur message pour étayer mon essai.

 

Merci

 

Le travail d'équipe est essentiel. En cas d'erreur, ça permet d'accuser quelq'un d'autre

[nicolas2]

Bon, voila déja pour les fonds GRC.

 

;FondB.lsp

;Version 1.0

;Programme AutoLISP écrit par Maxence Delannoy et modifié par Yann Nicollet avec l'aide de Bonuscad et Bred

;Dernière modification le 12.01.09

;Objet: Tracé de fonds GRC suivant NF E 81-102.

 

(defun c:FB ( / DiamExt RayInt RayCar Ep HtBD HtTot PtIns X0 X1 Y0 Y1 Ang1)

(setvar "OSMODE" 0)

(setq

DiamExt (getreal "\nDiamètre extérieur: ")

RayCar (/ DiamExt 10.0)

Ep (getreal "\nEpaisseur: ")

HtBD (getreal "\nHauteur du bord droit: ")

HtTot (+ HtBD Ep (- DiamExt (sqrt (- (expt (- DiamExt RayCar) 2.0) (expt (- (* DiamExt 0.5) Ep RayCar) 2.0)))))

PtIns (getpoint "\nPoint d'insertion: ")

X0 (- (car PtIns) (* DiamExt 0.5))

X1 (+ (car PtIns) (* DiamExt 0.5))

Y0 (- (+ (cadr PtIns) HtTot) DiamExt Ep)

Y1 (+ (cadr PtIns) HtBD)

)

(command "_.PLINE"

(list X1 (nth 1 PtIns))

(list X1 Y1)

"_A" "_CE" ; Arc défini par son centre

(list (- X1 RayCar Ep) Y1)

"_A" ; Angle...

(setq Ang1 (/ (* 180 (angle (list (nth 0 PtIns) Y0) (list (- X1 RayCar Ep) Y1))) pi))

"_CE"

(list (nth 0 PtIns) Y0)

"_A" ; Angle...

(- 180 (* 2 Ang1))

"_CE"

(list (+ X0 RayCar Ep) Y1)

"_A" ; Angle...

Ang1

"_L" ; Ligne...

(list X0 (nth 1 PtIns))

"_C" ; Ferme la polyligne

)

)

 

(prompt "M.D.D. - FondB.lsp chargé.")

(prompt "\nTapez FB pour dessiner un fond GRC suivant NF E 81-102.")

(princ)

 

 

Si quelq'un veut se pencher sur les Fonds elliptiques NF E 81.103 (le rapport de l'ellipse est de 3.8 (exemple pour un Ø de 1000, l'autre axe est de 263.15) en utilisant la même démarche que le fond GRC..Help !!....

 

Merci pour votre aide !

[nicolas2]

Voici mon fond elliptique:

 

le petit axe de l'ellipse = (1000-(2x10))/3.8=257.89 mm

 

http://img150.imageshack.us/my.php?image=fondellptiquep01sn6.jpg

[thry0]

Bjr,

 

Le lisp demande l'épaisseur du fond bombé sans pour autant la dessiner.

Ne serait-il pas judicieux de la modéliser pour l'ajout de piquages par exemple ?

Et savoir ainsi quelle longueur leur donner ...

 

Sinon ça marche impec ... fécilitations

[nicolas2]

Salut thry0,

 

l'épaisseur se fait par un simple "décalé" directement sous Autocad (dans la plupart des cas je ne la dessine pas).

 

J'ai une feuille de calcul EXCEL qui me donne la longueur d'une tubulure sur un fond GRC (tubulure axée ou désaxée) si tu mets ton adresse, je te la transmet.

 

Si tu possèdes des "programmes" EXCEL ou AUTOCAD dans le domaine de la Chaudronnerie, je suis preneur !

 

pcvs.be.nicollet@pcvs.fr

 

A+

[thry0]

Re,

 

Je ne suis pas chaudronnier plutôt charpente métallique, mécano soudure etc ...

donc pas vraiment de quoi t'impressionner avec des applications Xl en rapport avec ton activité ... mais je veux bien ton fichier, plus par curiosité que par nécessité au quotidien !

 

Merci d'avance,

 

t_kijijichezdbmailpointcom